1 (изменено: Zanoza, 2011-06-30 00:12:16)

Тема: AHK: Запустить скрипт по щелчку иконки трея

AHK: Запустить скрипт кликом мыши по иконке трея, возможно-ли?

Run, SndVol.exe -f, ,, SndVolPID

Скрипт запустить-(кликом мыши в трее  на созданный скрипт - Run ,  SndVol.exe -f, ,, SndVolPID.)
Просто у меня не отображаетя динамик в трее почемуто ?! , а винду не охота переустонавливать . Можно-ли так  сделать в AHK ?
На всякий случай - (система WIN7 /32.)
Любой ответ приветствуется
Зарание спасибо за помощь!

Win10 x64

2

Re: AHK: Запустить скрипт по щелчку иконки трея

Ничего не понял. Если запустить нужно скрипт, тогда зачем Run ,  SndVol.exe -f, ,, SndVolPID? SndVol.exe — это вроде не скрипт. И по какой иконке кликать, если скрипт не запущен?

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Skype dmitry_fiveg

3 (изменено: Grey, 2011-06-30 01:21:52)

Re: AHK: Запустить скрипт по щелчку иконки трея

Zanoza пишет:

Просто у меня не отображаетя динамик в трее почемуто...

Надо проверить настройки отображения системного значка громкости.

4

Re: AHK: Запустить скрипт по щелчку иконки трея

Изначально  значок был, после 2 - 3х перезагрузок и исчез (почему-то).
С помощью команды 

Run, SndVol.exe -f, ,, SndVolPID

я открыл регулятор громкости.
Впрос:
Можно-ли создать скрипт, который отображается только в трее  (в ожидании клика мыши по иконке в трее этого-же скрипта) запустил вот это ( Run, SndVol.exe -f, ,, SndVolPID ). ?

Win10 x64

5

Re: AHK: Запустить скрипт по щелчку иконки трея

Zanoza пишет:

...в ожидании клика мыши по иконке в трее...

С двух кликов, как минимум :

#Persistent
Menu, Tray, NoStandard
Menu, Tray, Icon, SndVol.exe
Menu, Tray, Add, &Volume, Volume
Menu, Tray, Add, &Exit, Exit
Menu, Tray, Default, &Volume
Menu, Tray, Tip, Volume
Return

Volume:
   Run, C:\Windows\System32\SndVol.exe -f 66061452 4116
;   Run, C:\Windows\System32\SndVol.exe -r 65864847 0
   Return

Exit:
   SplashTextOn, 80, 25,, Exit script
   Sleep, 500
   SplashTextOff
   ExitApp

При желании, можно в этот скрипт добавить горячие клавиши.

6

Re: AHK: Запустить скрипт по щелчку иконки трея

Zanoza пишет:

Можно-ли создать скрип ... ожидании клика мыши по иконке в трее ...

Menu, Tray, NoStandard
Menu, Tray, Icon, %A_WinDir%\system32\sndvol32.exe ; у меня XP :P
Menu, Tray, Add, &Volume, Volume
Menu, Tray, Add, &Exit, Exit
Menu, Tray, Default, &Volume
Menu, Tray, Tip, Volume

; Any script that calls OnMessage anywhere is automatically persistent...
OnMessage(0x404,"WindowProc")
Return

;~ ToolTip, % "hwnd " hwnd " Msg " Msg " lParam " lParam " wParam " wParam
WindowProc(wParam,lParam,Msg,hwnd)
{
	if (Msg=0x404&&lParam=0x201) ; WM_USER+4 && WM_LBUTTONDOWN
	SetTimer, Volume,-1 
}

Volume:
Process, Exist, sndvol32.exe
if !ErrorLevel
Run, %A_WinDir%\system32\sndvol32.exe
else Process, Close, % ErrorLevel
Return
 
Exit:
ExitApp

7

Re: AHK: Запустить скрипт по щелчку иконки трея

В ожидании однократного и двойного клика:

#Persistent
#SingleInstance Force

Menu, Tray, Click, 1
Menu, Tray, NoStandard
Menu, Tray, Add, &Volume1, Volume
Menu, Tray, Add, &Volume, DoubleClick
Menu, Tray, Delete, &Volume1, ;!!!!!!
Menu, Tray, Default, &Volume
Menu, Tray, Add, Выход, Exit
return


DoubleClick:
  If RClicked <> Yes
    {
      If Clicks =
        {
          SetTimer, Volume, 500
          Clicks = 1
          Return
        }
    }
  SetTimer, Volume, Off

  Run, %A_WinDir%\system32\taskmgr.exe

  Clicks =
  RClicked =
Return

Volume:
  SetTimer, Volume, Off

  Process, Exist, sndvol32.exe
  if !ErrorLevel {
    Run, %A_WinDir%\system32\sndvol32.exe
    Menu, Tray, Icon, %A_WinDir%\system32\sndvol32.exe
  }
  else {
    Process, Close, % ErrorLevel
    Menu, Tray, Icon, %A_WinDir%\system32\taskmgr.exe
  }

  Clicks =
  RClicked =
Return

Exit:
ExitApp

8

Re: AHK: Запустить скрипт по щелчку иконки трея

Огромное всем спасибо, варианты подходящие!

Win10 x64