Не согласен с примером. Дело тут совершенно не в "стрингах". В переменной js имеем объект с default  свойством ( функцией / методом), вызываемым по умолчанию. VarType обращается к нему и получает "результат". И уже по полученному результату делает вывод о данных. В данном случае, в этой переменной, находится объект JScriptTypeInfo. Его умолчательным методом, если я не ошибаюсь, является метод toString(), который и возвращает строку представляющую текущий объект.

TypeName работает иначе. Она берёт данные о типе содержимого из заголовка переменной Variant, в которой находятся данные (String / Long / Object / ...).

Рассмотрим пример:

Option Explicit
Dim oTest
Set oTest = new cCls

oTest.Value = 1
MsgBox VarType(oTest)

oTest.Value = "test"
MsgBox VarType(oTest)

Set oTest.Value = Me
MsgBox VarType(oTest)


Class cCls
    Public Value
    Public Default Property Get data
        if isObject(Value) Then
            Set data = Value
        Else
            data = Value
        End if
    End Property
End Class

Таким образом VarType(oTest) может быть любым из возвращаемых типов данных.
Но если возвращаемое значение String, то оно именно String, адекватно опознанный движком скрипта.
И разновидностей у него как таковых нет. Поэтому не совсем понимаю, какая необходимость в CStr у Вас возникла в первом примере и в последнем.

P.S Про мужские стринги тем более лучше умолчим )))

arr = Array("a","b")
Set SC = CreateObject("ScriptControl")
SC.Language = "JScript"
SC.AddCode("function VBArraySort(vbarray){return(new VBArray(vbarray).toArray().sort());}")
Set js = SC.Run("VBArraySort",arr)
WScript.Echo js & vbCr & "Подтип: " & VarType(js)
For Each item In js : WScript.Echo item : Next

P.P.S.: Бывают и мужские.

P.S В VBScript не зря сделали функции VarType и TypeName. Они дают возможность понять с чем Вы работаете.

P.P.S Или вы про другие "стринги" ? Женские в расчёт не берём. Это другая область. O_o

Так в том то и дело, что это никак не решает проблему преобразования. Проверьте. Смысла приводить его к CStr нет, так как метод и так возвращает String.

Не всегда верьте MSDN

Не знаю, проверил на 4-х машинах (SP2-SP4 Pro, SP3-2 Pro, SP3 Home), везде выдаёт отсутствие объекта.

Обратите внимание на мой пример, я там неспроста привожу значение к строковому типу по CStr.

Flasher,

Согласен. Буду исправляться.

Option Explicit
Dim sPath, oFile, i, vTmp
sPath = "C:\Image.jpg"
Set oFile = CreateObject("Scripting.FileSystemObject").GetFile(sPath)
With CreateObject("Shell.Application").NameSpace(oFile.ParentFolder.Path) 
    For Each i in Array(31,26)
        vTmp = .GetDetailsOf(.ParseName(oFile.Name),i)
        if InStr(1,vTmp,"x",1) > 0 Then
            vTmp = Split(Replace(vTmp," ",""),"x",2)
            MsgBox "Ширина: " & vTmp(0) & vbCrlf & "Высота: " & vTmp(1)
            Exit For
        End if
    Next
End With

Решил оформить в виде процедурки. Обнаружил неприятный момент. В Win 7 в строке присутствуют спец символы (на XP не обнаружил), которые не дают сделать преобразование полученных значений к числу. Так что без регулярки для выбора только чисел  (за помощь спасибо  JSman) не обошлось.

Option Explicit
Dim lWidth
Dim lHeight

GetImageWidth "C:\Image.jpg", lWidth, lHeight

MsgBox "Ширина: " & lWidth & vbCrlf & "Высота: " & lHeight

Sub GetImageWidth(sImagePath,lWidth,lHeight)
    Dim i, oFile, oRegExp
    Set oFile = CreateObject("Scripting.FileSystemObject").GetFile(sImagePath)
    With CreateObject("Shell.Application").NameSpace(oFile.ParentFolder.Path) 
        Set oRegExp = New RegExp
        oRegExp.Global = True
        oRegExp.Pattern = "[0-9]+"
        For Each i in Array(31,26)
            With oRegExp.Execute(.GetDetailsOf(.ParseName(oFile.Name),i)) 
                if .Count = 2 Then
                    lWidth = CLng(.Item(0))
                    lHeight = CLng(.Item(1))
                    Exit Sub
                End if
            End With
        Next
    End With
    Err.Raise vbObjectError + 1, "GetImageWidth", "Function failed."
End Sub

P.S Хотя конечно проверять по наличию "x" некорректно. Надо будет ещё подумать.

Неа. На MSDN - минимум Виста. Проверял на SP3.

Не всегда верьте MSDN: 1, 2.

Вот Вам оттуда же: Windows Image Acquisition (WIA) (Windows):

Для XP. Нужен как минимум SP1.

Неа. На MSDN - минимум Виста. Проверял на SP3.

На XP 26 вместо 31 (может, не везде).

Предлагаю перебирать свойства, проверяя его имя.

Для XP. Нужен как минимум SP1.

Ну, автор не уточнял под что пишем. Сюрприз будет.

Стремление к работоспособности на большинстве машин не мотивирует?

В первом варианте я бы всё же проверку добавил.
Либо по наличию " x " либо по "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CurrentVersion" > 5.1.

Ага. Вспомнил было дело.

Ну, автор не уточнял под что пишем. Сюрприз будет.

Решение очень удачное.

На XP 26 вместо 31 (может, не везде).

Вариант тоже не для XP.

Option Explicit
Dim sPath, oFile, aTmp
sPath = "C:\Image.jpg"
Set oFile = CreateObject("Scripting.FileSystemObject").GetFile(sPath)
With CreateObject("Shell.Application").NameSpace(oFile.ParentFolder.Path) 
    aTmp = Split(.GetDetailsOf(.ParseName(oFile.Name),31)," x ")
    MsgBox "Ширина: " & aTmp(0) & vbCrlf & "Высота: " & aTmp(1)
End With

Как вариант, можно ещё через WIA

Option Explicit

With CreateObject("WIA.ImageFile")
    .LoadFile "C:\Image.jpg"
    MsgBox .Width & "x" & .Height
End With

Или

Option Explicit

Dim oImg
Dim oHtmlDoc
Dim lPicWidth
Dim lPicHeight
Set oImg = LoadPicture("C:\Image.jpg")
Set oHtmlDoc = CreateObject("htmlfile")
With oHtmlDoc.parentWindow.screen
    lPicWidth = CLng(oImg.Width / 2540 * .deviceXDpi)
    lPicHeight = CLng(oImg.Height / 2540 * .deviceYDpi)
End With
MsgBox lPicWidth & "x" & lPicHeight