для фикса этого можно заменить строку

    ~Lbutton up::

на

    ~Lbutton::q:=1
#if q
    ~Lbutton up::
    q:=0

GetSelect := "AutoHotkey"
Run https://www.google.com/search?q=%GetSelect%

Если открывается в IE, значит IE и есть у вас браузер по умолчанию.

run % "https://www.google.com/?q=" GetSelect

но не ищет. Надо еще кнопку поиска нажимать вручную после загрузки страницы.

Не знаю, может, посоветует кто.

Как в notepad++ включить авто отступы?

Сейчас же у меня нет много километровых строк

Вас из одной крайности в другую бросает! Вы в обычном блокноте скрипты пишете? В любой среде разработки отступы автоматически добавляются.

; Окно с кнопками скопировать, вставить,гуглить.
Gui Clip:add, button,w40,copy
Gui Clip:add, button,w40 xp+40,paste
Gui Clip:add, button,w40 xp+40,google
Gui, Clip:+AlwaysOnTop -Caption +ToolWindow +LastFound +HWNDGuiClip_hwnd
; ---
Time = 2000 ; Время через сколько пропадет окно (2 секунды)

CoordMode, Mouse, Screen            
#if WhiteListCtrl("Edit","Scintilla") ; Тут указывается белый список контролов на которые будет действовать скрипт.
    ~Lbutton up::
    GetSelect := GetSelect()
    if !GetSelect ; проверка выделенного текста. Эта функция содержит выделенный текст.
        return ; если выделенного текста нет то конец цикла.
    MouseGetPos,x,y ; получаем координаты курсора.
    x+=20,y+=20 ; смещаем на 20
    settimer Time_ClipWin,off ; сбрасываем предыдущий таймер(если есть)
    gui Clip:show,NA x%x% y%y% ; показываем окно, неактивное по указанным координатам.
    settimer Time_ClipWin,-%Time% ; Устанавливаем новый таймер, по окончанию перейдет на метку Time_ClipWin
return
#if 

Time_ClipWin:
    if (GetHwndWin() = GuiClip_hwnd) ; Если курсор находится на ранее созданном окне
        settimer Time_ClipWin,-%Time% ;то, продлится время
    else
        gui Clip:Hide ; иначе скроется.
return

; тут проверяется на какой кнопке был клик, при этом не теряет фокус активного окна
#if (GetHwndWin() = GuiClip_hwnd) ;Тут сравнивает hwnd окна что под курсором и окна Clip если истина то
    Lbutton:: ; левый клик на этом окне будет не активировать окно
    MouseGetPos,,,,ctrl_Clip ; а покажет над каким элементом в этом окне был клик
    RegExMatch(ctrl_Clip,"[0-9]+",ctrl_Clip) ; уберет буквенную часть оставив цифры которые соответствуют номеру кнопки.
    if ctrl_Clip = 1 ; При нажатии кнопки копировать
        {
        Clipboard := GetSelect
        tooltip Copy "%GetSelect%"
        }
    else if ctrl_Clip = 2 ; При нажатии кнопки вставить
        {
        send ^{SC02F}
        tooltip pasted from the clipboard
        }
    else if ctrl_Clip = 3 ; При нажатии кнопки гугл
        {
        Run https://www.google.com/search?q=%GetSelect%
        tooltip Search google "%GetSelect%"
        }
    settimer tooltip_off,off 
    settimer tooltip_off,-2000 ; через 2 секунды уберет подсказку. Ожидание идет через таймер что бы весь скрипт не ждал пока она уберется.
return
#if

tooltip_off:
tooltip
return

WhiteListCtrl(ctrls*){ ; В этой функции проверяется контрол под курсором есть ли он в белом списке.
    MouseGetPos,,,,control
    control := substr(control,1,RegExMatch(control, "[0-9]+$")-1) ; в переменной control хранится имя контрола над которым в данный момент курсор.Имя контрола указывается без индекса.
    for k, ctrl in ctrls ; Проверяет есть ли в белом списке
        if (ctrl = control) ; тот контрол который сейчас под курсором.
            return 1 ; если да, то ответ функции положительный
return 0 ; иначе отрицательный.
; При положительном ответе  первое условие #if будет истиной и продолжит работу.
}

GetSelect(){ ; проверка выделенного текста.
    bufclip := clipboard ; сохраняем буфер обмена в переменную.
    clipboard := "" ; Очищаем буфер обмена.
    send ^{SC02E} ; копируем выделенный текст(ctrl+с)
    select := clipboard ; заносим это в значение в переменную
    clipboard := bufclip ; восстанавливаем предыдущий буфер обмена.
return select ; ответ функции выделенная область.
}

GetHwndWin(){ ; тут определяется hwnd окна который под курсором.
    MouseGetPos,,,Hwnd_cursor
return Hwnd_cursor
}