Камера DJI Osmo Action 5 Pro кроме оригинального видео также создает файл с расширением .LRF, содержащий видео с меньшем разрешением (1280*720 30fps).

При работе с роликами в высоком разрешении в видеоредакторе Vegas может потребоваться создание прокси-файлов, то есть копий оригинального ролика с меньшем разрешением, чтобы не тормозил предпросмотр во время монтажа в самой программе. Vegas умеет создавать прокси, но это долго и муторно. Куда лучше использовать в качестве прокси уже имеющиеся файлы .LRF.

Пошаговая инструкция, как преобразовать .LRF в Proxy для Vegas:

1. Скачать утилиту ffmpeg для конвертации форматов - https://ffmpeg.org/download.html

2. Прописать путь к файлу ffmpeg.exe в переменные среды PATH: Откройте Параметры Windows (Win + I); Система → О программе → Дополнительные параметры системы; во вкладке "Дополнительно" нажмите "Переменные среды..."; в переменную Path добавить путь к папке с ffmpeg.

3. При копировании видео с камеры, скопировать в том числе и файлы с расширением .LRF

4. В папку, куда скопированы видео-файлы с камеры, скопировать файл Proxy.cmd (см. вложение, не забудьте достать его из zip-архива).

5. Запустить Proxy.cmd, дождаться завершения процесса (должны исчезнуть все черные окна). По итогу у вас появятся файлы с расширением .MP4.sfvp0, это и есть прокси для Vegas.

6. Дальше просто работаете в Vegas, она автоматически подтянет данные прокси. Чтобы в окне предпросмотра использовались прокси-файлы (а не оригинальные), выставите режим предпросмотра Preview (Full) или Half, если у вас все равно тормозит воспроизведение.

Шаги 1 и 2 проделываются один раз, в последующем они не требуются.

Важные замечания:

1. Во время создания прокси-файлов появится куча черных окошек (на каждый файл по одному окошку) и комп прилично нагрузится (как ЦП, так и видеокарта). Скорость процесса зависит от мощности вашего железа и количества файлов. Например, у меня порядка 100 файлов обрабатывались около 1 минуты 20 секунд.

2. Видеокарта NVidia! Для других карт надо поменять параметр GPU_ACCEL на amf для AMD и qsv для Intel. Но в этих режимах не тестировалось. Можно этому параметру присвоить пустое значение (тогда весь процесс пойдет через ЦП).

3. Этот скрипт также делает прокси и для видео с дрона Fimi X8 Mini (приятный бонус).

4. Тестировалось в VEGAS Pro 21.0.

5. В некоторых случаях возможна небольшая рассинхронизация прокси с оригиналом, особенно это касается таких FPS, как 48, 50, 100.

6. Прокси с гиперлапс-видео Vegas не принимает.

7. С таймлапс-видео прокси вообще отсутствует (можно сделать средствами самого Vegas).

:: ==============================================
:: Батник создания Proxy-файлов для VEGAS Pro 21.0 (и других версий)
:: Проверено по данным с камеры DJI Osmo Action 5 Pro и дрона Fimi X8 Mini
:: Для работы нужно установить ютилиту FFmpeg - https://ffmpeg.org/download.html
:: (c) Arigato Software, 2025
:: ==============================================

@echo off
setlocal enabledelayedexpansion

:: ==============================================
:: Конфигурация
:: ==============================================
:: Расширение прокси-файлов
set PROXY_EXT=MP4.sfvp0
:: Битрейт прокси
set BITRATE=12M
:: Ширина прокси
set WIDTH=1280
:: Высота прокси
set HEIGHT=720
:: GPU-ускорение (NVIDIA=cuda, AMD=amf, INTEL=qsv, CPU=пусто)
set GPU_ACCEL=cuda
:: Включение аудио в прокси (1=вкл, 0=выкл, для Vegas выкл!)
set INCLUDE_AUDIO=0

:: ==============================================
:: Обработка файлов *.LRV и *.LRF
:: ==============================================
echo [INFO] Create proxy files

:: Применяем параметры
if not "!GPU_ACCEL!"=="" set "GPU_ACCEL=-hwaccel !GPU_ACCEL!"
if !INCLUDE_AUDIO! equ 1 (
	set "INCLUDE_AUDIO=-c:a aac -b:a 128k"
) else (
	set "INCLUDE_AUDIO=-an"
)

:: Перебор всех .LRV и .LRF-файлов
for %%i in (*.LRV *.LRF) do (
	set "source_filename=%%~ni.MP4"
	set "proxy_filename=%%~ni.%PROXY_EXT%"
	echo !source_filename!
	
	:: Определяем FPS оригинала
	call :get_fps "!source_filename!" source_fps
	echo FPS: !source_fps!
	
	:: Получаем количество кадров
	call :frames "!source_filename!" frames
	echo Frames: !frames!
	
	:: Определяем поворот
	call :rotation "%%i" rotation_degrees
	if !rotation_degrees! neq 0 (
		echo Rotation: !rotation_degrees!
	)
	
	:: Выбираем фильтр поворота
	set "vf_rotate="
	if !rotation_degrees! equ 90 set "vf_rotate=transpose=1,"
	if !rotation_degrees! equ 180 set "vf_rotate=transpose=1,transpose=1,"
	if !rotation_degrees! equ 270 set "vf_rotate=transpose=2,"
	
	:: Запускаем кодирование
	start "!source_filename!" ffmpeg !GPU_ACCEL! -i "%%i" -y -c:v mpeg2video ^
		-b:v %BITRATE% ^
		!INCLUDE_AUDIO! ^
		-vf "!vf_rotate!scale=%WIDTH%:%HEIGHT%:force_original_aspect_ratio=decrease,setsar=1,fps=!source_fps!" ^
		-f mp4 -r !source_fps! ^
		-movflags faststart -timecode "00:00:00:00" ^
		-fps_mode cfr -frames:v !frames! ^
		"!proxy_filename!"
)

:: ==============================================
:: Завершение работы
:: ==============================================
echo [SUCCESS] OK
rem pause
exit /b 0

:: ==============================================
:: Функция определения количества кадров
:: %1 - файл, %2 - выходная переменная
:: ==============================================
:frames
setlocal
set "frames=0"
for /f %%f in (
	'ffprobe -v error -select_streams v:0 -show_entries stream^=nb_frames -of default^=nokey^=1:noprint_wrappers^=1 "%~1" 2^>^&1'
) do set "frames=%%f"
endlocal & set "%~2=%frames%"
exit /b 0

:: ==============================================
:: Функция определения поворота видео
:: %1 - файл, %2 - выходная переменная
:: ==============================================
:rotation
setlocal
set "rot=0"
for /f "tokens=2 delims==" %%r in (
	'ffprobe -v error -select_streams v:0 -show_entries stream_side_data^=rotation -of default^=nw^=1 "%~1"'
) do set "rot=%%r"

:: Нормализация отрицательных значений
if "!rot!"=="-90" set "rot=270"
if "!rot!"=="-180" set "rot=180"
if "!rot!"=="-270" set "rot=90"
endlocal & set "%~2=%rot%"
exit /b 0

:: ==============================================
:: Функция определения частоты кадров видео
:: %1 - файл, %2 - выходная переменная
:: Возвращает fps в формате "60000/1001" (59.94) или "30/1" (30.0)
:: ==============================================
:get_fps
setlocal
set "fps_value=0/0"
for /f "tokens=2 delims==" %%f in (
    'ffprobe -v error -select_streams v:0 -show_entries stream^=r_frame_rate -of default^=nw^=1 "%~1"'
) do (
    set "fps_value=%%f"
    :: Удаляем возможные кавычки
    set "fps_value=!fps_value:"=!"
)
endlocal & set "%~2=%fps_value%"
exit /b 0

P.S. Можно модифицировать скрипт для других видеоредакторов.

@ echo off
setlocal enabledelayedexpansion

pause
echo Звуковой сигнал №1
call :beep1

pause
echo Звуковой сигнал №2
call :beep2

exit /b

:: Звуковой сигнал через символ с кодом 7 (Alt + 07)
:beep1
setlocal
0<nul set /p =[BEL]
endlocal & exit /b

:: Звуковой сигнал через choice
:beep2
echo 0y | choice /c y /n>nul
exit /b

[BEL] - это непечатный символ с кодом 7. В форум его вставить нельзя, так что работающий пример качайте из вложения.

Подпрограмма beep1 выводит звук через символ с кодом 7.
Подпрограмма beep2 выводит звук через команду choice.

Не факт что везде будет работать, не проверял, но у меня оба метода работают и звуки разные.

Сигнал SOS

А вот и пример реализации сигнала SOS через звуки и мигание экраном:

@ echo off
setlocal enabledelayedexpansion

cls
title Сигнал SOS

:sos
call :M_S
call :M_O
call :M_S
call :pause 2
echo.
goto sos

exit /b

:: O: ---
:M_O
call :dash
call :dash
call :dash
exit /b

:: S: ...
:M_S
call :dot
call :dot
call :dot
exit /b

:: Точка (Морзе)
:dot
setlocal
0<nul set /p =.
color f0
call :beep2
color 07
endlocal & exit /b

:: Тире (Морзе)
:dash
setlocal
0<nul set /p =-
color f0
call :beep2
call :pause
color 07
endlocal & exit /b

:: Звуковой сигнал через choice
:beep2
echo 01 | choice /c 1 /n>nul
exit /b

:: Задержка в сек (0 - короткая задержка)
:pause
setlocal
set t=%1
if "%t%"=="" set t=0
timeout /t %t% >nul
endlocal & exit /b

Так как звук подается вызовом подпрограммы beep2, которая работает через choice, то и непечатных символов тут нет. Можно копировать код прямо с форума.

start /b имя.cmd

Параметр /b позволяет запустить скрипт имя.cmd в том же консольном окне, при этом основная программа продолжает выполнение, а имя.cmd работает совместно, разделяя с ней потоки ввода-вывода.

Вот такой пример. Батник main.cmd:

@echo off
setlocal enabledelayedexpansion

cls
set test_var=Hello, second
start /b second.cmd

FOR /L %%i IN (0,1,10) DO (
	echo Thread_1: %%i
	timeout /t 1 >nul
)

set test_var=Goodby, second
echo Thread_1 ending

Батник second.cmd:

@echo off

echo %test_var%

FOR /L %%i IN (0,1,10) DO (
	echo Thread_2: %%i
	timeout /t 2 >nul
)

echo Thread_2 ending
echo %test_var%

Виден параллельный вывод в одну и туже консоль. При этом имеется возможность "передать" все данные из основной программы в параллельный поток. В примере это переменная test_var. Однако в second.cmd создается лишь ее копия, то есть не получится менять значение переменной одного потока из другого.

Если все же надо наладить взаимодействие двух потоков, то придется использовать общий файл.

Где можно использовать на практике?

Например, команда choice не просто считывает нажатую клавишу, но и останавливает выполнение до того, пока пользователь не нажмет клавишу. Если нам надо отслеживать нажатые клавиши, при этом не тормозить основной поток, то обработку клавиатуры можно вынести в отдельный поток. Например:

@echo off
:loop
choice /c YN /n /cs
echo %errorlevel% > input.txt
goto loop

Нажатая клавиша окажется в файле input.txt (точнее ее порядковый номер в списке). От туда основной поток в нужный момент может произвести чтение, не останавливая своей работы на ожидание нажатия клавиши.

Это лишь один пример, можно придумать и другие способы применения подобной многопоточности.

О чем идет речь, подробнее читайте тут - Управляющие последовательности ANSI

Данная методика работает начиная с Windows 10.

Для управления выводом текста в консоль используются специальные ESC-коды. Выглядят они так:

ESC[<параметры><буква-команда>

ESC[ — признак начала управляющей последовательности. Непечатный символ с кодом 27 (U+001B). Набирается посредством Alt+27 или Alt+027, на экране выглядит как вопросик в квадрате или иначе, в зависимости от редактора.
<параметры> — цифры (иногда с ; ), указывают режим или количество.
<буква-команда> — финализирующий символ, указывающий какое именно действие.

Так как символ ESC непечатный, то не всегда удастся вставить код в сообщение, примеры надо качать из вложений.

Команда m задает цвет текста и фона (цвет задается или из палитры 16, или из палитры 256, или по RGB), различные начертания шрифта (подчеркнутый, жирный).

Цвета из палитры 16

Цвета из палитры 256

ESC[38;5;<n>m   → цвет текста
ESC[48;5;<n>m   → цвет фона

где <n> от 0 до 255.
0–7: базовые цвета
8–15: яркие
16–231: 6×6×6 RGB-куб
232–255: градации серого

Полноцветный (TrueColor, 24-бит)

ESC[38;2;R;G;Bm   → текст (R,G,B = 0–255)
ESC[48;2;R;G;Bm   → фон

Пример:

echo Оранжевый текст

Основные атрибуты

ESC[0m   → сброс атрибутов
ESC[1m   → жирный / яркий цвет
ESC[2m   → тусклый
ESC[3m   → курсив (обычно игнорируется)
ESC[4m   → подчёркивание
ESC[5m   → мигающий (обычно игнорируется)
ESC[7m   → инверсия
ESC[8m   → скрытый
ESC[9m   → зачёркнутый
ESC[22m  → отмена жирного/тусклого
ESC[24m  → отмена подчёркивания
ESC[27m  → отмена инверсии
ESC[30–37m  → цвет текста
ESC[40–47m  → цвет фона
ESC[90–97m  → яркие цвета текста
ESC[100–107m → яркие цвета фона
ESC[38;5;#m  → текст 256-цвет
ESC[48;5;#m  → фон 256-цвет
ESC[38;2;R;G;Bm → текст TrueColor (24-бит)
ESC[48;2;R;G;Bm → фон TrueColor (24-бит)

Работает далеко не все...

Комбинирование

Можно комбинировать через ;. Например:

подчёркнутый красный
жёлтый инверсный

Сброс всех атрибутов

ESC[0m   → сброс атрибутов

Очистка экрана

ESC[J    → очистка экрана (по умолчанию от курсора до конца)
ESC[0J   → от курсора до конца экрана
ESC[1J   → от начала экрана до курсора
ESC[2J   → весь экран
ESC[3J   → весь экран + буфер (если поддерживается)

ESC[K    → очистка строки (по умолчанию от курсора до конца)
ESC[0K   → от курсора до конца строки
ESC[1K   → от начала строки до курсора
ESC[2K   → вся строка

Управление курсором

ESC[#A   → вверх # строк
ESC[#B   → вниз # строк
ESC[#C   → вправо # колонок
ESC[#D   → влево # колонок
ESC[#E   → на начало строки, ниже на #
ESC[#F   → на начало строки, выше на #
ESC[#G   → в колонку #
ESC[H → курсор в левый верхний угол
ESC[#;#H → в строку;колонку (позиция курсора)
ESC[#;#f → то же самое (альтернативная форма)

ESC[s    → сохранить позицию курсора
ESC[u    → восстановить позицию курсора

ESC[?25l → скрыть курсор
ESC[?25h → показать курсор

ESC[6n   → выводит текущее положение курсора в формате ^[[n;mR, где n — строка, m — столбец. Ответ попадает в поток ввода. Пока непонятно, как его считать...

Прокрутка

ESC[#S    → прокрутить экран вверх на #
ESC[#T    → прокрутить экран вниз на #

Пример:

@echo off
echo Очистка экрана: 
echo Красный текст: Hello
echo Подчёркнутый: Text
echo Инверсия: Inverted

Более полная демка во вложении. Скрины демки:

Файл wat.cmd

@echo off
if not "%1"=="" (
	set attr=%~a1
	echo %attr%
)

:

Но вот так работает с первого:

@echo off
if not "%1"=="" (
	echo %~a1
)

@echo off
for /f "skip=1 tokens=2 delims==" %%A in ('wmic /namespace:\\root\wmi PATH MSAcpi_ThermalZoneTemperature get CurrentTemperature /value') do (
   set Kel=%%~A
)
set /a Deg=Kel*10-27315
set CPU_Temp=%Deg:~0,-2%.%Deg:~-2%
echo CPU temperature: %CPU_Temp% C

Батник надо запускать от администратора.

Надо в командной строке coздать архив и в файле (архиве) потом изменить (удалить, добавить) первые символы.
Создаю Архив:

"C:\Program Files\7-Zip\7z.exe" a password.7z password.txt -pP@$$w0rd

Пробовол удалить так первые 2 символа

...
<"password.7z" set /p sLine=>nul
echo %sLine:~2%>"password.7z.not_7z_file" 
more +1 "password.7z">>"password.7z.not_7z_file"
...

Но файл полностью меняется и не работает потом, если удаляю (добавляю) вручную в Notepad++, то все работает.

Как это автоматизировать?

Заранее благодарю.

7z¼¯' Ø4à       r       Õ<ÜWüË„¤¯:@õNÖ.’3
 
	 
 $ñ
Sã1?öáÝÒ«™¾r·HðÎ!!
 
  

²T&Y  

  p a s s w o r d . t x t    

 Ø‹TjŝÛ

       

p.s. без использования сторонних средств.

for f in "$@"; do
	/opt/homebrew/bin/ffmpeg -i "$f" -c:v libx265 -vtag hvc1 "$f".mp4
	/bin/rm "$f"
done;

Здравствуйте! Сценарий конвертирует видео и удаляет исходный файл. На выходе получаю файл с двойным расширением (~mp4.mp4). Как исключить расширение из названия исходного файла? На выходе файл должен иметь расширение .mp4, но на входе может быть .mov, .ts, .braw и т.д. Спасибо!

Суть такова:
Есть каталог на диске 1, есть каталог зеркала на диске 2, создаваемого с помощью BAT по средствам robocopy.
Хочу чтобы был дополнительный BAT который смотрит на каталог диска 1 сравнивая его с зеркалом каталога второго диска но поученный результат копировал в третий каталог своего рода версионность.
Суть идеи такова: с понедельника по пятницу работает пять BAT файлов для каждого дня недели, копирующих только те файлы которые были добавлены или изменены, в субботу же запускается основной BAT который очищает каталоги версий и делает новое зеркало.

Прежде чем создать топик я воспользовался поиском с запросом «robocopy» и «резервное копирование» просмотрев найденное нашел бизкое по теме, но не то что нужно.

На текущий момент мысли крутятся вокруг следующего кода:

@echo on
chcp 1251
setlocal enabledelayedexpansion

rem Параметры
set "sourceDir=A:\$SUR"
set "targetDir=A:\$TARGT"
set "backupDir=A:\$CEL"
set "logFile=A:\$log\robocopy.log"

rem Очистка лог-файла перед началом
echo. > "%logFile%"

rem Запуск robocopy для сравнения каталогов и записи изменений в лог-файл
robocopy "%sourceDir%" "%targetDir%" /E /L /FP /NJH /NJS /NDL /NS /NC /XO /XX /LOG:"%logFile%"

rem Показать содержимое лог-файла для проверки
echo Содержимое лог-файла:
type "%logFile%"

rem Чтение лога и копирование измененных файлов
for /f "tokens=*" %%i in ('type "%logFile%"') do (
    set "line=%%i"
    rem Удаление начальных пробелов
    set "filePath=!line:~14!"

    rem Проверка, что строка не пустая
    if not "!filePath!" == "" (
        echo Обработка файла: !filePath!

        rem Получение полного пути файла относительно исходного каталога
        set "relativeFilePath=!filePath:%sourceDir%\=!"

        rem Полный путь к файлу в целевом каталоге
        set "backupFile=%backupDir%\!relativeFilePath!"
        
        rem Директория файла в целевом каталоге
        set "backupFileDir=!backupFile!"
        for %%k in ("!backupFileDir!") do set "backupFileDir=%%~dpk"
        
        if not exist "!backupFileDir!" (
            echo Создание каталога: "!backupFileDir!"
            mkdir "!backupFileDir!"
        )

        echo Копирование файла: "%sourceDir%\!relativeFilePath!" в "!backupFileDir!"
        robocopy "%sourceDir%" "!backupFileDir!" "!relativeFilePath!" /COPYALL /R:0 /W:0

        echo Команда robocopy завершена с кодом ошибки: %ERRORLEVEL%
    )
)

echo Копирование измененных файлов завершено.
endlocal
pause

Но к сожалению не могу понять почему он не работает.
Лог файл создается измененные файлы туда заносятся но копирования не происходит, возможно у кого-то есть более здравая мысль как это реализовать корректнее и надежнее…
Также необходимо учитывать что robocopy взят по причине присутствия длинных имен и каталогов.

subst i: "d:\"

С последующим размонтированием, если всё прошло успешно.

subst i: /d

Как при возникновении ошибки и закрытии окна по клавише "Esc" или по крестику сделать так, чтобы созданный диск "subst" размонтировался?
Возможно ли прописать действия на условие закрытия окна внутри BAT файла?

Думал на внешнее решение - Планировщик Windows, но тогда ему надо как то передать букву диска.  Буква диска у меня в скрипте назначается автоматически из свободных, если существующий занят, поэтому на разных ПК буква может быть разная.

DEL /F /S /Q /A "C:\sudo\Videos\*.pdf"

после отработки в bat пишет:

файл удален c:\sudo\video\readme1.pdf
файл удален c:\sudo\video\readme2.pdf
файл удален c:\sudo\video\readme3.pdf

но фактически файлы на месте, не удалились.
Eсли пишу с записью в файл txt в ту же директорию.
Пример
myBat.bat> out.txt

пишет отказано в доступе.

Что делать?
Под виндой могу создавать файлы в терминале отказано в доступе и не работают комманды хотя bat отрабатывает но ни чего не происходит.
Пишет отказано в доступе.

Исходные данные
Есть каталог с файлами .txt. В каждом файле количество строк разное. Содержание каждого файла:

234324;Ссылка1
464565;Ссылка2
546456;Ссылка3
456456;Ссылка4
...
7899;СсылкаN

Что должен делать батник?
1. В каждом файле оставить только 3 первых строки, остальные удалить.
2. В каждом файле оставить только ссылки. Цифры, которые расположены перед ссылками и символ ";" удалить
3. Выбирать рандомно при каждом запуске 3 файла, склеивать данные и создавать новый файл с этими данными.

Что должно получиться в итоге?

При запуске батника должен получиться новый файл в таком виде:
Ссылка1
Ссылка2
Ссылка3

Ссылка4
Ссылка5
Ссылка6

Ссылка7
Ссылка8
Ссылка9

Всем заранее благодарен за помощь ибо своих сил и знаний не хватает для реализации.

chcp 1251
cd /d E:\\Videos
dir /b /d >>files.txt

Получается в итоге в файле files.txt так:

107.mp4
108.mp4

Нужно чтобы названия с маской создавались вот так!

file '107.mp4'
file '108.mp4'

Как такой батник соорудить?)))