Серый форум — AHK: Буфер обмена, замена текста

Re: AHK: Буфер обмена, замена текста

null@example.com (teadrinker) — Wed, 21 Dec 2022 09:04:00 +0000

viviancels, ознакомьтесь, пожалуйста, с Правилами, отредактируйте свой пост. Обратите внимание на оформление ссылок.
Также прочитайте внимательно этот пост.

Re: AHK: Буфер обмена, замена текста

null@example.com (viviancels) — Wed, 21 Dec 2022 07:18:08 +0000

Здравствуйте. Почему-то, не редактируется буфер.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases
; #Warn  ; Enable warnings to assist with detecting common errors.
; SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
; SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance Force
^vk43::
Clipboard :=
Sleep 150
Send ^{vk43}
Sleep 150
Clipwait
Clipboard := RegExReplace(Clipboard, "m`a)^(.*)$\n.*,\s(.*)$", "$2 - $1")
return

Текст:

Awakening

En-Core, Malyarovsky Maxim, Nikita

Результат должен быть:

Nikita - Awakening

Здесь ошибки вроде нет:
https://regex101.com/r/MeOefY/1

UPD. Понял, в чем ошибка. Нужно добавить опцию s точка - перенос строки):

RegExReplace(Clipboard, "ms`a)^(.*)$\n.*,\s(.*)$", "$2 - $1")

Re: AHK: Буфер обмена, замена текста

null@example.com (Irbis) — Tue, 28 Apr 2015 14:39:18 +0000

Проще собрать все названия в один массив. Если [в скобках] стоит 1, (в примере у Wiki и Google), то 2ая строка будет вырезана.

#Persistent
Sites := {"Яндекс": ["Это взято с сайта Яндекс"]
        ,"Google": ["Это взято с сайта Google", 1]
        ,"Википедия": ["Это взято с сайта Wiki",1]
        ,"Серый форум": "Это взято с сайта script-coding"}
return
OnClipboardChange:
   IfWinNotActive ahk_class MozillaWindowClass
   return
   site := ""
   WinGetTitle, Title, A
   for k,v in Sites 
      If InStr(Title, k) {
         site := v[1]
         if (v[2]=1)
            ClipBoard := RegexReplace(ClipBoard, "s)\R.*?(?=(\R|$))",,,1)
         Break
      }
If (site != "")
   FileAppend, %Clipboard%`n%site%`n`n----------------------`n, G:\My Text File.txt
   Sleep 300
return

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Tue, 28 Apr 2015 12:14:24 +0000

Наверное можно и регексами:

f11::
msgbox % RegexReplace(ClipBoard, "s)\R.*?(?=(\R|$))",,,1)

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Tue, 28 Apr 2015 10:26:58 +0000

Работает!
А можно в этот код в Else if InStr дописать код при котором (естественно в зависимости от title) будет удаляться 2ая строка в копируемом тексте?

Начинать надо с Loop, parse, clipboard, `n, `r ?

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Tue, 28 Apr 2015 08:20:16 +0000

Ну так и будет:

If InStr(title, "Яндекс")
   site := "Это взято с сайта Яндекс"
Else if InStr(title, "Google")
   site := "Это взято с сайта Google"
Else if InStr(title, "Wiki")
   site := "Это взято с сайта Wiki"
Else if InStr(title, "script-coding")
   site := "Это взято с сайта script-coding"
Else
   site := ""

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Tue, 28 Apr 2015 07:45:50 +0000

это я сразу понял и применил. вопрос стоит иначе: как мне размножить этот код на 5-7-8-158 сайтов?
то есть к примеру этот код нужно применить к гугль, яндекс, википедия, ютуб, форум скрипт кодинг, то как будет выглядеть код?

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Mon, 27 Apr 2015 23:55:57 +0000

Дублируете эти секции:

Else if InStr(title, "Google")
   site := "Это взято с сайта Google"

Вместо "Google" вписываете отличительный признак страницы, который получаете через AHKSPY.

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Mon, 27 Apr 2015 22:35:10 +0000

http://www.script-coding.com/AutoHotkey/IfInString.html
прочитал, но так и не понял, а как в этот код добавить еще множество сайтов, помимо гугля и яндекса?

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Mon, 27 Apr 2015 22:02:58 +0000

Malcev пишет:

Я подправил 14 код.

вот так работает:

#Persistent
return

OnClipboardChange:
IfWinNotActive ahk_class MozillaWindowClass
   return
WinGetTitle, Title, A
If InStr(title, "Яндекс")
   site := "Это взято с сайта Яндекс"
Else if InStr(title, "Google")
   site := "Это взято с сайта Google"
Else
   site := ""
If (site != "")
FileAppend, %Clipboard%`n%site%`n`n----------------------`n, G:\My Text File.txt
return

Спасибо, Malcev!

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Mon, 27 Apr 2015 21:53:23 +0000

Я подправил 14 код.

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Mon, 27 Apr 2015 21:51:54 +0000

с msgbox работает, а вот с FileAppend не хочет. Что не так?:

F4::
#Persistent
return

OnClipboardChange:
IfWinNotActive ahk_class MozillaWindowClass
   return
WinGetTitle, Title, A
If InStr(title, "Яндекс")
   site := "Это взято с сайта Яндекс"
Else if InStr(title, "Google")
   site := "Это взято с сайта Google"
Else
   site := ""
If (site != "")
FileAppend, %Clipboard% `n site`n`n----------------------`n, G:\My Text File.txt
return

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Mon, 27 Apr 2015 21:26:33 +0000

Например так:

#Persistent
return

OnClipboardChange:
If !WinActive("ahk_class MozillaWindowClass") or toggle
{
   toggle := ""
   return
}
toggle := 1
WinGetTitle, Title, A
If InStr(title, "Яндекс")
   site := "Это взято с сайта Яндекс"
Else if InStr(title, "Google")
   site := "Это взято с сайта Google"
Else
   site := ""
If (site != "")
   ClipBoard .= "`r`n" site
return

Re: AHK: Буфер обмена, замена текста

null@example.com (busyava) — Mon, 27 Apr 2015 19:59:21 +0000

Продолжаю про буфер обмена.
Вопрос такой: если я копирую текст с разных сайтов, то можно ли сделать соответствующую индивидуальную приписку в конце текста, которая зависит от того с какого сайта я это скопировал?
Например:

блаблабла
Это взято с сайта google ;приписка

блаблабла
Это взято с сайта яндекс ;приписка

_______
браузер мозилла

Re: AHK: Буфер обмена, замена текста

null@example.com (Malcev) — Fri, 17 Apr 2015 23:14:08 +0000

"Заголовок с информацией" - это условно, может быть и другой заголовок.

Не заметил. Тогда можно так:

f1::
RegexMatch(ClipBoard, "s)(?:.*?[\n\r]+){5}(.*)Дмитрий\.", match)
msgbox % Clipboard := match1 "С уважением, Дмитрий. Прочитано."
return