Серый форум — AHK: Смена курсора

Re: AHK: Смена курсора

null@example.com (teadrinker) — Thu, 07 May 2015 14:53:45 +0000

Информация о названиях курсоров здесь.

Re: AHK: Смена курсора

null@example.com (yalanne) — Thu, 07 May 2015 12:56:59 +0000

Foma, Например у меня на последней версии винды(win10 10074) загружается кастумная иконка нормально. А насчет вин xp,2000 и тд не знаю, но скорей всего тоже должно нормально отобразится.

Re: AHK: Смена курсора

null@example.com (Foma) — Thu, 07 May 2015 11:51:09 +0000

Ещё хотел бы спросить. Перечисленные курсоры есть и одинаковые(однотипные) во всех виндовс? Или где-то может загрузиться принципиально другая картинка, или вообще курсор у пользователя пропадёт?

Re: AHK: Смена курсора

null@example.com (teadrinker) — Wed, 06 May 2015 22:04:15 +0000

Отредактировал немного. Правильно

hCopy := DllCall("CopyImage", Ptr, hCursor, UInt, IMAGE_CURSOR, Int, 0, Int, 0, UInt, 0, Ptr)

вместо

hCopy := DllCall("CopyImage", Ptr, hCursor, UInt, IMAGE_CURSOR, Int, 0, Int, 0, UInt, 0)

Re: AHK: Смена курсора

null@example.com (Foma) — Wed, 06 May 2015 21:50:02 +0000

Всё, нашёл. Менять нужно первую строку.

Re: AHK: Смена курсора

null@example.com (teadrinker) — Wed, 06 May 2015 21:46:50 +0000

А какой нужен?

Re: AHK: Смена курсора

null@example.com (Foma) — Wed, 06 May 2015 21:44:44 +0000

Спасибо! Что-то похожее я встречал и не смог приспособить.

Re: AHK: Смена курсора

null@example.com (teadrinker) — Wed, 06 May 2015 20:25:05 +0000

ReplaceSystemCursors("IDC_NO")
OnExit, Exit
Return

Esc:: ExitApp
Exit:
   ReplaceSystemCursors()
   ExitApp

ReplaceSystemCursors(IDC = "")
{
   static IMAGE_CURSOR := 2, SPI_SETCURSORS := 0x57
        , SysCursors := { IDC_APPSTARTING: 32650
                        , IDC_ARROW: 32512
                        , IDC_CROSS: 32515
                        , IDC_HAND: 32649
                        , IDC_HELP: 32651
                        , IDC_IBEAM: 32513
                        , IDC_NO: 32648
                        , IDC_SIZEALL: 32646
                        , IDC_SIZENESW: 32643
                        , IDC_SIZENWSE: 32642
                        , IDC_SIZEWE: 32644
                        , IDC_SIZENS: 32645 
                        , IDC_UPARROW: 32516
                        , IDC_WAIT: 32514 }
   if !IDC
      DllCall("SystemParametersInfo", UInt, SPI_SETCURSORS, UInt, 0, UInt, 0, UInt, 0)
   else  {
      hCursor := DllCall("LoadCursor", Ptr, 0, UInt, SysCursors[IDC], Ptr)
      for k, v in SysCursors  {
         hCopy := DllCall("CopyImage", Ptr, hCursor, UInt, IMAGE_CURSOR, Int, 0, Int, 0, UInt, 0, Ptr)
         DllCall("SetSystemCursor", Ptr, hCopy, UInt, v)
      }
   }
}

Re: AHK: Смена курсора

null@example.com (Foma) — Wed, 06 May 2015 17:28:24 +0000

Всё равно, если он над блокнотом или над текстом в броузере, он меняется на стандартный, если тянешь окно за бок - тоже.

Re: AHK: Смена курсора

null@example.com (Alectric) — Wed, 06 May 2015 17:04:50 +0000

Вот так пользуюсь: (надо посмотреть как загрузить из файла, не помню уже)

IDC_APPSTARTING := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32650, "UPtr")
IDC_ARROW := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32512, "UPtr")
IDC_CROSS := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32515, "UPtr")
IDC_HAND := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32649, "UPtr")
IDC_HELP := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32651, "UPtr")
IDC_IBEAM := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32513, "UPtr")
IDC_ICON := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32641, "UPtr")
IDC_NO := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32648, "UPtr")
IDC_SIZE := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32640, "UPtr")
IDC_SIZEALL := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32646, "UPtr")
IDC_SIZENESW := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32643, "UPtr")
IDC_SIZENS := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32645, "UPtr")
IDC_SIZENWSE := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32642, "UPtr")
IDC_SIZEWE := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32644, "UPtr")
IDC_UPARROW := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32516, "UPtr")
IDC_WAIT := DllCall("User32.dll\LoadCursor", "Ptr", NULL, "Int", 32514, "UPtr")


  DllCall("SetSystemCursor",Ptr,IDC_SIZEALL,Int,32512) ; установить курсор на загруженный в переменную "IDC_SIZEALL"

  DllCall("SystemParametersInfo",UInt,0x57,UInt,0,UInt,0,UInt,0) ; вернуть по умолчанию.

Вот с DLL'ки (источник):

hModule := DllCall("LoadLibrary", str, "dllName.dll") ; load dll into memory
DllCall("User32.dll\LoadCursor", UPtr, hModule, Str, "CursorName") ; call loadcursor passing the result from DllMain..

AHK: Смена курсора

null@example.com (Foma) — Wed, 06 May 2015 16:37:28 +0000

Как сменить курсор на другой системный так, чтобы он не менялся в зависимости от действия и местоположения? Всё что нашёл на эту тему либо не работает, либо меняет курсор непредсказуемо. То при перетаскивании вдруг меняется, то над полем Edit, то ещё как-то.
Помогите назначить на нужный курсор(любой, но неизменный), а потом вернуть всё к стандарту.