AHK: Передача информиции на хостинг текста

#Requires AutoHotkey v2.0

devKey := '183696cd98add6e21cdd53587a1987fb' ; сюда вставьте ваш ключ, этот не будет работать

pasteTitle := 'My paste'
pasteContent := '
(
    Hello, World!
    This is my first paste.
)'
url := 'https://pastebin.com/api/api_post.php'
headers := Map('Content-Type', 'application/x-www-form-urlencoded')

MsgBox A_Clipboard := WebRequest(url, 'POST', headers,,
      'api_option=paste'
    . '&api_dev_key=' . devKey
    . '&api_paste_name=' . EncodeDecodeURI(pasteTitle)
    . '&api_paste_code=' . EncodeDecodeURI(pasteContent))

WebRequest(url, method := 'GET', HeadersMap := '', binary := false, body?, &status?) {
    Whr := ComObject('WinHttp.WinHttpRequest.5.1')
    Whr.Open(method, url, true)
    if HeadersMap is Map {
        for name, value in HeadersMap
            Whr.SetRequestHeader(name, value)
    }
    Whr.Send(body ?? '')
    Whr.WaitForResponse()
    status := Whr.status
    SafeArray := Whr.responseBody
    pData := NumGet(ComObjValue(SafeArray) + 8 + A_PtrSize, 'Ptr')
    length := SafeArray.MaxIndex() + 1
    if !binary {
        return StrGet(pData, length, 'UTF-8')
    }
    DllCall('RtlMoveMemory', 'Ptr', data := Buffer(length), 'Ptr', pData, 'Ptr', length)
    return data
}

EncodeDecodeURI(str, encode := true, component := true) {
    static Doc := '', JS := ''
    if !Doc {
        Doc := ComObject('htmlfile')
        Doc.write('<meta http-equiv="X-UA-Compatible" content="IE=9">')
        JS := Doc.parentWindow
        (Doc.documentMode < 9 && JS.execScript())
    }
    Return JS.%(encode ? 'en' : 'de') . 'codeURI' . (component ? 'Component' : '')%(str)
}