AHK: Определить процесс выделенного файла и закрыть его (Страница 1 из 2)

F11::
   SelectedItems := GetSelectedFiles()
   Processes := ComObjGet("winmgmts:").InstancesOf("Win32_Process")
   Loop, parse, SelectedItems, `n
   {
      if SubStr(A_LoopField, -3) = ".exe"
      {
         for Process in Processes
            if (Process.ExecutablePath = A_LoopField)
               Process.Terminate
      }
      else ;if SubStr(A_LoopField, -3) = ".ahk   ; если нужно проверять только ahk-файлы, убрать точку с запятой
         for Process in Processes
            if InStr(Process.CommandLine, A_LoopField)
               Process.Terminate
   }
   return

GetSelectedFiles(hwnd="")
{
   if (hwnd = "")
      WinGet, hwnd,, A
   
   objShell := ComObjCreate("Shell.Application")
   
   for window in objShell.Windows
      if (window.hwnd = hwnd && ShellWindow := 1)
         Break

   if !ShellWindow
      return
   
   for item in window.document.SelectedItems
      if !item.IsFolder
         ret .= item.path . "`n"
   
   Return SubStr(ret, 1, -1)
}

F11::
   if !SelectedItems := GetSelectedFiles()
   {
      MsgBox, Не найдено выделенных файлов в активном окне
      return
   }
   
   Processes := ComObjGet("winmgmts:").InstancesOf("Win32_Process")
   Loop, parse, SelectedItems, `n
   {
      if SubStr(A_LoopField, -3) = ".lnk"
         FileGetShortcut, % A_LoopField, FilePath
      else
         FilePath := A_LoopField
      
      if !FileExist(FilePath)
      {
         MsgBox, Ошибка
         return
      }
      
      if SubStr(FilePath, -3) = ".exe"
      {
         for Process in Processes
            if (Process.ExecutablePath = FilePath)
               Process.Terminate
      }
      else ;if SubStr(FilePath, -3) = ".ahk   ; если нужно проверять только ahk-файлы, убрать точку с запятой
         for Process in Processes
            if InStr(Process.CommandLine, FilePath)
               Process.Terminate
   }
   return

GetSelectedFiles(hwnd="")
{
   if (hwnd = "")
      WinGet, hwnd,, A
   
   WinGetClass, Class, ahk_id %hwnd%
   if (Class = "Progman")
   {
      ClipSaved := ClipboardAll
      Clipboard := ""
      SendInput, ^{vk43}
      ClipWait, 1
      if ErrorLevel
      {
         Clipboard := TempClipboard
         return
      }
      var := Clipboard, Clipboard := ClipSaved
      Return var
   }
   else
   {
      objShell := ComObjCreate("Shell.Application")
      
      for window in objShell.Windows
         if (window.hwnd = hwnd && ShellWindow := 1)
            Break

      if !ShellWindow
         return
      
      for item in window.document.SelectedItems
         if !item.IsFolder
            ret .= item.path . "`n"
      
      Return SubStr(ret, 1, -1)
   }
}

/*
    Library for getting info from a specific explorer window (if window handle not specified, the currently active
    window will be used).  Requires AHK_L or similar.  Works with the desktop.  Does not currently work with save
    dialogs and such.
    
    
    Explorer_GetSelected(hwnd="")   - paths of target window's selected items
    Explorer_GetAll(hwnd="")        - paths of all items in the target window's folder
    Explorer_GetPath(hwnd="")       - path of target window's folder
    
    example:
        F1::
            path := Explorer_GetPath()
            all := Explorer_GetAll()
            sel := Explorer_GetSelected()
            MsgBox % path
            MsgBox % all
            MsgBox % sel
        return
    
    Joshua A. Kinnison
    2011-04-27, 16:12
    http://www.autohotkey.com/board/topic/60985-get-paths-of-selected-items-in-an-explorer-window/
*/

Explorer_GetPath(hwnd="")
{
    if !(window := Explorer_GetWindow(hwnd))
        return ErrorLevel := "ERROR"
    if (window="desktop")
        return A_Desktop
    path := window.LocationURL
    path := RegExReplace(path, "ftp://.*@","ftp://")
    StringReplace, path, path, file:///
    StringReplace, path, path, /, \, All 
    
    ; thanks to polyethene
    Loop
        If RegExMatch(path, "i)(?<=%)[\da-f]{1,2}", hex)
            StringReplace, path, path, `%%hex%, % Chr("0x" . hex), All
        Else Break
    return path
}
Explorer_GetAll(hwnd="")
{
    return Explorer_Get(hwnd)
}
Explorer_GetSelected(hwnd="")
{
    return Explorer_Get(hwnd,true)
}

Explorer_GetWindow(hwnd="")
{
    ; thanks to jethrow for some pointers here
    WinGet, process, processName, % "ahk_id" hwnd := hwnd? hwnd:WinExist("A")
    WinGetClass class, ahk_id %hwnd%
    
    if (process!="explorer.exe")
        return
    if (class ~= "(Cabinet|Explore)WClass")
    {
        for window in ComObjCreate("Shell.Application").Windows
            if (window.hwnd==hwnd)
                return window
    }
    else if (class ~= "Progman|WorkerW") 
        return "desktop" ; desktop found
} 
Explorer_Get(hwnd="",selection=false)
{
    if !(window := Explorer_GetWindow(hwnd))
        return ErrorLevel := "ERROR"
    if (window="desktop")
    {
        ControlGet, hwWindow, HWND,, SysListView321, ahk_class Progman
        if !hwWindow ; #D mode
            ControlGet, hwWindow, HWND,, SysListView321, A
        ControlGet, files, List, % ( selection ? "Selected":"") "Col1",,ahk_id %hwWindow%
        base := SubStr(A_Desktop,0,1)=="\" ? SubStr(A_Desktop,1,-1) : A_Desktop
        Loop, Parse, files, `n, `r
        {
            path := base "\" A_LoopField
            IfExist %path% ; ignore special icons like Computer (at least for now)
                ret .= path "`n"
        }
    }
    else
    {
        if selection
            collection := window.document.SelectedItems
        else
            collection := window.document.Folder.Items
        for item in collection
            ret .= item.path "`n"
    }
    return Trim(ret,"`n")
}

1:: ToolTip % GetSelectedDesktop() 
 
GetSelectedDesktop()   { 
    ControlGet, hwnd, HWND,, SysListView321, Program Manager ahk_class Progman ahk_exe explorer.exe
    
    If !hwnd   ;  Win+D mode
        ControlGet, hwnd, HWND,, SysListView321, ahk_class WorkerW ahk_exe explorer.exe

    ControlGet, SelectedCount, List, Count Selected, , ahk_id %hwnd% 
 
    If !SelectedCount
        Return "Ничего не выделено"
        
    ControlGet, ListSelected, List, Selected, , ahk_id %hwnd%   
    objShellApp := ComObjCreate("Shell.Application")
    objFolder := objShellApp.NameSpace(A_Desktop)  
    
    Loop, %A_Desktop%\*.*, 1
    {
        objItem := objFolder.ParseName(A_LoopFileName), info := ""
        
        Loop 3
            info .= objFolder.GetDetailsOf(objItem, A_Index - 1) . A_Tab
    
        IfInString, ListSelected, %info%
            SelectedItems .= A_LoopFileLongPath . (objItem.IsFolder ? "  ::  Это папка" : "") . "`n"
    } 
    Return RTrim(SelectedItems, "`n")
}

sel = 18.11.2013 18:55
inf = 18.11.2013 18:55
MsgBox % sel = inf

GetSelectedDesktop()  
Return

GetSelectedDesktop()   {
    Static objShellApp := ComObjCreate("Shell.Application")
    ControlGet, Selected, List, Selected, SysListView321, Program Manager ahk_class Progman ahk_exe explorer.exe
    objFolder := objShellApp.NameSpace(A_Desktop)
    
    arrSelected := StrSplit(Selected, "`n", "`r")   ;  потом извлекается первый выделенный для наглядности сравнения
    CoordMode, ToolTip, Screen   
    ToolTip % Selected, 5, 5  

    Loop, %A_Desktop%\*.*, 1
    {
        objItem := objFolder.ParseName(A_LoopFileName), info := ""
        
        Loop 4 
            info .= objFolder.GetDetailsOf(objItem, A_Index-1) . A_Tab
            
        info := Clipboard := RTrim(info, A_Tab) 
        
        MsgBox % StrLen(info) "`n" info 
            . "`n`n" StrLen(arrSelected[1]) "`n" arrSelected[1] 
            . "`n`n" A_LoopFileName
         str := arrSelected[1]
         Loop, parse, str
            MsgBox, % A_Index "`n" A_LoopField "`n" Asc(A_LoopField)
        
        IfInString, Selected, %info%
            MsgBox % "Выделено:`n" A_LoopFileName
    }
}

    Loop, parse, SelectedList, `n
    ListSelected .= SubStr(A_LoopField, 1, p:=InStr(A_LoopField, A_Tab, , 0, 1)) 
                    . RegExReplace(SubStr(A_LoopField, p+1), "[^\d \:\.]") . "`n"

1:: ToolTip % GetSelectedDesktop()
 
GetSelectedDesktop()   {
    ControlGet, hwnd, HWND,, SysListView321
        , % DllCall("GetTopWindow", "Int", id:=DllCall("GetShellWindow")) 
        ? "ahk_id" id : "ahk_class WorkerW ahk_exe explorer.exe"
    ControlGet, GetList, List, Selected, , ahk_id %hwnd% 
    Loop, parse, GetList, `n
        ListSelected .= SubStr(A_LoopField, 1, p:=InStr(A_LoopField, A_Tab, , 0, 1)) 
                    . RegExReplace(SubStr(A_LoopField, p+1), "[^\d \:\.]") . "`n"
    For k, Folder in [A_Desktop, A_DesktopCommon]
    { 
        objFolder := ComObjCreate("Shell.Application").NameSpace(Folder)  
        Loop, %Folder%\*.*, 1
        {
            objItem := objFolder.ParseName(A_LoopFileName), info := "" 
            Loop 4
                info .= objFolder.GetDetailsOf(objItem, A_Index - 1) . (A_Index = 4 ? "" : A_Tab)
            IfInString, ListSelected, %info%
                SelectedItems .= A_LoopFileLongPath "`n"
        } 
    }  
    Return RTrim(SelectedItems, "`n")
}

DllCall("shell32\SHGetDesktopFolder", "ptr *", pShellFolder)
VarSetCapacity(CSFV, A_PtrSize * 7, 0)
NumPut(A_PtrSize * 7, CSFV, 0, "uint")
NumPut(pShellFolder, CSFV, A_PtrSize, "ptr")
DllCall("shell32\SHCreateShellFolderViewEx", "ptr", &CSFV, "ptr *", pShellView)
pVTable := NumGet(pShellView + 0, 0, "ptr")
pQueryInterface := NumGet(pVTable + 0, 0, "ptr")
iidFolderView2 := "{1af3a467-214f-4298-908e-06b03e0b39f9}"
VarSetCapacity(iidfv2, 16, 0)
DllCall("ole32\IIDFromString", "wstr", iidFolderView2, "ptr", &iidfv2)
hres := DllCall(pQueryInterface, "ptr", pShellView, "ptr", &iidfv2, "ptr *", pFolderView2, "uint")

MsgBox, %hres% %pFolderView2%

ShellRun(prms*)
{
    shellWindows := ComObjCreate("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    
    desktop := shellWindows.Item(ComObj(19, 8)) ; VT_UI4, SCW_DESKTOP                
   
    ; Retrieve top-level browser object.
    if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser
    {
        ; IShellBrowser.QueryActiveShellView -> IShellView
        if DllCall(NumGet(NumGet(ptlb+0)+15*A_PtrSize), "ptr", ptlb, "ptr*", psv:=0) = 0
        {
            ; Define IID_IDispatch.
            VarSetCapacity(IID_IDispatch, 16)
            NumPut(0x46000000000000C0, NumPut(0x20400, IID_IDispatch, "int64"), "int64")
           
            ; IShellView.GetItemObject -> IDispatch (object which implements IShellFolderViewDual)
            DllCall(NumGet(NumGet(psv+0)+15*A_PtrSize), "ptr", psv
                , "uint", 0, "ptr", &IID_IDispatch, "ptr*", pdisp:=0)
           
            ; Get Shell object.
            shell := ComObj(9,pdisp,1).Application
           
            ; IShellDispatch2.ShellExecute
            shell.ShellExecute(prms*)
           
            ObjRelease(psv)
        }
        ObjRelease(ptlb)
    }
}

F11::
    SelectedItems := DesktopGetSelectedItems()
    Loop, % SelectedItems.Count
        MsgBox, % SelectedItems.Item(A_Index - 1).Name
Return
    

DesktopGetSelectedItems()
{
    shellWindows := ComObjCreate("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    
    desktop := shellWindows.Item(ComObj(19, 8)) ; VT_UI4, SCW_DESKTOP                
   
    ; Retrieve top-level browser object.
    if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser
    {
        ; IShellBrowser.QueryActiveShellView -> IShellView
        if DllCall(NumGet(NumGet(ptlb+0)+15*A_PtrSize), "ptr", ptlb, "ptr*", psv:=0) = 0
        {
            ; Define IID_IDispatch.
            VarSetCapacity(IID_IDispatch, 16)
            NumPut(0x46000000000000C0, NumPut(0x20400, IID_IDispatch, "int64"), "int64")
           
            ; IShellView.GetItemObject -> IDispatch (object which implements IShellFolderViewDual)
            DllCall(NumGet(NumGet(psv+0)+15*A_PtrSize), "ptr", psv
                , "uint", 0, "ptr", &IID_IDispatch, "ptr*", pdisp:=0)
           
            Items := ComObjEnwrap(pdisp).SelectedItems()
            ObjRelease(psv)
        }
        ObjRelease(ptlb)
    }
    return Items
}

IShellFolderViewDual := GetDesktopIShellFolderViewDual()
Return
    
F11::
    for item in IShellFolderViewDual.SelectedItems
        MsgBox, % item.Path
Return
    

GetDesktopIShellFolderViewDual()
{
    IShellWindows := ComObjCreate("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    desktop := IShellWindows.Item(ComObj(19, 8)) ; VT_UI4, SCW_DESKTOP                
   
    ; Retrieve top-level browser object.
    if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser
    {
        ; IShellBrowser.QueryActiveShellView -> IShellView
        if DllCall(NumGet(NumGet(ptlb+0)+15*A_PtrSize), "ptr", ptlb, "ptr*", psv) = 0
        {
            ; Define IID_IDispatch.
            VarSetCapacity(IID_IDispatch, 16)
            NumPut(0x46000000000000C0, NumPut(0x20400, IID_IDispatch, "int64"), "int64")
           
            ; IShellView.GetItemObject -> IDispatch (object which implements IShellFolderViewDual)
            DllCall(NumGet(NumGet(psv+0)+15*A_PtrSize), "ptr", psv
                , "uint", 0, "ptr", &IID_IDispatch, "ptr*", pdisp)
           
            IShellFolderViewDual := ComObjEnwrap(pdisp)
            ObjRelease(psv)
        }
        ObjRelease(ptlb)
    }
    return IShellFolderViewDual
}