1

Тема: AHK: Как добавить дочернюю вкладку в одну из уже созданных вкладок?

Имеется такой написанный скрипт для МТАшки, ну  это не суть. В нем есть пару вкладок. Хочу сделать так сказать подвкладки в уже созданную вкладку. Для наглядности вот скриншот - https://yapx.ru/v/L01U1 . Во вкладке "Информационная доска" хочу создать дочернии вкладки.

Gui, 2:Add, Tab2, x0 y0 w1220 h25 cFF2400  +BackgroundTrans, Бинды|РП Ситуации|Штрафы КоАП|Штрафы УАК|График работы|Автомобили и амуниция|Информационная доска

Вот, что имеется.

2

Re: AHK: Как добавить дочернюю вкладку в одну из уже созданных вкладок?

Простого и очевидного решения нет.

Gui, Main: Default
Gui, Margin, 0, 0
Gui, Add, Tab3, hwndhTab vMainTab w400 h300 gMainTab AltSubmit, Вкладка 1|Вкладка 2|Вкладка 3
hParent := DllCall("GetWindow", Ptr, hTab, UInt, GW_HWNDNEXT := 2, Ptr)
WinGetPos,,, W, H, ahk_id %hParent%

Colors := ["Red", "Lime", "Blue"]
Loop 3  {
   Gui, Tab%A_Index%: Default
   Gui, +Parent%hParent% -Caption +ToolWindow
   Gui, Add, Tab3, % "x" 5 " y" 5 " w" W - 20 " h" H - 20, Вкладка %A_Index%-1|Вкладка %A_Index%-2|Вкладка %A_Index%-3
   Gui, Tab, 1
   Gui, Add, Edit, w200 h100, Edit %A_Index%-1
   Gui, Tab, 2
   Gui, Add, Button, gOnClick w100, Кнопка %A_Index%-2
   Gui, Tab, 3
   Gui, Add, Progress, % "w200 h20 c" Colors[A_Index], % 100 * A_Index/3
   Gui, Show, % "Hide x5 y5 w" W - 10 " h" H - 10
}
Gui, Tab1:Show, NA

Gui,Main: Show, w400 h300
Return

OnClick:
   MsgBox, % A_GuiControl
   Return
   
MainTab:
   Gui, Tab%MainTab%:Show, Hide
   GuiControlGet, MainTab, Main:
   Gui, Tab%MainTab%:Show, NA
   Return
   
MainGuiClose:
   ExitApp
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder