1 (изменено: alex16uk, 2022-08-05 16:28:04)

Тема: AHK: Помогите сделать скриншот

Мне нужно что бы AHK сохранило скриншот с экрана и сохранил в папку ( всего экрана без выбора зоны и подобного ).

2 (изменено: alex16uk, 2022-08-05 16:27:51)

Re: AHK: Помогите сделать скриншот

Заранее спасибо.

3

Re: AHK: Помогите сделать скриншот

...

4

Re: AHK: Помогите сделать скриншот

Foma, what the fuck?
alex16uk, добро пожаловать на форум! Ознакомьтесь, пожалуйста, с Правилами, отредактируйте свой пост. Обратите внимание на заглавные буквы в начале и точки в конце предложений.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

5

Re: AHK: Помогите сделать скриншот

alex16uk, уже лучше. Ещё есть правило: одна тема — один вопрос. Так что выбирайте основной, для остальных создавайте новые темы, тем более, что вопросы никак не связаны.

alex16uk пишет:

Мне нужно что бы AHK сохранило скриншот с экрана и сохранил в папку

Я бы советовал воспользоваться поиском по форуму. Также у нас есть Коммерческий раздел, заказы лучше размещать там.

Разработка AHK-скриптов:
e-mail dfiveg@mail.ru
Telegram jollycoder

6

Re: AHK: Помогите сделать скриншот

alex16uk

screenshot:=(A_ScriptDir . "\screenshot.png")
SaveScreenshotToFile(0, 0, A_ScreenWidth, A_ScreenHeight, screenshot)

SaveScreenshotToFile(x, y, w, h, filePath)
{
	hBitmap := GetHBitmapFromScreen(x, y, w, h)
	gdip := new GDIplus
	pBitmap := gdip.BitmapFromHBitmap(hBitmap)
	DllCall("DeleteObject", Ptr, hBitmap)
	gdip.SaveBitmapToFile(pBitmap, filePath)
	gdip.DisposeImage(pBitmap)
}

GetHBitmapFromScreen(x, y, w, h)
{
	hDC := DllCall("GetDC", Ptr, 0, Ptr)
	hBM := DllCall("CreateCompatibleBitmap", Ptr, hDC, Int, w, Int, h, Ptr)
	pDC := DllCall("CreateCompatibleDC", Ptr, hDC, Ptr)
	oBM := DllCall("SelectObject", Ptr, pDC, Ptr, hBM, Ptr)
	DllCall("BitBlt", Ptr, pDC, Int, 0, Int, 0, Int, w, Int, h, Ptr, hDC, Int, x, Int, y, UInt, 0x00CC0020)
	DllCall("SelectObject", Ptr, pDC, Ptr, oBM)
	DllCall("DeleteDC", Ptr, pDC)
	DllCall("ReleaseDC", Ptr, 0, Ptr, hDC)
	Return hBM
}

class GDIplus   {
	__New()  {
		if !DllCall("GetModuleHandle", Str, "gdiplus", Ptr)
			DllCall("LoadLibrary", Str, "gdiplus")
		VarSetCapacity(si, A_PtrSize = 8 ? 24 : 16, 0), si := Chr(1)
		DllCall("gdiplus\GdiplusStartup", PtrP, pToken, Ptr, &si, Ptr, 0)
		this.token := pToken
	}
	__Delete()  {
		DllCall("gdiplus\GdiplusShutdown", Ptr, this.token)
		if hModule := DllCall("GetModuleHandle", Str, "gdiplus", Ptr)
			DllCall("FreeLibrary", Ptr, hModule)
	}
	BitmapFromHBitmap(hBitmap, Palette := 0)  {
		DllCall("gdiplus\GdipCreateBitmapFromHBITMAP", Ptr, hBitmap, Ptr, Palette, PtrP, pBitmap)
		return pBitmap
	}
	SaveBitmapToFile(pBitmap, sOutput, Quality=75)  {
		SplitPath, sOutput,,, Extension
		if Extension not in BMP,DIB,RLE,JPG,JPEG,JPE,JFIF,GIF,TIF,TIFF,PNG
			return -1
		DllCall("gdiplus\GdipGetImageEncodersSize", UIntP, nCount, UIntP, nSize)
		VarSetCapacity(ci, nSize)
		DllCall("gdiplus\GdipGetImageEncoders", UInt, nCount, UInt, nSize, Ptr, &ci)
		if !(nCount && nSize)
			return -2
		Loop, % nCount  {
			sString := StrGet(NumGet(ci, (idx := (48+7*A_PtrSize)*(A_Index-1))+32+3*A_PtrSize), "UTF-16")
			if !InStr(sString, "*." Extension)
				continue
			pCodec := &ci+idx
			break
		}
		if !pCodec
			return -3
		if RegExMatch(Extension, "i)^J(PG|PEG|PE|FIF)$") && Quality != 75  {
			DllCall("gdiplus\GdipGetEncoderParameterListSize", Ptr, pBitmap, Ptr, pCodec, UintP, nSize)
			VarSetCapacity(EncoderParameters, nSize, 0)
			DllCall("gdiplus\GdipGetEncoderParameterList", Ptr, pBitmap, Ptr, pCodec, UInt, nSize, Ptr, &EncoderParameters)
			Loop, % NumGet(EncoderParameters, "UInt")  {
				elem := (24+A_PtrSize)*(A_Index-1) + 4 + (pad := A_PtrSize = 8 ? 4 : 0)
				if (NumGet(EncoderParameters, elem+16, "UInt") = 1) && (NumGet(EncoderParameters, elem+20, "UInt") = 6)  {
					p := elem+&EncoderParameters-pad-4
					NumPut(Quality, NumGet(NumPut(4, NumPut(1, p+0)+20, "UInt")), "UInt")
					break
				}
			}
		}
		if A_IsUnicode
			pOutput := &sOutput
		else  {
			VarSetCapacity(wOutput, StrPut(sOutput, "UTF-16")*2, 0)
			StrPut(sOutput, &wOutput, "UTF-16")
			pOutput := &wOutput
		}
		E := DllCall("gdiplus\GdipSaveImageToFile", Ptr, pBitmap, Ptr, pOutput, Ptr, pCodec, UInt, p ? p : 0)
		return E ? -5 : 0
	}
	DisposeImage(pBitmap)  {
		return DllCall("gdiplus\GdipDisposeImage", Ptr, pBitmap)
	}
}
Return

7

Re: AHK: Помогите сделать скриншот

Clannad5 А как сделать что бы он сохранял скриншот где в название время скрина а не screenshot?

8

Re: AHK: Помогите сделать скриншот

alex16uk
Для этого вам нужно получать текущую дату, а далее указывать в строчке за место имени "screenshot.png" - переменную, которая будет содержать дату:

screenshot:=(A_ScriptDir . "\screenshot.png")