1 (изменено: cffgmntl, 2020-12-26 14:41:03)

Тема: AHK: Переключение

Привет, есть такой вопрос возможно ли сделать так допустим у меня есть 2 переключателя в gui, и бинд "Hotkey", так вот возможно сделать чтобы при выборе одного из переключателей он активировался биндом "Hotkey"?





Надеюсь более менее понятно объяснил, буду рад любой вашей помощи)

2

Re: AHK: Переключение

Примерно так:

#SingleInstance Force
#NoEnv
; Устанавливаем клавишам действия:
Hotkey, F1, Start, Off
Hotkey, F2, Start, Off
Hotkey, F5, Start2, Off
Hotkey, F6, Start2, Off

Gui Add, Radio, gTest vKeyRadio x8 y8 w120 h23, 1 вариант
Gui Add, Radio, gTest x136 y8 w120 h23, 2 вариант
Gui Add, Text, x8 y48 w180 h23 HWNDhText, Активных клавиш нет.

Gui Show, w272 h82	; Отобразить окно.
Return

; Метка выполняется при выборе Radio-кнопки и вкл./выкл. хоткеи. +меняет текст для наглядности.
Test:
Gui, Submit, NoHide	; Получить переменные из Gui окна, не сворачивать его.

If (KeyRadio = 1)
{
 GuiControl,, %hText%, Активные клавиши: F1`, F2
 Hotkey, F1, Start, On		; Включить перехват.
 Hotkey, F2, Start, On
 Hotkey, F5, Start2, Off	; Выкл. перехват.
 Hotkey, F6, Start2, Off
}
If (KeyRadio = 2)
{
 GuiControl,, %hText%, Активные клавиши: F5`, F6
 Hotkey, F1, Start, Off
 Hotkey, F2, Start, Off
 Hotkey, F5, Start2, On
 Hotkey, F6, Start2, On
}
Return


Start:
ToolTip, Действия #1: %A_ThisLabel%`nКлавиша: %A_ThisHotkey%
Return

Start2:
ToolTip, Действия #2: %A_ThisLabel%`nКлавиша: %A_ThisHotkey%
Return

; При закрытии окна - закрывает скрипт:
GuiEscape:
GuiClose:
ExitApp

3

Re: AHK: Переключение

__Михаил__

Спасибо, это именно то что я искал)