1 (изменено: [CM]White, 2012-10-27 12:27:30)

Тема: AHK: Свернуть/Развернуть в трей

Нужно по нажатию выделенной кнопки свернуть окно в трей, а развернуть по нажатию левой кнопки мыши на иконку в трее

#SingleInstance force
Gui, +AlwaysOnTop
Gui,Show, w300 h200, Тест
return

-:
Gui, hide
return

?:
Gui, Show
return

GuiClose:
ExitApp

2

Re: AHK: Свернуть/Развернуть в трей

global SC_MINIMIZE := 0xF020, WM_LBUTTONDOWN := 0x201, hGui

Gui, +AlwaysOnTop +hwndhGui
Gui, Show, w300 h200, Тест

OnMessage(0x404, "AHK_NOTIFYICON")
OnMessage(0x112, "WM_SYSCOMMAND")
return

GuiClose:
   ExitApp

WM_SYSCOMMAND(wp, lp, msg, hwnd)
{
   if (wp = SC_MINIMIZE && hwnd = hGui)
   {
      WinHide, ahk_id %hwnd%
      return 0
   }
}

AHK_NOTIFYICON(wp, lp)
{
   if (lp = WM_LBUTTONDOWN)
      WinShow, ahk_id %hGui%
}
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

3

Re: AHK: Свернуть/Развернуть в трей

А возможно сразу запустить приложение в трее?

4

Re: AHK: Свернуть/Развернуть в трей

Смотря, какое приложение.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

5

Re: AHK: Свернуть/Развернуть в трей

Для которого уже предусмотрена отправка в трей? Имею в виду «Архивариус 3000».

+ открыть спойлер

https://i.imgur.com/VonVcMf.png

6 (изменено: teadrinker, 2019-08-29 11:36:44)

Re: AHK: Свернуть/Развернуть в трей

Не, не в курсе.
Можно так попробовать:

Run, MyExe.exe,, Hide
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

7 (изменено: DD, 2019-08-30 14:15:55)

Re: AHK: Свернуть/Развернуть в трей

Так тоже пробовал

Archivarius3000.exe /min
start /min Archivarius3000.exe
start /min /low Archivarius3000.exe
в свойствах ярлыка дописать /tray

Максимум получается добиться свернутого окна в кнопку на Панели задач (помимо значка в Трее).

А можно сделать проверку и убрать определенное окно с Панели задач?

8

Re: AHK: Свернуть/Развернуть в трей

Через WinClose можно.

9

Re: AHK: Свернуть/Развернуть в трей

А как сделать так, что-бы этот код действовал лишь на одно GUI, а на другое - нет?  teadrinker

10

Re: AHK: Свернуть/Развернуть в трей

Gui, New, +hwndhGui1, Gui1
Gui, Show, x300 w300 h200

Gui, New,, Gui2
Gui, Show, x700 w300 h200

OnMessage(0x404, Func("AHK_NOTIFYICON").Bind(hGui1))
OnMessage(0x112, Func("WM_SYSCOMMAND").Bind(hGui1))
return

GuiClose:
   ExitApp

WM_SYSCOMMAND(hGui, wp, lp, msg, hwnd) {
   static SC_MINIMIZE := 0xF020
   if (wp = SC_MINIMIZE && hwnd = hGui) {
      WinHide, ahk_id %hwnd%
      return 0
   }
}

AHK_NOTIFYICON(hGui, wp, lp) {
   static WM_LBUTTONDOWN := 0x201
   if (lp = WM_LBUTTONDOWN)
      WinShow, ahk_id %hGui%
}
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

11 (изменено: ypppu, 2020-04-07 11:01:56)

Re: AHK: Свернуть/Развернуть в трей

Огромное спасибо!)

Не цитируйте предыдущее сообщение.