AHK: Как изменить время и дату в системе?

; Параметры, которые хотим изменить
Day := 8    ; число от 1 до 31
Hour := 17  ; число от 1 до 23
Min := 30   ; число от 1 до 59

; Получаем текущие настройки времени
VarSetCapacity(SYSTEMTIME, 16)
DllCall("GetLocalTime", Ptr, &SYSTEMTIME)

; Изменяем необходимые параметры, заполняя нужные поля структуры SYSTEMTIME в соответствии с описанием:
; http://msdn.microsoft.com/en-us/library/windows/desktop/ms724950%28v=vs.85%29.aspx
NumPut(Day, SYSTEMTIME, 6, "UShort")
NumPut(Hour, SYSTEMTIME, 8, "UShort")
NumPut(Min, SYSTEMTIME, 10, "UShort")

if !DllCall("SetLocalTime", Ptr, &SYSTEMTIME)
   MsgBox, Не удалось установить время. Ошибка %A_LastError%
Return

; указываем только те параметры, которые хотим изменить, остальные ""
oTime := { year:  ""    ; число от 1601 до 30827
         , month: 1     ; 1 — 12
         , day:   8     ; 1 — 31
         , hour:  17    ; 0 — 23
         , min:   30    ; 0 — 59
         , sec:   "" }  ; 0 — 59

StartTickCount := A_TickCount
StartTime := GetLocalTime()   ; в переменной StartTime время начала работы скрипта в формате YYYYMMDDHH24MISS

ChangeLocalTime(oTime)     ; изменяем параметры, указанные в oTime
OnExit, Exit
Return

Exit:
   RetrieveLocalTime(StartTime, StartTickCount)   ; при выходе возвращаем настройки с учётом прошедшего времени
   ExitApp
         
Esc:: ExitApp

GetLocalTime()
{
   pSYSTEMTIME := GetLocalTimeStruct()   ; Получаем текущие настройки времени
   Loop 6   ; Преобразуем их в формат YYYYMMDDHH24MISS
   {
      num := NumGet(pSYSTEMTIME + 2*(A_Index - (A_Index < 3 ? 1 : 0)), "UShort")
      TimeFormatVar .= (A_Index = 1 ? num : SubStr("0" . num, -1))
   }
   Return TimeFormatVar
}

ChangeLocalTime(oTime)
{
   pSYSTEMTIME := GetLocalTimeStruct()   ; Получаем текущие настройки времени
   
   for k, v in ["year", "month", "day", "hour", "min", "sec"]    ; Изменяем необходимые параметры
      if (oTime[v] != "")
         NumPut(oTime[v], pSYSTEMTIME + 2*(A_Index - (A_Index < 3 ? 1 : 0)), "UShort")
   
   Return SetLocalTime(pSYSTEMTIME)   ; устанавливаем новое время
}

RetrieveLocalTime(Time, StartTickCount)
{
   Time += Round((A_TickCount - StartTickCount)/1000), Seconds   ; прибавляем разницу во времени с начала работы
   
   VarSetCapacity(SYSTEMTIME, 16)
   Loop 6
   {
      number := A_Index = 1 ? SubStr(Time, 1, 4) : SubStr(Time, 3 + 2*(A_Index - 1), 2)
      offset := A_Index = 1 ? 0 : 2*(A_Index - (A_Index = 2 ? 1 : 0))
      NumPut(number, SYSTEMTIME, offset, "UShort")
   }
   Return SetLocalTime(&SYSTEMTIME)
}

GetLocalTimeStruct()
{
   static SYSTEMTIME
   VarSetCapacity(SYSTEMTIME, 16, 0)
   DllCall("GetLocalTime", Ptr, &SYSTEMTIME)
   Return &SYSTEMTIME
}

SetLocalTime(pSYSTEMTIME)
{
   Loop 2   
      if !DllCall("SetLocalTime", Ptr, pSYSTEMTIME) && Error := 1  {
         MsgBox, Не удалось установить время. Ошибка %A_LastError%
         break
      }
   Return !Error
}