AHK: Управление окнами мышкой

CoordMode, Mouse
SetBatchLines, -1
Return

#If PressedButton := GetPressedButton()
LButton::Return

#If PressedButton
LButton Up::
   for key, var in ["left", "top", "right", "bottom"]
      %var% := PressedButton.Pos[key]
   button := PressedButton.Name, hWin := PressedButton.hWin, PressedButton := ""
   
   MouseGetPos, X, Y
   if (X >= left && X <= right && Y >= top && Y <= bottom)
   {  ; здесь вместо сообщения действия в зависимости от значения button и hWin
      MsgBox, % "Была нажата кнопка " button " в окне " hWin
   }
   Return

#If
Esc:: ExitApp

GetPressedButton()
{
   MouseGetPos, X_Mouse, Y_Mouse, hWin
   VarSetCapacity(TITLEBARINFO, 140, 0)
   NumPut(140, TITLEBARINFO)
   SendMessage, WM_GETTITLEBARINFOEX := 0x33F,, &TITLEBARINFO,, ahk_id %hWin%
   
   for button, offset in {Min: 76, Max: 92, Close: 124}
   {
      pos := []
      loop 4
         pos[A_Index] := NumGet(&TITLEBARINFO + offset + 4*(A_Index - 1), "UInt")
      
      if (X_Mouse >= pos[1] && X_Mouse <= pos[3] && Y_Mouse >= pos[2] && Y_Mouse <= pos[4])
         Return {Name: button, Pos: pos, hWin: hWin}
   }
}

#Persistent ; Делает скрипт постоянно выполняющимся
WM_NCHITTEST(){ ;Функция используется для определения области, над которой находится указатель.
   CoordMode, Mouse, Screen ;Влияет на MouseGetPos.Координаты будут относительно экрана.
   MouseGetPos, x, y, z ; x-y определение позиции курсора. z hwnd окна над которым находится курсор.
   SendMessage, 0x84, 0, (x&0xFFFF)|(y&0xFFFF)<<16,, ahk_id %z% ; Отправляет сообщение WM_NCHITTEST окну который находится по курсором.
  Return Errorlevel ; Ответ функции равен ответу оконного сообщения.
}
#if (WM_NCHITTEST:=WM_NCHITTEST()) and (WM_NCHITTEST=8) or (WM_NCHITTEST=9) or (WM_NCHITTEST=20) ; # - позволяет проверять постоянно, изменяется ли значение функции выше. 
;  [  (WM_NCHITTEST:=WM_NCHITTEST())  ] Функция переводится в переменную. Что бы не вызывать её несколько раз за цикл.
;  [ (WM_NCHITTEST=8) or (WM_NCHITTEST=9) or (WM_NCHITTEST=20)  ] Если содержимое WM_NCHITTEST равно 8 или 9 или 20 условие истина.
; 8 - кнопка свернуть. 9 - кнопка развернуть. 20 - кнопка закрыть.
Lbutton::
Rbutton::
Mbutton::  ;  По нажатию любой из этих кнопок откроется msgbox.
msgbox % "Нажата " ( (WM_NCHITTEST=8) ? "свернуть" : ((WM_NCHITTEST=9) ? "развернуть" : ((WM_NCHITTEST=20) ? "закрыть" : "" ))) " " ((A_ThisHotkey="Lbutton") ? "левой" : ((A_ThisHotkey="Rbutton") ? "правой" : ((A_ThisHotkey="Mbutton") ? "средней" : ""))) " клавишей."
; Если WM_NCHITTEST будет равным 8 то покажет надпись "свернуть",а если нет то проверит следующее условие равно ли 9, если да то надпись будет "развернуть". Или нет то проверит 3й раз равно ли 20. если да то надпись будет "закрыть"
; с нажатиями клавиш мыши аналогично.
#if

#Persistent ; Делает скрипт постоянно выполняющимся

#If res := NCHITTEST()
RButton::
MButton:: MsgBox, % "Нажата " A_ThisHotkey " над " res
#If
Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

#If res := NCHITTEST()
RButton::
   if (res = "MINBUTTON")  {
      MsgBox, Здесь действие при нажатии RButton над кнопкой «Свернуть»
   }
   else if (res = "CLOSE")  {
      MsgBox, Здесь действие при нажатии RButton над кнопкой «Закрыть»
   }
   Return
   
MButton::
   if (res = "MINBUTTON")  {
      MsgBox, Здесь действие при нажатии MButton над кнопкой «Свернуть»
   }
   else if (res = "CLOSE")  {
      MsgBox, Здесь действие при нажатии MButton над кнопкой «Закрыть»
   }
   Return
   
#If
Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

#NoEnv
#If res := NCHITTEST()
RButton::
MButton::
   try Gosub %A_ThisHotkey%_%res%
#If
Return

RButton_MINBUTTON:
   MsgBox, Здесь действие при нажатии RButton над кнопкой «Свернуть»
Return
RButton_CLOSE:
   MsgBox, Здесь действие при нажатии RButton над кнопкой «Закрыть»
Return
MButton_MINBUTTON:
   MsgBox, Здесь действие при нажатии MButton над кнопкой «Свернуть»
Return
MButton_CLOSE:
   MsgBox, Здесь действие при нажатии MButton над кнопкой «Закрыть»
Return

Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}