Серый форум — VBS: сложение времени

Re: VBS: сложение времени

null@example.com (Flasher) — Sun, 13 Sep 2015 15:01:25 +0000

Стандартными методами нельзя.

Re: VBS: сложение времени

null@example.com (Malcev) — Sun, 13 Sep 2015 14:31:16 +0000

Вопрос, не совсем по теме.
Можно ли без вызова mediainfo.dll узнать длительность видео с точностью до кадра?

Re: VBS: сложение времени

null@example.com (Flasher) — Sat, 25 Jul 2015 18:40:14 +0000

griha09, с этим, я так понимаю, сюда.

Re: VBS: сложение времени

null@example.com (griha09) — Sat, 25 Jul 2015 18:02:22 +0000

Flasher, решил чуть переделать вашу процедуру вот так

Sub FFolder(Folder, Folder2)
  Set Folder = Shell.NameSpace(Folder)
  Set Items  = Folder.Items
  Items.Filter 192, Exts
  For Each File in Items
objFSO.MoveFile File, Folder2+File.Name 
  Next
End Sub

чтоб после отсортировки переносить отсортированные видеофайлы, да в цикле выдает только имя(без расширения) файла. Не подкажите как получить полное имя с путем для переноса файла?

Re: VBS: сложение времени

null@example.com (griha09) — Wed, 08 Jul 2015 20:26:30 +0000

Спасибо.

Re: VBS: сложение времени

null@example.com (Flasher) — Wed, 08 Jul 2015 20:23:04 +0000

Раскладываем на 3 строчки.

Dim A(0) ' объявляем массив, 0 - один элемент массива
A(0) = 0 ' устанавливаем первичное значение первого и, соотв., единственного элемента массива
FFolder CD ' вызываем процедуру, подставляя путь рабочей папки в качестве её аргумента

Время жизни переменной в процедуре длится, как известно, до окончания её отработки, в то время как элемент массива (как и элемент коллекции) позволяет не терять обновляемое в ней значение.

Re: VBS: сложение времени

null@example.com (griha09) — Wed, 08 Jul 2015 20:09:15 +0000

Flasher, продолжая мой вопрос. Здесь перечислены переменные? Что означает FFolder CD?

Dim A(0) : A(0) = 0 : FFolder CD

Re: VBS: сложение времени

null@example.com (griha09) — Sun, 25 Jan 2015 16:33:24 +0000

Спасибо!

Re: VBS: сложение времени

null@example.com (Flasher) — Wed, 21 Jan 2015 22:09:32 +0000

' Подсчёт общей длительности доступных видео-файлов в структуре данного каталога

Set Shell = CreateObject("Shell.Application")
CD = CreateObject("WScript.Shell").CurrentDirectory
Exts = "*.3gp;*.asf;*.avi;*.mov;*.mp4;*.mpg;*.wmv;*.vob"
Dim A(0) : A(0) = 0 : FFolder CD
D = Int(A(0)/86400) : H1 = A(0) - (D * 86400)
H = Int(H1/3600)    : M1 = H1   - (H * 3600)
M = Int(M1/60)      : S  = M1   - (M * 60)
If D = 0 Then D = "" Else D = D & " дн. "
MsgBox "Общая продолжительность доступных видео-файлов " & _
"структуры папки """ & CD & """: " & D & TimeSerial(H, M, S), 64

Sub FFolder(Folder)
  Set Folder = Shell.NameSpace(Folder)
  Set Items  = Folder.Items
  Items.Filter 192, Exts
  For Each File in Items
    Dur = Folder.GetDetailsOf(File, 27)
    If Dur <> "" Then A(0) = A(0) + DateDiff("s", 0, Dur)
  Next : Items.Filter 160, "*"
  For Each Fd In Items : FFolder Fd.Path : Next
End Sub

Re: VBS: сложение времени

null@example.com (omegastripes) — Wed, 21 Jan 2015 18:53:53 +0000

griha09 пишет:

... но затык с сложением времени

Замените строку

str=str+param

на

str=str+cdate(param)

VBS: сложение времени

null@example.com (griha09) — Wed, 21 Jan 2015 10:26:27 +0000

Хочу сделать скрипт для подсчета общей длительности видеофайлов в папке



Option Explicit
Dim oFileDetailsReader, sTmpStr, sValue, i, input, output, objFSO, WSHShell, Folder, File, param, SubFolder, str
input = "f:\видео\"        
str=0
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set WSHShell = WScript.CreateObject("WScript.Shell")


RecursiveFolderScan input
 MsgBox str

'Создаём процедуру рекурсивного обхода каталога
Sub RecursiveFolderScan(FolderPath)
    'Получаем объектную модель текущего каталога
    Set Folder = objFSO.GetFolder(FolderPath)
 
    'Перебираем все файлы в текущем каталоге
    For Each File in Folder.Files
Set oFileDetailsReader = New cFileDetailsReader
With oFileDetailsReader
    .OpenFile File
        param = .GetDetail(27)

 str=str+param
   End With
 Next
    'Перебираем все подкаталоги в каталоге
    For Each SubFolder in Folder.SubFolders
        RecursiveFolderScan(SubFolder.Path)
    Next
Set WSHShell = Nothing

  End Sub



Set WSHShell = Nothing


Class cFileDetailsReader
    Private oFSO, oShellApp, oFolder3, oFolderItem
    
    Private Sub Class_Initialize()
        Set oFSO = CreateObject("Scripting.FileSystemObject")
        Set oShellApp = CreateObject("Shell.Application")
    End Sub
    
    Sub OpenFile(FilePath)
        With oFSO.GetFile(FilePath)
            Set oFolder3 = oShellApp.NameSpace(.ParentFolder.Path)
            Set oFolderItem = oFolder3.ParseName(.Name)
        End With
    End Sub
    
    Function GetDetail(Index)
        GetDetail = oFolder3.GetDetailsOf(oFolderItem,Index)
    End Function

    Function GetDetailName(Index)
        GetDetailName = oFolder3.GetDetailsOf(0,Index)
    End Function
End Class

но затык с сложением времени