1

Тема: AHK: Выход из спящего режима

Возможно ли как-то по таймеру (расписанию) с помощью скрипта выйти из спящего режима?

По вопросам возмездной помощи пишите на E-Mail: serzh82saratov@mail.ru Telegram: https://t.me/sergiol982
Win10x64 AhkSpy, Hotkey, ClockGui

2

Re: AHK: Выход из спящего режима

Вроде можно устанавливать таймер пробуждения. Сам не пробовал, просто в поисковике задал вопрос.

Как посмотреть все таймеры пробуждения в Windows 8.1 и 10
Самовключение или пробуждение Windows 10

Насколько я понимаю, во время сна все процессы замораживаются.

3

Re: AHK: Выход из спящего режима

SleepTime := 60    ; время в сна секундах
SleepMode := true  ; true — гибернация, false — сон

hTimer := DllCall("CreateWaitableTimer", "Ptr", 0, "UInt", 0, "Str", "MyTimer", "Ptr")
DllCall("SetWaitableTimer", "Ptr", hTimer, "Int64P", -SleepTime*10000000, "UInt", 0, "Ptr", 0, "Ptr", 0, "UInt", 1)
if (A_LastError = 50) {; ERROR_NOT_SUPPORTED
	DllCall("CloseHandle", "Ptr", hTimer)
	MsgBox, Этот компьютер не поддерживает пробуждение по таймеру!
	Return
}
DllCall("PowrProf\SetSuspendState", "UInt", SleepMode, "UInt", 0, "UInt", 0)
DllCall("WaitForSingleObject", "Ptr", hTimer, "UInt", INFINITE := 0xFFFFFFFF)
DllCall("CloseHandle", "Ptr", hTimer)
Return

Если не нужно сразу же отправлять в сон, закомментируй строку

DllCall("PowrProf\SetSuspendState", "UInt", SleepMode, "UInt", 0, "UInt", 0)
Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder