1 (изменено: ypppu, 2019-05-09 15:27:12)

Тема: AHK: Нажатие ЛКМ по найденной картинке

Подскажите скрипт.
Надо что бы по области экрана (1024х700) искалась картинка Х (размер картинки 90х90) и что бы как он ее найдет было нажатие по центру картинки.


Я новичек поэтому не судите строго. )


        
ok:
		Sleep, 1000
        ImageSearch, X, Y, 5, 5, 1024, 700, *50 C:\ok.bmp 
	    while (ErrorLevel)                                  		
	     {	
        Goto, ok				 		         					
	     }
     тут надо клик по координатам найденной картинке


И еще если не затруднит. Надо что бы по области экрана был поиск картинки и при ее нахождении делался скрин.

Post's attachments

Новый точечный рисунок.jpg 32.94 kb, file has never been downloaded. 

You don't have the permssions to download the attachments of this post.

2

Re: AHK: Нажатие ЛКМ по найденной картинке

donbluugame, приведите заголовок темы в соответствие с правилами. Код должен обрамляться тегом "code"! Предложения должны начинаться заглавной буквой и заканчиваться точкой. Исправьте!

3

Re: AHK: Нажатие ЛКМ по найденной картинке


; Источник: https://www.autohotkey.com/docs/commands/ImageSearch.htm

CoordMode, Pixel, Client ; Pixel: влияет на PixelGetColor, PixelSearch и ImageSearch.
CoordMode, Mouse, Client ; Mouse: влияет на MouseGetPos, Click и MouseMove/Click/Drag.
CoordMode, ToolTip, Client ; ToolTip: Влияет На Всплывающую Подсказку.
; Client: координаты относительно клиентской области активного окна, исключая строку заголовка окна, меню (если оно стандартное) и границы. 
; Screen: Координаты относительно рабочего стола (весь экран).
; Relative: координаты относительно активного окна.

File_name = File_name.png

ImageSearch, Coordinate_X, Coordinate_Y, 0, 0, A_ScreenWidth, A_ScreenHeight, *60 %A_WorkingDir%\%File_name%
if ErrorLevel = 2 
{
	MsgBox, 8256, ERROR, Не удалось провести поиск. Отсутствует файл %File_name%
}
else if ErrorLevel = 0
{
	MsgBox, 8256, ERROR, Картинка найдена на экране. Координаты: %Coordinate_X%, %Coordinate_Y%
}
else if ErrorLevel = 1
{
	MsgBox, 8256, ERROR, Картинка не найдена на экране.
}

; Источник: http://forum.script-coding.com/viewtopic.php?pid=121790#p121790

SaveScreenshotToFile(0, 0, A_ScreenWidth, A_ScreenHeight, A_ScriptDir . "\test.png")
;Run, % A_ScriptDir . "\test.png"

SaveScreenshotToFile(x, y, w, h, filePath)  {
   hBitmap := GetHBitmapFromScreen(x, y, w, h)
   gdip := new GDIplus
   pBitmap := gdip.BitmapFromHBitmap(hBitmap)
   DllCall("DeleteObject", Ptr, hBitmap)
   gdip.SaveBitmapToFile(pBitmap, filePath)
   gdip.DisposeImage(pBitmap)
}

GetHBitmapFromScreen(x, y, w, h)  {
   hDC := DllCall("GetDC", Ptr, 0, Ptr)
   hBM := DllCall("CreateCompatibleBitmap", Ptr, hDC, Int, w, Int, h, Ptr)
   pDC := DllCall("CreateCompatibleDC", Ptr, hDC, Ptr)
   oBM := DllCall("SelectObject", Ptr, pDC, Ptr, hBM, Ptr)
   DllCall("BitBlt", Ptr, pDC, Int, 0, Int, 0, Int, w, Int, h, Ptr, hDC, Int, x, Int, y, UInt, 0x00CC0020)
   DllCall("SelectObject", Ptr, pDC, Ptr, oBM)
   DllCall("DeleteDC", Ptr, pDC)
   DllCall("ReleaseDC", Ptr, 0, Ptr, hDC)
   Return hBM  ; should be deleted with DllCall("DeleteObject", Ptr, hBM)
}

class GDIplus   {
   __New()  {
      if !DllCall("GetModuleHandle", Str, "gdiplus", Ptr)
         DllCall("LoadLibrary", Str, "gdiplus")
      VarSetCapacity(si, A_PtrSize = 8 ? 24 : 16, 0), si := Chr(1)
      DllCall("gdiplus\GdiplusStartup", PtrP, pToken, Ptr, &si, Ptr, 0)
      this.token := pToken
   }
   
   __Delete()  {
      DllCall("gdiplus\GdiplusShutdown", Ptr, this.token)
      if hModule := DllCall("GetModuleHandle", Str, "gdiplus", Ptr)
         DllCall("FreeLibrary", Ptr, hModule)
   }
   
   BitmapFromHBitmap(hBitmap, Palette := 0)  {
      DllCall("gdiplus\GdipCreateBitmapFromHBITMAP", Ptr, hBitmap, Ptr, Palette, PtrP, pBitmap)
      return pBitmap  ; should be deleted with this.DisposeImage(pBitmap)
   }
   
   SaveBitmapToFile(pBitmap, sOutput, Quality=75)  {
      SplitPath, sOutput,,, Extension
      if Extension not in BMP,DIB,RLE,JPG,JPEG,JPE,JFIF,GIF,TIF,TIFF,PNG
         return -1

      DllCall("gdiplus\GdipGetImageEncodersSize", UIntP, nCount, UIntP, nSize)
      VarSetCapacity(ci, nSize)
      DllCall("gdiplus\GdipGetImageEncoders", UInt, nCount, UInt, nSize, Ptr, &ci)
      if !(nCount && nSize)
         return -2
      
      Loop, % nCount  {
         sString := StrGet(NumGet(ci, (idx := (48+7*A_PtrSize)*(A_Index-1))+32+3*A_PtrSize), "UTF-16")
         if !InStr(sString, "*." Extension)
            continue
         
         pCodec := &ci+idx
         break
      }
      
      if !pCodec
         return -3

      if RegExMatch(Extension, "i)^J(PG|PEG|PE|FIF)$") && Quality != 75  {
         DllCall("gdiplus\GdipGetEncoderParameterListSize", Ptr, pBitmap, Ptr, pCodec, UintP, nSize)
         VarSetCapacity(EncoderParameters, nSize, 0)
         DllCall("gdiplus\GdipGetEncoderParameterList", Ptr, pBitmap, Ptr, pCodec, UInt, nSize, Ptr, &EncoderParameters)
         Loop, % NumGet(EncoderParameters, "UInt")  {
            elem := (24+A_PtrSize)*(A_Index-1) + 4 + (pad := A_PtrSize = 8 ? 4 : 0)
            if (NumGet(EncoderParameters, elem+16, "UInt") = 1) && (NumGet(EncoderParameters, elem+20, "UInt") = 6)  {
               p := elem+&EncoderParameters-pad-4
               NumPut(Quality, NumGet(NumPut(4, NumPut(1, p+0)+20, "UInt")), "UInt")
               break
            }
         }      
      }
      
      if A_IsUnicode
         pOutput := &sOutput
      else  {
         VarSetCapacity(wOutput, StrPut(sOutput, "UTF-16")*2, 0)
         StrPut(sOutput, &wOutput, "UTF-16")
         pOutput := &wOutput
      }
      E := DllCall("gdiplus\GdipSaveImageToFile", Ptr, pBitmap, Ptr, pOutput, Ptr, pCodec, UInt, p ? p : 0)
      return E ? -5 : 0
   }
   
   DisposeImage(pBitmap)  {
      return DllCall("gdiplus\GdipDisposeImage", Ptr, pBitmap)
   }
}