Серый форум — AHK: полностью прозрачная панель задач Windows, возможно ли?

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2018-06-16T17:47:11Z

Раскладка языка пропадает ещё.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-20T19:51:27Z

А, нет, всё таки можно увеличить скорость, загружая через AccessibleChildren только нужное количество потомков, особенно заметен прирост, когда в объекте много потомков, а требуемый в начале.


#SingleInstance Force 
#NoEnv  
OnExit Exit
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, ahk_id %hShellTray% 
ControlGet, hNotifyWnd, HWND,, TrayNotifyWnd1, ahk_id %hShellTray%  
DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
ComObjError(false)
SetTimer, Reload, 1800000

Loop  {
    Sleep 50  
    If ((Acc := Acc_NeedChildren(Acc_ObjectFromWindow(hTaskbar),4)) = "")
        Continue
    Acc.accLocation(ComObj(0x4003,&x:=0), 0, ComObj(0x4003,&w:=0), 0, Acc.accChildCount)    
    Right := NumGet(x,0,"int") + NumGet(w,0,"int")
    ControlGetPos, Left, , , , , ahk_id %hNotifyWnd%
    If (prLeft = Left && prRight = Right)
        Continue
    prLeft := Left, prRight := Right
    WinGetPos, wX, , wW, wH, ahk_id %hShellTray% 
    Right -= wX
    WinSet, Region, % Right "-0 0-0 0-" wH " " Right "-" wH " " Right "-0 "
        . Left "-" wH " " wW "-" wH " " wW "-0 " Left "-0" " " Left "-" wH
        , ahk_id %hShellTray% 
}

Reload:
    Reload
    
Esc::
Exit:
    WinSet, Region, , ahk_id %hShellTray%
    ExitApp 
  
Acc_NeedChildren(Acc, Index) {  
    if DllCall("oleacc\AccessibleChildren", "Ptr", ComObjValue(Acc), "Int",0, "Int", Index, "Ptr",VarSetCapacity(varChildren, Index*(8+2*A_PtrSize),0)*0+&varChildren, "Int*", Index)=0 {
        Loop %Index%
            i:=(A_Index-1)*(A_PtrSize*2+8)+8, child:=NumGet(varChildren, i), Ret := (NumGet(varChildren,i-8)=9 ? ComObj(9,ComObjQuery(child, "{618736e0-3c3d-11cf-810c-00aa00389b71}"), 1) : child), NumGet(varChildren,i-8)=9 ? ObjRelease(child) : 0
        Return Ret
    }
}

Acc_ObjectFromWindow(hWnd, idObject = 0)  {
    If DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc) = 0
        Return ComObjEnwrap(9, pacc, 1)
}

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-20T18:57:53Z

Я так понял, что "oleacc\AccessibleChildren" загружает в память сразу все объекты, и после, их жизненно необходимо все перебрать, чтобы для каждого применить "ObjRelease".
И тут уже заявленный в 4 посте прирост скорости (20-25%) стремится к нулю, потому код ниже отличается от 2 поста, только отсутствием привязки к библиотеке.


#SingleInstance Force 
#NoEnv  
OnExit Exit
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, ahk_id %hShellTray% 
ControlGet, hNotifyWnd, HWND,, TrayNotifyWnd1, ahk_id %hShellTray%  
DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
ComObjError(false)
SetTimer, Reload, 1800000

Loop  {
    Sleep 50  
    If ((Acc := Acc_NeedChildren(Acc_ObjectFromWindow(hTaskbar),4)) = "")
        Continue
    Acc.accLocation(ComObj(0x4003,&x:=0), 0, ComObj(0x4003,&w:=0), 0, Acc.accChildCount)    
    Right := NumGet(x,0,"int") + NumGet(w,0,"int")
    ControlGetPos, Left, , , , , ahk_id %hNotifyWnd%
    If (prLeft = Left && prRight = Right)
        Continue
    prLeft := Left, prRight := Right
    WinGetPos, wX, , wW, wH, ahk_id %hShellTray% 
    Right -= wX
    WinSet, Region, % Right "-0 0-0 0-" wH " " Right "-" wH " " Right "-0 "
        . Left "-" wH " " wW "-" wH " " wW "-0 " Left "-0" " " Left "-" wH
        , ahk_id %hShellTray% 
}

Reload:
    Reload
    
Esc::
Exit:
    WinSet, Region, , ahk_id %hShellTray%
    ExitApp 
  
Acc_NeedChildren(Acc, Index) { 
    cChildren:=Acc.accChildCount, Children:=[]
    if DllCall("oleacc\AccessibleChildren", "Ptr",ComObjValue(Acc), "Int",0, "Int",cChildren, "Ptr",VarSetCapacity(varChildren,cChildren*(8+2*A_PtrSize),0)*0+&varChildren, "Int*",cChildren)=0 {
        Loop %cChildren%
            i:=(A_Index-1)*(A_PtrSize*2+8)+8, child:=NumGet(varChildren,i), Children.Insert(NumGet(varChildren,i-8)=9 ? ComObj(9,ComObjQuery(child, "{618736e0-3c3d-11cf-810c-00aa00389b71}"), 1) : child), NumGet(varChildren,i-8)=9 ? ObjRelease(child) : 0
        return Children.MaxIndex() ? Children[Index] : 0
    }  
}

Acc_ObjectFromWindow(hWnd, idObject = 0)  {
    If DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc) = 0
        Return ComObjEnwrap(9, pacc, 1)
}

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-13T06:39:12Z

Как ни крутил, так и не понял в чём отличия Acc_NeedChildren от Acc_Children.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-11T12:52:39Z

Но я этого не вижу в самой Acc_Children.
Так например память не кушает:

#SingleInstance Force 
#NoEnv  
OnExit Exit
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, ahk_id %hShellTray% 
ControlGet, hNotifyWnd, HWND,, TrayNotifyWnd1, ahk_id %hShellTray%   
SetTimer, Reload, 1800000

Loop  {
    Sleep 50  
    If ((Acc := Acc_Children(Acc_ObjectFromWindow(hTaskbar))[4]) = "")
        Continue
    Acc.accLocation(ComObj(0x4003,&x:=0), 0, ComObj(0x4003,&w:=0), 0, Acc.accChildCount)    
    Right := NumGet(x,0,"int") + NumGet(w,0,"int")
    ControlGetPos, Left, , , , , ahk_id %hNotifyWnd%
    If (prLeft = Left && prRight = Right)
        Continue
    prLeft := Left, prRight := Right
    WinGetPos, wX, , wW, wH, ahk_id %hShellTray% 
    Right -= wX
    WinSet, Region, % Right "-0 0-0 0-" wH " " Right "-" wH " " Right "-0 "
        . Left "-" wH " " wW "-" wH " " wW "-0 " Left "-0" " " Left "-" wH
        , ahk_id %hShellTray% 
}

Reload:
    Reload
    
Esc::
Exit:
    WinSet, Region, , ahk_id %hShellTray%
    ExitApp

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-11T12:47:30Z

AccessibleChildren()

Clients must call the IUnknown::Release method for any IDispatch interfaces retrieved by this function, and free the array when it is no longer required.

Сейчас подробно некогда смотреть.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-11T12:41:19Z

teadrinker
Действительно, и однозначно это делает Acc_NeedChildren. Не понимаю, всё сделано по образу по подобию, в чём может быть дело?

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-11T11:55:26Z

Код из #3 нещадно память пожирает.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T17:38:59Z

serzh82saratov
Ясно, жаль, но спасибо, так как цель в видимости любого OSD сквозь таскбар выполняется.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T17:25:01Z

Всё правильно, этот код так и должен делать.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T17:21:04Z

serzh82saratov
Т.е. у Вас такое же поведение?

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T16:54:14Z

Но становится прозрачной не вся панель

Тут у меня никаких идей.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T14:43:30Z

serzh82saratov
Опять удивляете, почти работает. Но становится прозрачной не вся панель, а только свободное место. За иконками и значками уведомлений оно остается, смотрите как это выглядит на 8.1. Т.к. когда-то пытался добиться этого, редактируя стоковую тему, знаю, что у значков уведомлений своя собственная подложка.

http://s017.radikal.ru/i408/1501/c4/f1729d72175e.png

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T14:03:02Z

К Acc_NeedChildren легко прикручивается привычный Path.


DllCall("LoadLibrary","Str","oleacc","Ptr")
Win := WinExist("ahk_class CabinetWClass ahk_exe explorer.exe")    
Acc := Acc_ObjectFromPath(Acc_ObjectFromWindow(Win), "4,3,4,1,4,1,4,1,8")
MsgBox, % Acc.accName(0)
Return

Acc_ObjectFromPath(Acc, Path)  { 
    Loop, parse, Path, `,
        Acc := Acc_NeedChildren(Acc, A_LoopField)
    Return Acc
}

Acc_NeedChildren(Acc, Index)  {  
    If DllCall("oleacc\AccessibleChildren", "Ptr", ComObjValue(Acc), "Int", 0, "Int", Index, "Ptr", VarSetCapacity(varChildren, Index * (8 + 2 * A_PtrSize), 0) * 0 + &varChildren, "Int*", Index) = 0  { 
        i := (Index - 1) * (A_PtrSize * 2 + 8) + 8, child := NumGet(varChildren, i)
        return (NumGet(varChildren, i - 8) = 9 ? ComObj(9, ComObjQuery(child, "{618736e0-3c3d-11cf-810c-00aa00389b71}"), 1) : child), ObjRelease(child)
    } 
}

Acc_ObjectFromWindow(hWnd, idObject = 0)  {
    If DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc) = 0
        Return ComObjEnwrap(9, pacc, 1)
}

По результатам тестов, работает на 20-25% процентов быстрее, чем Acc_Get.

Re: AHK: полностью прозрачная панель задач Windows, возможно ли?

2015-01-10T13:31:06Z

Библиотека Acc не требуется.

Давно неустраивала Acc_Get своей громоздкостью, и ненужным перебором всех Child в объекте, всего лишь для получения одного объекта. По случаю написал функцию Acc_NeedChildren.


#SingleInstance Force 
#NoEnv  
OnExit Exit
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, ahk_id %hShellTray% 
ControlGet, hNotifyWnd, HWND,, TrayNotifyWnd1, ahk_id %hShellTray%  
DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
ComObjError(false)
SetTimer, Reload, 1800000

Loop  {
    Sleep 50  
    If ((Acc := Acc_NeedChildren(Acc_ObjectFromWindow(hTaskbar), 4)) = "")
        Continue
    Acc.accLocation(ComObj(0x4003,&x:=0), 0, ComObj(0x4003,&w:=0), 0, Acc.accChildCount)    
    Right := NumGet(x,0,"int") + NumGet(w,0,"int")
    ControlGetPos, Left, , , , , ahk_id %hNotifyWnd%
    If (prLeft = Left && prRight = Right)
        Continue
    prLeft := Left, prRight := Right
    WinGetPos, wX, , wW, wH, ahk_id %hShellTray% 
    Right -= wX
    WinSet, Region, % Right "-0 0-0 0-" wH " " Right "-" wH " " Right "-0 "
        . Left "-" wH " " wW "-" wH " " wW "-0 " Left "-0" " " Left "-" wH
        , ahk_id %hShellTray% 
}

Reload:
    Reload
    
Esc::
Exit:
    WinSet, Region, , ahk_id %hShellTray%
    ExitApp 

Acc_ObjectFromWindow(hWnd, idObject = 0)  {
    If DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc) = 0
    Return ComObjEnwrap(9, pacc, 1)
}

Acc_NeedChildren(Acc, Index)  {  
    if DllCall("oleacc\AccessibleChildren", "Ptr", ComObjValue(Acc), "Int", 0, "Int", Index, "Ptr", VarSetCapacity(varChildren, Index * (8 + 2 * A_PtrSize), 0) * 0 + &varChildren, "Int*", Index) = 0  { 
        i := (Index - 1) * (A_PtrSize * 2 + 8) + 8, child := NumGet(varChildren, i)
        return (NumGet(varChildren, i - 8) = 9 ? ComObj(9, ComObjQuery(child, "{618736e0-3c3d-11cf-810c-00aa00389b71}"), 1) : child), ObjRelease(child)
    } 
}