Серый форум — AHK: Управление окнами мышкой

Re: AHK: Управление окнами мышкой

null@example.com (Astoria) — Sat, 20 Jul 2019 13:12:12 +0000

Добрый день.
Код работает, но у меня стоит Win10 DPI fix и, соответственно, 125% масштаб интерфейса.
Все клики приведённого выше скрипта смещены относительно кнопок на сколько-то пикселей (разное кол-во, в зависимости от близости к краю, вроде бы).
Может быть, кто-то знает, как скорректировать скрипт под измененный масштаб?
Возможно, есть встроенные функции WM на эту тему.
Поиском не удалось найти ничего похожего..
Заранее благодарю.

Re: AHK: Управление окнами мышкой

null@example.com (Alexey244) — Thu, 02 Apr 2015 20:13:08 +0000

На nncron-е работало немного по другому, там в цикле отслеживались нужные клики мышкой, если клик был то этим кликом окно сразу делалось активным, посылался WM_NCHITTEST и уже дальше выбиралось нужное действие.. Но как я уже говорил глючило тоже регулярно.. Посмотрим как на AHK работать будет..

Re: AHK: Управление окнами мышкой

null@example.com (Irbis) — Thu, 02 Apr 2015 20:04:02 +0000

Действительно, далеко не факт, что под курсором активно окно.
Можно и в глобальную переменную записывать HWND, но "это не наши методы" (с)

#NoEnv
#If res := NCHITTEST(id)
RButton::
MButton::
   WinGetTitle, Title, AHK_id %id%
   try Gosub %A_ThisHotkey%_%res%
#If
Return

RButton_MINBUTTON:
   MsgBox, Нажатие RButton над кнопкой «Свернуть»`n%Title%
Return
RButton_CLOSE:
   MsgBox, Нажатие RButton над кнопкой «Закрыть»`n%Title%
Return
MButton_MINBUTTON:
   MsgBox, Нажатие MButton над кнопкой «Свернуть»`n%Title%
Return
MButton_CLOSE:
   MsgBox, Нажатие MButton над кнопкой «Закрыть»`n%Title%
Return

Esc:: ExitApp

NCHITTEST(ByRef hWnd)
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

Re: AHK: Управление окнами мышкой

null@example.com (Alexey244) — Thu, 02 Apr 2015 20:01:46 +0000

Еще раз всем спасибо за участие и отзывчивость. Пойду изобретать свое двухколесное средство. В планах у меня еще отслеживание позиции корсора на таких длинных элементах как заголовок окна CAPTION и рамка ("LEFT","RIGHT","TOP" и "BOTTOM") и в зависимости от позиции делать разные действия.. Например менять прозрачность окна кликая пр.кн. по нижней границе и чемближе к правому углу окна тем более прозрачнее...
Но это я так, идеей делюсь и не призываю никого писать для меня готовый код.. Я и так чувствую что мое спасибо это слишком мало за эту помощь.. Надеюсь, что не мне одному пригодятся эти примеры.

Re: AHK: Управление окнами мышкой

null@example.com (teadrinker) — Thu, 02 Apr 2015 19:39:02 +0000

Ну, в идеале-то ещё нужно учитывать hWnd (или заголовок) окна, который функция могла бы возвращать через ByRef-параметр.

Re: AHK: Управление окнами мышкой

null@example.com (Irbis) — Thu, 02 Apr 2015 19:28:13 +0000

Alexey244 пишет:

<...> Читал сегодня мануалы, так и не смог понять есть ли в AHK такой оператор как CASE?? Или выбор действия придется множеством If–ов делать?

Ну как тут не изобрести свое двухколесное средство передвижения, тем более teadrinker в двух вариантах кода приложил почти все комплектующие к нему.

#NoEnv
#If res := NCHITTEST()
RButton::
MButton::
   try Gosub %A_ThisHotkey%_%res%
#If
Return

RButton_MINBUTTON:
   MsgBox, Здесь действие при нажатии RButton над кнопкой «Свернуть»
Return
RButton_CLOSE:
   MsgBox, Здесь действие при нажатии RButton над кнопкой «Закрыть»
Return
MButton_MINBUTTON:
   MsgBox, Здесь действие при нажатии MButton над кнопкой «Свернуть»
Return
MButton_CLOSE:
   MsgBox, Здесь действие при нажатии MButton над кнопкой «Закрыть»
Return

Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

Upd: Почему-то try Gosub <..> не срабатывает, будучи записанным на одной строке с хоткеем, хотя формально это однострочная директива. Один Gosub срабатывает, а так - нет.

Re: AHK: Управление окнами мышкой

null@example.com (teadrinker) — Thu, 02 Apr 2015 18:46:13 +0000

Если срабатывания над какими-то элементами окна не нужны, можно удалить эти элементы из списка, оставив вместо них пустые кавычки.

Re: AHK: Управление окнами мышкой

null@example.com (teadrinker) — Thu, 02 Apr 2015 18:39:19 +0000

Для практического использования данного кода принцип такой:

#If res := NCHITTEST()
RButton::
   if (res = "MINBUTTON")  {
      MsgBox, Здесь действие при нажатии RButton над кнопкой «Свернуть»
   }
   else if (res = "CLOSE")  {
      MsgBox, Здесь действие при нажатии RButton над кнопкой «Закрыть»
   }
   Return
   
MButton::
   if (res = "MINBUTTON")  {
      MsgBox, Здесь действие при нажатии MButton над кнопкой «Свернуть»
   }
   else if (res = "CLOSE")  {
      MsgBox, Здесь действие при нажатии MButton над кнопкой «Закрыть»
   }
   Return
   
#If
Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

Re: AHK: Управление окнами мышкой

null@example.com (Alexey244) — Thu, 02 Apr 2015 18:31:39 +0000

Уважаемый teadrinker, а не могли бы вы слегка подкорректировать ваш последний пример таким образом, чтобы в нем было несколько MsgBox, и отображали они сообщения не из переменных значений, а из постоянных. Например
MsgBox "Нажата ср.кнопка мыши над кнопкой свернуть"
Я, к своему стыду, пока не могу вникнуть куда мне вставить код, к примеру, делающий активное окно поверх всех окон при нажатии пр.кн.мыши над «развернуть»..
Читал сегодня мануалы, так и не смог понять есть ли в AHK такой оператор как CASE?? Или выбор действия придется множеством If–ов делать?

Re: AHK: Управление окнами мышкой

null@example.com (teadrinker) — Thu, 02 Apr 2015 15:32:16 +0000

YMP пишет:

Зачем эти лишние телодвижения и расход памяти

Так ты тоже заметил, что нарушать правила легче, чем выполнять их? Вопрос лишь в последствиях. Но я уверен, что образованные и культурные люди, которые собираются на нашем форуме, не встанут на этот скользкий путь! А кто некультурный — тому бан.

yalanne пишет:

добавил комментарии к скрипту

Комментировать код — прекрасная привычка, которой напрочь лишены большинство завсегдатаев раздела AHK. Но едва ли необходимы комментарии типа

#Persistent ; Делает скрипт постоянно выполняющимся

Во-первых, что делает данная директива и так написано в справке, ни к чему её копировать. Во-вторых, эта команда не нужна в данном коде вовсе. Комментируют же обычно тонкости алгоритма, которые могут быть не совсем понятны на первый взгляд.
Но я, когда говорил про аккуратность и понятность, имел в виду не совсем это. Сравните:

#If res := NCHITTEST()
RButton::
MButton:: MsgBox, % "Нажата " A_ThisHotkey " над " res
#If
Esc:: ExitApp

NCHITTEST()
{  ; из списка удалена позиция "CLIENT", соответствующая клиентской части окна
   static pos := [ "","CAPTION","SYSMENU","SIZE","MENU","HSCROLL","VSCROLL"
                  ,"MINBUTTON","MAXBUTTON","LEFT","RIGHT","TOP","TOPLEFT","TOPRIGHT"
                  ,"BOTTOM","BOTTOMLEFT","BOTTOMRIGHT","BORDER","OBJECT","CLOSE","HELP" ]
   CoordMode, Mouse
   MouseGetPos, X, Y, hWnd
   SendMessage, WM_NCHITTEST := 0x84,, X | Y<<16,, ahk_id %hWnd%
   Return pos[ErrorLevel]
}

Re: AHK: Управление окнами мышкой

null@example.com (yalanne) — Thu, 02 Apr 2015 09:36:44 +0000

teadrinker пишет:

аккуратней и понятней

добавил комментарии к скрипту

Re: AHK: Управление окнами мышкой

null@example.com (YMP) — Thu, 02 Apr 2015 07:26:57 +0000

teadrinker пишет:

Это в девять утра-то, когда на форуме кроме тебя никого нет?

Да я обычно и не смотрю, есть кто или нет. Зачем эти лишние телодвижения и расход памяти, если можно процитировать?

Да и привычка у человека уже сформировалась, видимо, на других форумах, а привычка — вторая натура.

Re: AHK: Управление окнами мышкой

null@example.com (teadrinker) — Thu, 02 Apr 2015 06:39:22 +0000

yalanne, так уже лучше, но всё это записать можно аккуратней и понятней (особенно предпоследнюю строчку).

yalanne пишет:

5) без понятий. Так уже в примере было.

Такая запись понадобилась бы, если б x и y могли принимать отрицательные значения, в данном случае же это ни к чему.

Re: AHK: Управление окнами мышкой

null@example.com (Irbis) — Thu, 02 Apr 2015 06:28:29 +0000

+ Off

Есть кнопка "Предпросмотр" - категорически рекомендовано к использованию министерством образования РФ, в частности спецкомитетом по борьбе с ошибками, а точнее его подразделением по отлову и уничтожению очепяток. )
Новые посты, при их появлении, при этом будут показаны прямо под вашим ответом.

Re: AHK: Управление окнами мышкой

null@example.com (yalanne) — Thu, 02 Apr 2015 06:26:21 +0000

teadrinker,
1) Исправил.
2) Предлагаю другие варианты, если их доработать будет альтернативой.
3) Исправил на это

#if (WM_NCHITTEST:=WM_NCHITTEST()) and (WM_NCHITTEST=8) or (WM_NCHITTEST=9) or (WM_NCHITTEST=20)

что бы вызывалось 1 раз а не 6.
В этом If'е убирает другие сообщения. оставляет только 8,9,20 - которые соответствуют действиям свернуть, развернуть, закрыть.
4) Чтобы не вызывалось и бралось из переменной.

msgbox % "Нажата " ( (WM_NCHITTEST=8) ? "свернуть" : ((WM_NCHITTEST=9) ? "развернуть" : ((WM_NCHITTEST=20) ? "закрыть" : "" ))) " " ((A_ThisHotkey="Lbutton") ? "левой" : ((A_ThisHotkey="Rbutton") ? "правой" : ((A_ThisHotkey="Mbutton") ? "средней" : ""))) " клавишей."

5) Без понятий. Так уже в примере было.