Re: AHK: Динамическое количество изображений в GUI

null@example.com (serzh82saratov) — Sat, 01 Aug 2015 10:10:16 +0000

их может быть разное количество(от 1 до 10).

Для любого количества.


inX1 := 121.0988922, inX2 := 454.7867432
inY1 := 85.5152516, inY2 := -350.3629761

inW := Abs(inX2-inX1), inH := Abs(inY2-inY1)

guiW := 200, guiH := Ceil(guiW * (inW / inH)) ; ширина карты

markW := 5, markH := 5 ; размеры маркера
PrCount := 0
 
Gui, Margin, 0, 0
Gui, Color, DA952D
Gui -DPIScale +AlwaysOnTop
Gui, Show, % " NA w" guiW + markW " h" guiH + markH 
 
Loop 
{ 
    Random, Count, 1, 20
    If (Count < PrCount)
        Loop % PrCount - Count 
            Index := Count + A_Index, DllCall("DestroyWindow", "Ptr", hPoi%Index%)
    Else If (Count > PrCount)
        Loop % Count - PrCount
            Gui, Add, Progress, % "BackgroundD26419F w" markW " h" markH " hwndhPoi" PrCount + A_Index  
    Loop % PrCount := Count
    {
        Random, X, inX1, inX2
        Random, Y, inY2, inY1
        RelativeMovePoi(X, Y, hPoi%A_Index%) 
    } 
    SetTimer, Flash, % "-" (SH := 0)
    Gui, Show, NA, % Count
    Sleep 888
} 
 
RelativeMovePoi(posX, posY, HWND)  {  
    Local outX, outY
    outX := guiW * (Abs(posX - inX1) / inW) 
    outY := guiH * (Abs(posY - inY1) / inH) 
    GuiControl, Move, %HWND%, x%outX% y%outY% 
}

Flash: 
    Loop % Count + ((SH := !SH) * 0)
        GuiControl,  % SH ? "Show" : "Hide", % hPoi%A_Index%
    SetTimer, Flash, -111
    Return

AHK: Динамическое количество изображений в GUI

null@example.com (Dworkin) — Fri, 31 Jul 2015 22:52:05 +0000

Доброй ночи.
Помогите пожалуйста разобраться кое в чем.
Это продолжение старой темы на этом сайте: http://forum.script-coding.com/viewtopic.php?id=8731

Например возьмем код из поста номер 16 прошлой темы.
В этом коде происходит отображение точки на координатной плоскости.

inX1 := 121.0988922, inX2 := 454.7867432
inY1 := 85.5152516, inY2 := -350.3629761

inW := Abs(inX2-inX1), inH := Abs(inY2-inY1)

guiW := 200, guiH := Ceil(guiW * (inW / inH)) ; ширина карты
 
markW := 5, markH := 5 ; размеры маркера
 
Gui, Margin, 0, 0
Gui, Color, DA952D
Gui -DPIScale +AlwaysOnTop
Gui, Add, Progress, x205 y161 w%markW% h%markH% vPoi BackgroundD26419F
Gui, Show, % " NA w" guiW + markW " h" guiH + markH 

SetTimer, Flash, -1 

RelativeMovePoi(inX2, inY1)
Sleep 555
RelativeMovePoi(inX1, inY1)
Sleep 555
RelativeMovePoi(inX1, inY2) 
Sleep 555
RelativeMovePoi(inX2, inY2)  
Sleep 555
RelativeMovePoi(196.4629517, -256.4821167)
return


RelativeMovePoi(posX, posY)  {
    Global
    outX := guiW * (Abs(posX - inX1) / inW) 
    outY := guiH * (Abs(posY - inY1) / inH) 
    GuiControl, Move, Poi, x%outX% y%outY%
    GuiControl, Show, Poi
}

Flash: 
    GuiControl,  % (T := !T) ? "Show" : "Hide", Poi
    SetTimer, Flash, -133  
    return

Суть вопроса вот в чем. После подобного куска кода идет функция, которая считывает постоянно координаты xyz всех точек которые доступны в данную секунду, а их может быть разное количество(от 1 до 10). Так вот как сделать что бы эти точки отображались в gui в зависимости от количества?

Этот код для отображения одной точки. А как сделать чтобы их отображалось 3, а через 30 секунд их уже 5, а еще через минуту уже 2 и тд.

Gui, Margin, 0, 0
Gui, Color, DA952D
Gui -DPIScale +AlwaysOnTop
Gui, Add, Progress, x205 y161 w%markW% h%markH% vPoi BackgroundD26419F
Gui, Show, % " NA w" guiW + markW " h" guiH + markH

Если бы количество точек было всегда точное то было бы проще.

Серый форум — AHK: Динамическое количество изображений в GUI

Re: AHK: Динамическое количество изображений в GUI

AHK: Динамическое количество изображений в GUI