1

Тема: VBS: Переход по гиперссылке, у которой меняется адрес

Здравствуйте, возможно кто то сталкивался с вредным сайтом Spamhaus.
Он блокирует почту у нашей компании ежедневно. для разбана необходимо ежедневно кликать по ссылке на их сайте.
внешне она выглядит так "Click on this link to delist 31.200.192.111"
но адрес у неё всегда разный.

2

Re: VBS: Переход по гиперссылке, у которой меняется адрес

всё было бы прекрасно если бы ссылка не менялась, и работало то что я нахимичил. но увы.

Set objIE = CreateObject("InternetExplorer.Application")
objIE.Visible = False
::здесь та и проблема, ссылка не постоянна!
objIE.Navigate "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&timestamp=1413179590&hash=2637a1436e605ca631c46cd326745252"
WScript.Sleep 6000
set WshShell = WScript.CreateObject("WScript.Shell")

WshShell.Run "taskkill /f /IM iexplore.exe"
MsgBox "В течении 10 минут почта заработает "

3

Re: VBS: Переход по гиперссылке, у которой меняется адрес

для разбана необходимо ежедневно кликать по ссылке на их сайте.

Адрес страницы, где находится ссылка, откуда узнаёте?

4

Re: VBS: Переход по гиперссылке, у которой меняется адрес

http://www.spamhaus.org/query/ip/31.200.192.111
когда банят почту третья строка "31.200.192.111 is not listed in the XBL" выделена красным
и ниже неё появляется ссылка
Click on this link to delist 31.200.192.111

5

Re: VBS: Переход по гиперссылке, у которой меняется адрес

Надо дождаться, когда забанят и посмотреть на эту ссылку в DOM — как она выглядит «изнутри».

6 (изменено: sqraen, 2014-10-21 13:22:53)

Re: VBS: Переход по гиперссылке, у которой меняется адрес

http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&timestamp=1413868434&hash=94b699716e8cf99b78caca5861307792

7

Re: VBS: Переход по гиперссылке, у которой меняется адрес

sqraen, «изнутри» — это так:

<a href="http://forum.script-coding.com/viewtopic.php?id=10070">создать VBS переходящий по гиперссылке, у которой меняется адрес</a>

или так:

<a href="http://rusfolder.com/control/?file_id=25576605&amp;code=516a0d58fdedb89fcedcdc246e0bed73d" target="_blank">Управление файлом</a>

или вовсе генерироваться на лету.

8

Re: VBS: Переход по гиперссылке, у которой меняется адрес

первый вариант, оно самое!
адрес ссылки сгенерирован с момента бана
и остаётся постоянным до нажатия,
при следующем бане, ссылка уже имеет другие значения (цифры) вконце

9

Re: VBS: Переход по гиперссылке, у которой меняется адрес

Что ж, попробуйте:

Option Explicit

Const READYSTATE_COMPLETE = 4


Dim strHRefPart

Dim objHTMLAnchorElement
Dim boolFound


strHRefPart = "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&timestamp="

With WScript.CreateObject("InternetExplorer.Application")
    .Visible = True
    .Navigate "http://www.spamhaus.org/query/ip/31.200.192.111"
    
    Do
        WScript.Sleep 100
    Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
    
    boolFound = False
    
    For Each objHTMLAnchorElement In .Document.getElementsByTagName("a")
        If InStr(1, objHTMLAnchorElement.href, strHRefPart, vbTextCompare) > 0 Then
            objHTMLAnchorElement.click
            boolFound = True
            
            Exit For
        End If
    Next
    
    '.Quit
End With

If Not boolFound Then
    WScript.Echo "Can't find anchor with href part [" & strHRefPart & "]."
    WScript.Quit 1
End If

WScript.Quit 0

При удаче — раскомментируйте «'.Quit» и смените «.Visible = True» на «.Visible = False».

10 (изменено: sqraen, 2014-10-21 15:57:37)

Re: VBS: Переход по гиперссылке, у которой меняется адрес

огромное спасибо за помощ
но к сожалению не вышло,
---------------------------
Windows Script Host
---------------------------
Can't find anchor with href part [http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&timestamp=].
---------------------------
ОК   
---------------------------
дело в том что я пока что не в чёрном листе (бан)
я пробовал на сохранённой странице в htm
страница открывается но выдаёт ошибку я так понял о том что ссылка не найдена для клика
может вам будет удобней почь мне так:
я скинул в архив страницу в htm и ваш vbs с изменённым пётём .Navigate "***.htm"
https://cloud.mail.ru/public/ad79a7ae64b7%2Fspam.rar

Заранее благодарен!

11

Re: VBS: Переход по гиперссылке, у которой меняется адрес

дело в том что я пока что не в чёрном листе (бан)

Ну, естественно. Попадёте — проверите и отпишетесь.

12

Re: VBS: Переход по гиперссылке, у которой меняется адрес

sqraen, пишите грамотно. Ссылки и код оформляйте специальными тегами. Исправьте Ваши сообщения.

13

Re: VBS: Переход по гиперссылке, у которой меняется адрес

Попал, проверил, не работает.
ошибка идентичная

14

Re: VBS: Переход по гиперссылке, у которой меняется адрес

sqraen, а причину "бана" Вы не знаете ? Судя по названию сайт блокирует тех, кто занимается "спамом".

P.S Почитал подробнее.

Роскомнадзор о Spamhaus

Spamhaus не задумываясь скинет на Вас ядерную бомбу, заподозрив в причастности к рассылки спама

Мда. "Компашка" ещё та. Но раз так, то может всё-таки попробовать предотвратить блокировку, нежели всё время пытаться разблокировать.

P.P.S

Один из участников обсуждения рекомендует:

qxfusion пишет:

Добавляетесь в Whitelist — прописываете SPF, DKIM для домена — и тогда SpamHaus не будет производить блокирование — т.к. это левый отправитель.

ссылка

Передумал переделывать мир. Пашет и так, ну и ладно. Сделаю лучше свой !

15

Re: VBS: Переход по гиперссылке, у которой меняется адрес

sqraen пишет:

Попал, проверил, не работает.

Ну, а сняли-то зачем? Мне ж надо было посмотреть.

Ладно. Попробуйте заменить строку:

strHRefPart = "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&timestamp="

на:

strHRefPart = "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111&amp;timestamp="

16

Re: VBS: Переход по гиперссылке, у которой меняется адрес

АААА дАААААААА!!!!!!
всё отлично получилось!!!
огромное спасибо!!!!!
alexii - с самого начала у тебя всё правильно было! по какой то причине он не мог найти параметр "strHRefPart"
Я видо изменил адрес, уменьшил и всё получилось!!
вот в каком виде всё работает:


+ открыть спойлер

Option Explicit

Const READYSTATE_COMPLETE = 4


Dim strHRefPart

Dim objHTMLAnchorElement
Dim boolFound


strHRefPart = "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111"

With WScript.CreateObject("InternetExplorer.Application")
    .Visible = True
    .Navigate "http://www.spamhaus.org/query/ip/31.200.192.111"
   
    Do
        WScript.Sleep 100
    Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
   
    boolFound = False
   
    For Each objHTMLAnchorElement In .Document.getElementsByTagName("a")
        If InStr(1, objHTMLAnchorElement.href, strHRefPart, vbTextCompare) > 0 Then
            objHTMLAnchorElement.click
            boolFound = True
           
            Exit For
        End If
    Next
   
    '.Quit
End With

If Not boolFound Then
    WScript.Echo "Can't find anchor with href part [" & strHRefPart & "]."
    WScript.Quit 1
End If

WScript.Quit 0

17

Re: VBS: Переход по гиперссылке, у которой меняется адрес

а как сделать что бы по окончании выполнения скрипта
iexplore в процессах не висел?

18

Re: VBS: Переход по гиперссылке, у которой меняется адрес

sqraen пишет:

по какой то причине он не мог найти параметр "strHRefPart"

Потому что в оригинале символ «&» представлен как «&amp;», о чём я и написал в сообщении #15.

sqraen пишет:

как сделать что бы по окончании выполнения скрипта iexplore в процессах не висел?

См. выше:

alexii пишет:

При удаче — раскомментируйте «'.Quit» и смените «.Visible = True» на «.Visible = False».

19

Re: VBS: Переход по гиперссылке, у которой меняется адрес

Пробовал поменять &amp; как вы писали! не получилось! осталась та же ошибка
и решил вовсе урезать, и тогда вышло)
False  - я поменял, вся работа iexplore свёрнута.
поясните пожалуйста что означает: раскомментируйте «'.Quit»

20 (изменено: sqraen, 2014-10-22 15:01:57)

Re: VBS: Переход по гиперссылке, у которой меняется адрес

ок, всё, догадался! Спасибо ещё раз огромное всё получилось!!!

Option Explicit
Const READYSTATE_COMPLETE = 4

Dim strHRefPart
Dim objHTMLAnchorElement
Dim boolFound

strHRefPart = "http://cbl.abuseat.org/removea.cgi?ip=31.200.192.111"
With WScript.CreateObject("InternetExplorer.Application")
    .Visible = False
    .Navigate "http://www.spamhaus.org/query/ip/31.200.192.111"
    
    Do
        WScript.Sleep 100
    Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
    
    boolFound = False
    
    For Each objHTMLAnchorElement In .Document.getElementsByTagName("a")
        If InStr(1, objHTMLAnchorElement.href, strHRefPart, vbTextCompare) > 0 Then
            objHTMLAnchorElement.click
            boolFound = True
            
            Exit For
        End If
    Next
    
    .Quit
End With
If Not boolFound Then
    WScript.Echo "Can't find anchor with href part [" & strHRefPart & "]."
    WScript.Quit 1
End If
WScript.Quit 0

21

Re: VBS: Переход по гиперссылке, у которой меняется адрес

Пробовал поменять &amp; как вы писали! не получилось! осталась та же ошибка

Ну, тогда только смотреть на реальную страницу, как оно выглядит. Либо ещё обрезать, как Вы сделали:

и решил вовсе урезать, и тогда вышло)