1

Тема: AHK: Sciter

Всех приветствую, кто-нибудь пробовал работать со sciter'ом на AHK?
Нашел здесь "свежую" тему.
И несколько тем на форумах AutoIt [1], [2]. Как я понял(со второго поста), sciter давно обновился и поменялись адреса функций. Ссылки на скачивание устарели, соответственно, всё, что там есть - не рабочее.

2

Re: AHK: Sciter

Плохо смотрели:
https://www.autoitscript.com/forum/topi … nt-1330233

3

Re: AHK: Sciter

MandarinKa02, есть прогресс?
Моя попытка запустить пример по ссылке "свежей" темы, почему-то "фейлит" исключением на стадии выполнения Clr_CreateObject():

#SingleInstance Force
#NoEnv
SetWorkingDir, A_ScriptDir
ListLines, Off
SetBatchLines, -1

#Include <CLR>

html =
(
<html>
<head>
<style>
body {
  background-color: linen;
}

h1 {
  color: maroon;
  margin-left: 40px;
} 
</style>
</head>
<body>
<h1>
This is an Experiment
</h1>
<div>
Sciter runs in AHK!
</div>
</body>
</html>

)

sci := Clr_LoadLibrary("SciterSharpWindows.dll")

Try
	sciwin := Clr_CreateObject(sci, "SciterSharp.SciterWindow")
Catch e {
	MsgBox % e.Message
	ExitApp
}
sciwin.CreateMainWindow(400, 300)
sciwin.CenterTopLevelWindow()
sciwin.Title := "Using SciterSharp in AutoHotkey"
sciwin.LoadHtml(html)
sciwin.Show()
return

Escape::ExitApp

4 (изменено: MandarinKa02, 2019-04-21 19:29:41)

Re: AHK: Sciter

KusochekDobra, к сожалению - нет. Sciter имеет много страшных CSS-свойств, которых в привычном CSS'е нет. Поэтому остановлюсь на том, что начал.
В дальнейшем буду смотреть в сторону ultralig.ht. Возможно, попытаюсь провернуть это дело на AHK.

5

Re: AHK: Sciter

KusochekDobra, значит дллку криво скомпилили.
Берите, например, отсюда:
http://misoftware.com.br/Home/Post/TheLibrary

6

Re: AHK: Sciter

MandarinKa02 пишет:

В дальнейшем буду смотреть в сторону ultralig.ht. Возможно, попытаюсь провернуть это дело на AHK.

Как вы это собираетесь переносить?

The API is currently available for C++

7 (изменено: MandarinKa02, 2019-04-21 20:26:19)

Re: AHK: Sciter

Мои познания(на данный момент) в семействе C языков программирования не уходят дальше Hello World. Поэтому - не знаю.
Но, знаю одно - есть желание, есть стремление.

8 (изменено: KusochekDobra, 2019-04-22 02:37:24)

Re: AHK: Sciter

Malcev, спасибо за ссылку.
В "свежей" теме, автор оставил ссылку в которой есть указание, что это пакет для NuGet. Я его просто скачал и вскрыл архиватором, вытащив dll.  В TheLibrary, dll той же версии, разве что судя по дате изменения она на два дня моложе и на 8Кб полегче, но это вряд ли что-то меняет, раз реакция на пример у неё идентична.

9

Re: AHK: Sciter

По приведенной мной ссылке у меня работает - показывает окно с введённым текстом.
AHK 32 bit 1.1.30.03.

10

Re: AHK: Sciter

С dll из пакета для Nuget тоже работает.

html =
(
<html>
<head>
<style>
body {
  background-color: linen;
}

h1 {
  color: maroon;
  margin-left: 40px;
} 
</style>
</head>
<body>
<h1>
This is an Experiment
</h1>
<div>
Sciter runs in AHK!
</div>
</body>
</html>

)

sci := Clr_LoadLibrary("SciterSharpWindows.dll")
sciwin := Clr_CreateObject(sci, "SciterSharp.SciterWindow")
sciwin.CreateMainWindow(400, 300)
sciwin.CenterTopLevelWindow()
sciwin.Title := "Using SciterSharp in AutoHotkey"
sciwin.LoadHtml(html)
sciwin.Show()
return

Escape::ExitApp


; ==========================================================
;                  .NET Framework Interop
;      https://autohotkey.com/boards/viewtopic.php?t=4633
; ==========================================================
;
;   Author:     Lexikos
;   Version:    1.2
;   Requires:	AutoHotkey_L v1.0.96+
;

CLR_LoadLibrary(AssemblyName, AppDomain=0)
{
	if !AppDomain
		AppDomain := CLR_GetDefaultDomain()
	e := ComObjError(0)
	Loop 1 {
		if assembly := AppDomain.Load_2(AssemblyName)
			break
		static null := ComObject(13,0)
		args := ComObjArray(0xC, 1),  args[0] := AssemblyName
		typeofAssembly := AppDomain.GetType().Assembly.GetType()
		if assembly := typeofAssembly.InvokeMember_3("LoadWithPartialName", 0x158, null, null, args)
			break
		if assembly := typeofAssembly.InvokeMember_3("LoadFrom", 0x158, null, null, args)
			break
	}
	ComObjError(e)
	return assembly
}

CLR_CreateObject(Assembly, TypeName, Args*)
{
	if !(argCount := Args.MaxIndex())
		return Assembly.CreateInstance_2(TypeName, true)
	
	vargs := ComObjArray(0xC, argCount)
	Loop % argCount
		vargs[A_Index-1] := Args[A_Index]
	
	static Array_Empty := ComObjArray(0xC,0), null := ComObject(13,0)
	
	return Assembly.CreateInstance_3(TypeName, true, 0, null, vargs, null, Array_Empty)
}

CLR_CompileC#(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
{
	return CLR_CompileAssembly(Code, References, "System", "Microsoft.CSharp.CSharpCodeProvider", AppDomain, FileName, CompilerOptions)
}

CLR_CompileVB(Code, References="", AppDomain=0, FileName="", CompilerOptions="")
{
	return CLR_CompileAssembly(Code, References, "System", "Microsoft.VisualBasic.VBCodeProvider", AppDomain, FileName, CompilerOptions)
}

CLR_StartDomain(ByRef AppDomain, BaseDirectory="")
{
	static null := ComObject(13,0)
	args := ComObjArray(0xC, 5), args[0] := "", args[2] := BaseDirectory, args[4] := ComObject(0xB,false)
	AppDomain := CLR_GetDefaultDomain().GetType().InvokeMember_3("CreateDomain", 0x158, null, null, args)
	return A_LastError >= 0
}

CLR_StopDomain(ByRef AppDomain)
{	; ICorRuntimeHost::UnloadDomain
	DllCall("SetLastError", "uint", hr := DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+20*A_PtrSize), "ptr", RtHst, "ptr", ComObjValue(AppDomain))), AppDomain := ""
	return hr >= 0
}

; NOTE: IT IS NOT NECESSARY TO CALL THIS FUNCTION unless you need to load a specific version.
CLR_Start(Version="") ; returns ICorRuntimeHost*
{
	static RtHst := 0
	; The simple method gives no control over versioning, and seems to load .NET v2 even when v4 is present:
	; return RtHst ? RtHst : (RtHst:=COM_CreateObject("CLRMetaData.CorRuntimeHost","{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}"), DllCall(NumGet(NumGet(RtHst+0)+40),"uint",RtHst))
	if RtHst
		return RtHst
	EnvGet SystemRoot, SystemRoot
	if Version =
		Loop % SystemRoot "\Microsoft.NET\Framework" (A_PtrSize=8?"64":"") "\*", 2
			if (FileExist(A_LoopFileFullPath "\mscorlib.dll") && A_LoopFileName > Version)
				Version := A_LoopFileName
	if DllCall("mscoree\CorBindToRuntimeEx", "wstr", Version, "ptr", 0, "uint", 0
	, "ptr", CLR_GUID(CLSID_CorRuntimeHost, "{CB2F6723-AB3A-11D2-9C40-00C04FA30A3E}")
	, "ptr", CLR_GUID(IID_ICorRuntimeHost,  "{CB2F6722-AB3A-11D2-9C40-00C04FA30A3E}")
	, "ptr*", RtHst) >= 0
		DllCall(NumGet(NumGet(RtHst+0)+10*A_PtrSize), "ptr", RtHst) ; Start
	return RtHst
}

;
; INTERNAL FUNCTIONS
;

CLR_GetDefaultDomain()
{
	static defaultDomain := 0
	if !defaultDomain
	{	; ICorRuntimeHost::GetDefaultDomain
		if DllCall(NumGet(NumGet(0+RtHst:=CLR_Start())+13*A_PtrSize), "ptr", RtHst, "ptr*", p:=0) >= 0
			defaultDomain := ComObject(p), ObjRelease(p)
	}
	return defaultDomain
}

CLR_CompileAssembly(Code, References, ProviderAssembly, ProviderType, AppDomain=0, FileName="", CompilerOptions="")
{
	if !AppDomain
		AppDomain := CLR_GetDefaultDomain()
	
	if !(asmProvider := CLR_LoadLibrary(ProviderAssembly, AppDomain))
	|| !(codeProvider := asmProvider.CreateInstance(ProviderType))
	|| !(codeCompiler := codeProvider.CreateCompiler())
		return 0

	if !(asmSystem := (ProviderAssembly="System") ? asmProvider : CLR_LoadLibrary("System", AppDomain))
		return 0
	
	; Convert | delimited list of references into an array.
	StringSplit, Refs, References, |, %A_Space%%A_Tab%
	aRefs := ComObjArray(8, Refs0)
	Loop % Refs0
		aRefs[A_Index-1] := Refs%A_Index%
	
	; Set parameters for compiler.
	prms := CLR_CreateObject(asmSystem, "System.CodeDom.Compiler.CompilerParameters", aRefs)
	, prms.OutputAssembly          := FileName
	, prms.GenerateInMemory        := FileName=""
	, prms.GenerateExecutable      := SubStr(FileName,-3)=".exe"
	, prms.CompilerOptions         := CompilerOptions
	, prms.IncludeDebugInformation := true
	
	; Compile!
	compilerRes := codeCompiler.CompileAssemblyFromSource(prms, Code)
	
	if error_count := (errors := compilerRes.Errors).Count
	{
		error_text := ""
		Loop % error_count
			error_text .= ((e := errors.Item[A_Index-1]).IsWarning ? "Warning " : "Error ") . e.ErrorNumber " on line " e.Line ": " e.ErrorText "`n`n"
		MsgBox, 16, Compilation Failed, %error_text%
		return 0
	}
	; Success. Return Assembly object or path.
	return compilerRes[FileName="" ? "CompiledAssembly" : "PathToAssembly"]
}

CLR_GUID(ByRef GUID, sGUID)
{
	VarSetCapacity(GUID, 16, 0)
	return DllCall("ole32\CLSIDFromString", "wstr", sGUID, "ptr", &GUID) >= 0 ? &GUID : ""
}

11

Re: AHK: Sciter

Malcev, у вас ,случаем, не x64? Поскольку, ни первый вариант("свежая" тема), ни второй у меня не работает.

P.S. запускаю TheLibrary.exe и вылазит окно о несовместимых версиях винды, что уже намекает.

12

Re: AHK: Sciter

Сообщение исключения:

0x80131604 -
Source: mscorlib
Description: Адресат вызова создал исключение.
HelpFile: (null)
HelpContext: 0

https://c.radikal.ru/c17/1904/79/c49a2d62f937.png
Win 7 x64 со всеми обновлениями, AHK x32 v1.1.30.03.
.NET framework v4.7 обновлён.

TheLibrary.exe запускается нормально.

13 (изменено: Malcev, 2019-04-22 15:38:59)

Re: AHK: Sciter

KusochekDobra, у меня такая же система, как и у вас.
.NET framework v4.72 с четырьмя апдейтами.
TheLibrary.exe запускается, но ничего не происходит.

14

Re: AHK: Sciter

У меня так выглядит запущенная "TheLibrary.exe":
https://c.radikal.ru/c11/1904/39/3608ada1cdbe.png

Странная ошибка, какая-то. Толком ничего в поиске не могу найти.

15

Re: AHK: Sciter

Понял причину.
Для запуска нужно поместить в ту же  директорию sciter.dll отсюда:
https://sciter.com/download/

16

Re: AHK: Sciter

Вы говорите о запуске "TheLibrary.exe"?
Если так, то при первом старте, программа просит указать папку с SDK и в этом же сообщении предлагает его скачать с этой страницы.

17

Re: AHK: Sciter

У library.exe более старая scite.dll, которая у меня подхватывается library.exe, но не работает в связке ahk + SciterSharpWindows.dll.
А работает scite.dll из оригинального дистрибутива.

18

Re: AHK: Sciter

Мой низкий поклон за Вашу наблюдательность!
Теперь работает.