Серый форум — VBS:Как при помощи VBS получить текст из окна консольного приложения?

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Wed, 17 Dec 2014 07:38:09 +0000

После завершения всех действий кроме закрытия, разумеется.
Если консоль не требует скрытия, то зачем вообще какие-то иные окна?
Можно вводить данные через InputBox и передавать через WriteLine. Только нужно заведомо знать на каком этапе выводить информацию, знать число последующих строк.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 23:59:16 +0000

Но тут вы запускаете Exe.StdOut.ReadAll уже после завершения работы программы?

Дело в следующем.
Я сейчас ввожу в программу данные просто через эмуляцию ввода с клавиатуры и пауз WScript.Sleep t
В некоторый момент программа начинает расчёт, который может длиться 2 секунды, а может 20 минут. Я сейчас вычисляю требуемую паузу "на глазок". А вместо этого хотел следить, когда программа сообщит на экране об окончании расчёта, и затребует дальнейший ввод с клавиатуры.
Т. е. хотел циклически Do While… WScript.Sleep 100 :Loop проверять последнюю выведенную на экран строку.

С помощью варианта с WinAPI:ReadConsoleOutputCharacter вроде получается.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 23:41:58 +0000

+ Либо так:

n = 5 ' число последних строк

With CreateObject("WScript.Shell")
  If InStrRev(WScript.FullName, "WScript.exe") Then
    .Run "CScript.exe //NoLogo """ & WScript.ScriptFullName & """", 0
    WScript.Quit
  Else
    Set Exe = .Exec("RADMODLS.EXE")
    For i = 1 to 12 : Exe.StdIn.WriteLine "N" : Next
    All = Split(Exe.StdOut.ReadAll, vbnewline) : Max = Ubound(All)
    For i = Max - n to Max - 1 : S = S & vbNewLine & All(i) : Next
    .Popup Mid(S, 3)
  End If
End With

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 23:28:49 +0000

Ok.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 23:27:01 +0000

Сразу никак (точнее проблематично). Конкретно тут нужно подсчитать число пропускаемых строк сначала и пройтись циклом For/to, вызывая Exe.StdOut.SkipLine, а потом уже читать через ReadAll.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 23:08:29 +0000

А как в некоторый момент, до завершения работы программы, прочитать n последних символов вывода?
С помощью .StdOut.Read(n) или ReadLine листать с начала… но не соображу, как определить, где "текущий конец" StdOut.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 22:52:25 +0000

Зaменил MsgBox, пусть хоть побольше влезает.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 22:43:36 +0000

Я там малюсенькую правку ранее вносил, после кот. не должно этого быть.

Какой-то один подвисший ntvdm.exe в списке процессов мешал.

Есть убрать, то с первого раза и старый вариант сработает. Нужно использовать текущий.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 22:40:19 +0000

Flasher пишет:

Кавычку добавил. Проверьте. В пути, наверно, пробелы есть.

Теперь заработало. Почти ) Показывает MsgBox только после того, как через диспетчер задач убить процесс ntvdm.exe :-/

UPD: А, всё, заработало нормально. Один подвисший ntvdm.exe в списке процессов мешал.

Большое спасибо.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 22:28:17 +0000

Кавычку добавил. Проверьте. В пути, наверно, пробелы есть.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 22:20:56 +0000

Flasher пишет:

Скрипт должен лежать в той же папке, что и программа, запускать обычным вызовом по Enter/даблклик.

Да, всё так и делаю.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 22:17:55 +0000

Скрипт должен лежать в той же папке, что и программа, запускать обычным вызовом по Enter/даблклик.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 22:15:16 +0000

Flasher пишет:

вот что у меня вышло:

Э-мм, а у меня это не работает.
Всегда выполняется условие If InStrRev(WScript.FullName, "WScript.exe").
Если конструкцию If убрать и оставить только кусок Set Exe = .Exec… MsgBox Exe.StdOut.ReadAll, то программа запускается и тут же закрывается, а скрипт выдаёт ошибку:
Ошибка: Идёт закрытие канала.
Код: 800700E8
Источник: (null)

ОС Windows 7 32-бит, пользователь с правами администратора.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (Flasher) — Tue, 16 Dec 2014 21:53:20 +0000

Система "ниппель", конечно, но вот что у меня вышло:

With CreateObject("WScript.Shell")
  If InStrRev(WScript.FullName, "WScript.exe") Then
    .Run "CScript.exe //NoLogo """ & WScript.ScriptFullName & """", 0
  Else
    Set Exe = .Exec("RADMODLS.EXE")
    For i = 1 to 12
      Exe.StdIn.WriteLine "N"
    Next
    .PopUp Exe.StdOut.ReadAll
  End If
End With

Хотя я вообще не понял, зачем нужно подобные программы выводить в окно, к тому же существенно ограниченное по высоте.

Re: VBS:Как при помощи VBS получить текст из окна консольного приложения?

null@example.com (404) — Tue, 16 Dec 2014 21:26:51 +0000

Заработал такой код

Set ws = WScript.CreateObject("WScript.Shell")

Set DX = CreateObject("DynamicWrapperX")

DX.Register "user32.dll",   "GetForegroundWindow",                    "r=h"
DX.Register "user32.dll",   "GetWindowThreadProcessId",  "i=hL",      "r=l"
DX.Register "kernel32.dll", "AttachConsole",             "i=l",       "r=l"
DX.Register "kernel32.dll", "GetStdHandle",              "i=l",       "r=h"
DX.Register "kernel32.dll", "ReadConsoleOutputCharacter","i=hSlpL",   "r=l"

ws.Run("abcd.exe") :WScript.Sleep 2000

wh = DX.GetForegroundWindow()
pid= 0
wh = DX.GetWindowThreadProcessId(wh, pid)
res= DX.AttachConsole(pid)
sh = DX.GetStdHandle(-11)

n = 100
s = Space(n)

x = 10 :y = 3  'координаты экрана, откуда надо начинать чтение
coord = y*2^16 + x

res = DX.ReadConsoleOutputCharacter(sh, s, n, coord, n)

msgbox(s)