1

Тема: AHK: Подключение к интернету (Wi-Fi)

Всем привет!
Подскажите пожалуйста код, чтобы сделать горячую клавишу, отключить/включить доступ к интернету (Беспроводное сетевое соединение).

2

Re: AHK: Подключение к интернету (Wi-Fi)

Пользуйтесь поиском.
AHK: подключение/отключение интернета
AHK: Настройки сетевого адаптера
AHK: Управлением сетевым адаптером
AHK: Отключение интернета.

3

Re: AHK: Подключение к интернету (Wi-Fi)

У меня такой скрипт сам определяет название подключения, если оно единственное wi-fi. Должен быть запущен от администратора.

$F10:: ToggleWiFi()

ToggleWiFi()  {
   wmi := ComObjGet("winmgmts:")
   for adapter in wmi.ExecQuery("Select * from Win32_NetworkAdapter")
      if InStr(adapter.name, "wireless") && (interfaceName := adapter.NetConnectionID) && status := adapter.NetConnectionStatus
         break
      
   if (interfaceName = "" || status = "")  {
      MsgBox, Failed to get interfaceName!
      return
   }
   if status not in 0,2   ; Disconnected = 0, Connected = 2
   {
      Loop  {
         Sleep, 500
         for adapter in wmi.ExecQuery("Select * from Win32_NetworkAdapter Where Index=" . adapter.Index)
            status := adapter.NetConnectionStatus
      } until status = 0 || status = 2 || (A_Index = 20 && failed := true)
      if failed  {
         MsgBox, Failed to get the status!
         return
      }
   }
   Run, % (A_IsAdmin ? "" : "*RunAs ") . "netsh.exe interface set interface name="""
                                       . interfaceName . """ admin="
                                       . (status = 0 ? "en" : "dis") . "abled",, Hide
}
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg