1

Тема: AHK: Отключение акселерации мыши

Доброго времени суток . В настройках мыши снял галочку с пункта включить повышенную точность тем самым отключив акселерацию , но мышь оказалась мудрёная время от времени она сама включает акселерации.С помощью этого файла отключил акселерацию а она всё равно  включает акселерацию.Проверял мышь на акселерацию с помощью этой программы.Помогите пожалуйста отключить акселерацию совсем.

OS: Win7x64, AutoHotkey v1.1.25.01 (Unicode 64-bit).

2

Re: AHK: Отключение акселерации мыши

тем самым отключив акселерацию

А точно? Нет отдельной настройки для акселерации?

3

Re: AHK: Отключение акселерации мыши

Foma - Да точно нет отдельной настройки.

OS: Win7x64, AutoHotkey v1.1.25.01 (Unicode 64-bit).

4 (изменено: Malcev, 2017-01-03 00:54:03)

Re: AHK: Отключение акселерации мыши

Можно в цикле проверять включена ли акселерация и если включена - отключать ее.

loop
{
   SPI_GETMOUSE(accel, low, high)
   if accel
      SPI_SETMOUSE(!accel)
   sleep 200
}
return



; Get mouse acceleration level and low/high thresholds.
; Returns true on success and false on failure.
SPI_GETMOUSE(ByRef accel, ByRef low="", ByRef high="")
{
    VarSetCapacity(vValue, 12)
    if !DllCall("SystemParametersInfo", "uint", 3, "uint", 0, "uint", &vValue, "uint", 0)
        return false ; Fail.
    low := NumGet(vValue, 0)
    high := NumGet(vValue, 4)
    accel := NumGet(vValue, 8)
    return true
}

; Set mouse acceleration level and low/high thresholds.
; Supplies standard default values for low/high if omitted.
; fWinIni:  0 or one of the following values:
;           1 to update the user profile
;           2 to notify applications
;           3 to do both.
; Returns true on success and false on failure.
SPI_SETMOUSE(accel, low="", high="", fWinIni=3)
{
    VarSetCapacity(vValue, 12)
    , NumPut(accel
    , NumPut(high!="" ? high : accel ? 10 : 0
    , NumPut(low!="" ? low : accel ? 6 : 0, vValue)))
    return 0!=DllCall("SystemParametersInfo", "uint", 4, "uint", 0, "uint", &vValue, "uint", fWinIni)
}

5

Re: AHK: Отключение акселерации мыши

Спасибо Вам Malcev всё работает.

OS: Win7x64, AutoHotkey v1.1.25.01 (Unicode 64-bit).