1

Тема: АНК: Скрипт для обрамления активного окна

Хочу написать скрипт, который обрамляет только активное в данный момент времени окно красной рамкой (по контуру активного окна).

Возможно ли задать эту рамку вокруг активного окна с помощью команды WinSet ?

2

Re: АНК: Скрипт для обрамления активного окна

Посмотри эту тему.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

3 (изменено: Ed11, 2011-12-25 14:48:50)

Re: АНК: Скрипт для обрамления активного окна

teadrinker пишет:

Посмотри эту тему.

Спасибо.

Теперь я хочу сделать, чтобы рамка вокруг активного окна появлялась сразу после запуска скрипта (без нажатия хоткея) и окна с одним одинаковым словом (1) в заголовке обрамлялись красным, а окна с другим одинаковым словом (2) в заголовке - зеленым, остальные окна при этом выделять не нужно.
Начинаю c 

WinGetActiveTitle, Title

Теперь, думаю, надо задать условие для 3 разных значений переменной Title - для 1, 2 и остальных.

Не могу сообразить, как задать разные цвета для 2 разных типов окон, а остальные окна не трогать.

4

Re: АНК: Скрипт для обрамления активного окна

TH = 2

SetWinDelay, 0
Gui, +LastFound +ToolWindow -Caption +AlwaysOnTop +Disabled

Loop
{
   Sleep, 50
   
   WinGetActiveTitle, Title
   if InStr(Title, 1)
      Gui, Color, Red
   else if InStr(Title, 2)
      Gui, Color, Green
   Else
   {
      Gui, Show, Hide
      XPrev := ""
      Continue
   }
   
   WinGetPos, X, Y, W, H, A
   WinGet, ID,, A
   if (X = XPrev && Y = YPrev && W = WPrev && H = HPrev && ID = IDPrev)
      Continue
      
   XPrev := X, YPrev := Y, WPrev := W, HPrev := H, IDPrev := ID
   X -= TH, Y -= TH, W += 2*TH, H += 2*TH
   
   Gui, Show, x%X% y%Y% w%W% h%H% Hide
   Options := "0-0 " W "-0 " W "-" H " 0-" H " 0-0 " TH "-" TH
      . " " W-TH "-" TH " " W-TH "-" H-TH " " TH "-" H-TH " " TH "-" TH
   WinSet, Region, % Options
   Gui, Show, NA
}
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder