Серый форум — AHK: Показать свёрнутое окно не активируя его

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (serzh82saratov) — Sun, 09 Aug 2015 12:34:06 +0000

Alectric молодца! Вот то, что нужно было:


ShowWindow(WinExist("ahk_class Notepad ahk_exe notepad.exe"), 1, 1)

ShowWindow(hwnd, x="", y="", w="", h="") {  
  DllCall("ShowWindow", "ptr", hwnd, "Int", 4) ; SW_SHOWNOACTIVATE=4
  WinMove, % "ahk_id" hwnd, , % x, % y, % w, % h  
}

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (Alectric) — Sun, 09 Aug 2015 09:40:00 +0000

А нет, все в порядке вроде.

showWin("ahk_class Notepad ahk_exe notepad.exe")

showWin(win,x=0,y=0,w=600,h=400)
{
  hwnd:=WinExist("A")
  WinExist(win)
  WinSet, ExStyle, +0x08000000 ; WS_EX_NOACTIVATE
  winset,AlwaysOnTop,on
  DllCall("ShowWindow", "ptr",WinExist("ahk_class Notepad ahk_exe notepad.exe"), "Int", 4) ; SW_SHOWNOACTIVATE=4
  WinMove, , ,% x,% y,% w,% h
  WinSet, ExStyle, -0x08000000
  winset,AlwaysOnTop,off
}

Опять глюки, да что ж такое то сегодня... И опять мультипост.

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (Alectric) — Sun, 09 Aug 2015 09:22:21 +0000

Больше ничем не могу помочь, могу только "костыли" писать.

...
Может через ShowWindow function?

...
Попробовал с параметром "SW_SHOWNOACTIVATE", все равно активируется.

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (serzh82saratov) — Sun, 09 Aug 2015 09:19:33 +0000

Так, активное окно ненадолго деактивируется.

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (Alectric) — Sun, 09 Aug 2015 09:15:09 +0000

Тогда такой странный метод:

h:=WinExist("A")
WinExist("ahk_class Notepad ahk_exe notepad.exe")
WinSet, ExStyle, +0x08000000 ; WS_EX_NOACTIVATE
winset,AlwaysOnTop,on
winrestore
WinMove, , , 5, 5, 555, 555
WinSet, ExStyle, -0x08000000
winactivatebottom,% "ahk_id " h
winset,AlwaysOnTop,off
Return

Оформил в функцию:


showWin("ahk_class Notepad ahk_exe notepad.exe")

showWin(win,x=0,y=0,w=600,h=400)
{
  hwnd:=WinExist("A")
  WinExist(win)
  WinSet, ExStyle, +0x08000000 ; WS_EX_NOACTIVATE
  winset,AlwaysOnTop,on
  winrestore
  WinMove, , ,% x,% y,% w,% h
  WinSet, ExStyle, -0x08000000
  winactivatebottom,% "ahk_id " hwnd
  winset,AlwaysOnTop,off
}

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (serzh82saratov) — Sun, 09 Aug 2015 09:02:21 +0000

И правда забыл, но у меня при показе свёрнутого окна, активное деактивируется.

Re: AHK: Показать свёрнутое окно не активируя его

null@example.com (Alectric) — Sun, 09 Aug 2015 03:37:31 +0000

Забыли про "WinRestore":

WinExist("ahk_class Notepad ahk_exe notepad.exe")
; WinGetPos, x, y, W, H
; ToolTip % x "|" y "|" W "|" H
WinSet, ExStyle, +0x08000000 ; WS_EX_NOACTIVATE
winrestore
WinMove, , , 5, 5, 555, 555
WinSet, ExStyle, -0x08000000
Return

AHK: Показать свёрнутое окно не активируя его

null@example.com (serzh82saratov) — Sat, 08 Aug 2015 22:47:16 +0000

Может не вижу чего то лежащего на поверхности, не соображу как показать свёрнутое окно стороннего приложения, не активируя его, и желательно сразу в заданных координатах.

В принципе не активировать можно так:

WinExist("ahk_class Notepad ahk_exe notepad.exe")
; WinGetPos, x, y, W, H 
; ToolTip % x "|" y "|" W "|" H
WinSet, ExStyle, +0x08000000 ; WS_EX_NOACTIVATE
WinMove, , , 5, 5, 555, 555
WinSet, ExStyle, -0x08000000
Return

Но размеры не задаются, окно появляется в минимальном размере, а хотелось бы прежние размеры до сворачивания.
Со своим окном всё просто:

Gui, Show, w333 h333
Return

1::Gui, Show, Noactivate x1 y1