Серый форум — AHK: Создание текcтового документа в текущей директории

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (Oleksandr) — Thu, 01 Apr 2021 06:12:55 +0000

teadrinker
Ваш пример с моим кодом не дружит, пишет else без if..., возможно я что-то не понял..

Я тут немного еще пошаманил, и дополнил свой предыдущий код, что-бы было нагляднее понятно как это работает. Есть 3 файла. Сам скрипт и два шаблона Example.docx, Example.ahk. При создании файла, он просто копируеться и создаеться в той папке, в которой нахожусь.

Так вот.., при создании файла, через раз срабатывает в проводнике., но в основном создает файл на рабочем столе.
Пробовал WinActivate, в проводнике, но это не сработало.


q::
Gui 2: New, % "+AlwaysOnTop +Owner hwndhGui +E" . WS_EX_NOACTIVATE := 0x08000000
Gui 2: +HwndSystemMenu
Gui 2: Font, s16, Consolas
Gui 2: Add, Button, g1 x0 y0 w330 h40, Create .ahk
Gui 2: Add, Button, g2 x0 y40 w330 h40, Create .docx
Gui 2: Show, w330 h80, Create Menu

1:
ExampleAHK()
Return
2:
ExampleWord()
Return

ExampleAHK() {
OldFile := "Example.ahk"
FileName := "ExampleScript"                           ; шаблон имени нового файла
; NewFileName := FolderPath "\" FileName ".ahk"
   
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW|AutoHotkeyGUI")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   if (FolderPath = "")  {
      MsgBox, Активное окно не является окном Проводника
      Return
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   
   NewFileName := FolderPath "\" FileName ".ahk"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.ahk", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").ahk"
   }

 ;FileAppend,, % NewFileName        ; Create New File
;#WinActivate, ahk class ExploreWClass|CabinetWClass
FileCopy, %OldFile%, %NewFileName%    ; Copy File to FolderPath
;#WinActivate ;
 ; Run, % NewFileName               ; Run This File
 Return                       ; The End Script  
}

ExampleWord() {
OldFile := "Example.docx"
FileName := "Example"                           ; шаблон имени нового файла
; NewFileName := FolderPath "\" FileName ".ahk"
   
   WinGetClass, class, A
    if (class ~= "Progman|WorkerW|AutoHotkeyGUI")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   if (FolderPath = "")  {
      MsgBox, Активное окно не является окном Проводника
      Return
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   
   NewFileName := FolderPath "\" FileName ".docx"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.docx", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").docx"
   }

 ;FileAppend,, % NewFileName        ; Create New File
;#WinActivate, ahk class ExploreWClass|CabinetWClass
FileCopy, %OldFile%, %NewFileName%    ; Copy File to FolderPath
;#WinActivate ;
 ; Run, % NewFileName               ; Run This File
 Return 
}

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Wed, 31 Mar 2021 22:13:54 +0000

Попробуйте так:

Gui, New, % "+AlwaysOnTop +Owner hwndhGui +E" . WS_EX_NOACTIVATE := 0x08000000
Gui, Font, s16, Consolas
Gui, Add, Button, gExample x0 y0 w330 h40 vAHK, Create .ahk
Gui, Add, Button, gExample x0 y40 w330 h40 vDOC, Create .docx
Return

q:: Gui, %hGui%: Show, NA w330 h80, Create Menu

Example() {
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   if (FolderPath = "")  {
      MsgBox, Активное окно не является окном Проводника
      Return
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   if (A_GuiControl = "AHK")
      MsgBox, 4096, Здесь код для создания AHK, Папка:`n%FolderPath%
   else
      MsgBox, 4096, Здесь код для создания документа, Папка:`n%FolderPath%
   Return
}

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (Oleksandr) — Wed, 31 Mar 2021 21:30:49 +0000

teadrinker пишет:

Так можно:

Очень хороший код. Я его немного дополнил, чтобы создать меню, и делать Копию Файла ( Шаблоны ). Но на GUI, Это не работает из-за того, что "Активное окно не является окном Проводника". Не могли бы вы поправить меня. Заранее благодарю.

q::
Gui 2: +HwndSystemMenu
Gui 2: Font, s16, Consolas
Gui 2: Add, Button, g1 x0 y0 w330 h40, Create .ahk
Gui 2: Add, Button, g2 x0 y40 w330 h40, Create .docx
Gui 2: Show, w330 h80, Create Menu

1:
Example()
Return
2:
Example()
Return

Example() {
OldFile := "Example.ahk"
FileName := "ExampleScript"                           ; шаблон имени нового файла
; NewFileName := FolderPath "\" FileName ".ahk"
   
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW|AutoHotkeyGUI")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   if (FolderPath = "")  {
      MsgBox, Активное окно не является окном Проводника
      Return
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   
   NewFileName := FolderPath "\" FileName ".ahk"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.ahk", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").ahk"
   }

 ;FileAppend,, % NewFileName        ; Create New File
 FileCopy, %OldFile%, %NewFileName%    ; Copy File to FolderPath
 ; Run, % NewFileName               ; Run This File
 Return                       ; The End Script  
}

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (vzregit) — Sun, 20 May 2018 16:10:19 +0000

А не подскажите, как код 14 поста переделать, чтобы у меня он сразу создавал и открывал файл, а после выполнения скрипт завершал работу сам. Я планирую запускать его по горячей клавише.

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (tregalka) — Tue, 05 Apr 2016 14:24:03 +0000

teadrinker
Спасибо!!!

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Tue, 05 Apr 2016 10:39:01 +0000

FileName := "NewText"  ; шаблон имени нового файла
SetTitleMatchMode, Regex
Return

#IfWinActive ahk_class ((Cabinet|Explore)WClass|Clover_WidgetWin_0)
^!vk4E::  ; Ctrl + Alt + N
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until DllCall("GetAncestor", Ptr, WinExist("A"), "UInt", GA_ROOT := 2, Ptr) = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
	
   NewFileName := FolderPath "\" FileName ".txt"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.txt", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").txt"
   }

   FileAppend,, % NewFileName
   Run, % NewFileName
   Return

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Mon, 25 Jan 2016 19:01:31 +0000

Оно и не должно работать нигде, кроме обычного проводника, там ведь директива

#IfWinActive ahk_class (Progman|WorkerW|CabinetWClass)

Код рассчитан только на работу с проводником. Уверен, что с программой Clover тоже можно как-то работать, но у меня она не установлена.

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (tregalka) — Mon, 25 Jan 2016 17:07:12 +0000

teadrinker

Приветствую!
Пробовал у себя 2й вариант вашего скрипта, в проводнике работает идеально!
Но как быть, если я постоянно работаю в программе Clover, там работать ничего не хочет : (
Когда нажимаешь комбинацию клавиш на рабочем столе то тишина.
Когда в проводнике (Clover) выходит такое сообщение - Не удается найти указанный файл

Смотрел Clover с помощью утилиты ahk (AU3_Spy) процесс (название окна) вроде тот же что и у родного Проводника

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (hauk70) — Mon, 17 Aug 2015 20:00:15 +0000

Спасибо, все заработало, сканкоды нужных клавиш нашел и забиндил, тему можно закрывать.

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Mon, 17 Aug 2015 19:47:37 +0000

FileName := "NewText"  ; шаблон имени нового файла

должно быть до первой горячей клавиши, иначе не выполняется.

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (hauk70) — Mon, 17 Aug 2015 19:43:53 +0000

Код особо не менял
файлы создаются с именами ".txt", "(2).txt", "(3).txt" и тд
Если убрать код на новый идентификатор он будет открывать первый созданный или с таким же именем файл, а не создавать новые. А спросил потому что было интересно.

#SingleInstance force

+SPACE:: 
Winset, Alwaysontop, Toggle, A, 
Return

FileName := "NewText"  ; шаблон имени нового файла

#vk4E::  ; Ctrl + Alt + N
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }

   if (FolderPath = "")  {
      Return
   }

   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   
   NewFileName := FolderPath "\" FileName ".txt"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.txt", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").txt"
   }

   FileAppend,, % NewFileName
   Run, % NewFileName
   Return

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Mon, 17 Aug 2015 19:17:19 +0000

Про мультимедийные клавиши точно не знаю, у меня старая клавиатура. Про первое зы не понял, у меня всё создаётся нормально. Если у вас что-то не так, приведите код, как он выглядит у вас. Про второе зы можете сами попробовать, зачем спрашивать.

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (hauk70) — Mon, 17 Aug 2015 19:07:39 +0000

Второй вариант не сработал, первый взял и настроил хоткеи под свою руку из чего вытекает новый вопрос - можно повесить скрипт на любую код кнопки и вывести этот код?(мультимедийные клавиши клавиатуры)

ЗЫ файлы создаются с пустым именем (".txt"), но порядковый идентификатор добавляется.
ЗЫЫ Зачем столько возни с присвоением нового идентификатора если текущий занят? разве сама виндане уследит за этим?

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (teadrinker) — Mon, 17 Aug 2015 18:33:02 +0000

А работает?
Так можно:

FileName := "NewText"  ; шаблон имени нового файла

^!vk4E::  ; Ctrl + Alt + N
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   if (FolderPath = "")  {
      MsgBox, Активное окно не является окном Проводника
      Return
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   
   NewFileName := FolderPath "\" FileName ".txt"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.txt", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").txt"
   }

   FileAppend,, % NewFileName
   Run, % NewFileName
   Return

Или, чтобы работало только в окнах Проводника и Рабочего стола:

FileName := "NewText"  ; шаблон имени нового файла
SetTitleMatchMode, Regex
Return

#IfWinActive ahk_class (Progman|WorkerW|CabinetWClass)
^!vk4E::  ; Ctrl + Alt + N
   WinGetClass, class, A
   if (class ~= "Progman|WorkerW")
      FolderPath := A_Desktop
   else  {
      for item in ComObjCreate("Shell.Application").Windows
         continue
      until WinExist("A") = item.hwnd || item := ""
      FolderPath := item.Document.Folder.Self.Path
   }
   SplitPath, FolderPath,,,,, Drive
   if InStr(Drive, "::")  {
      MsgBox, Это служебная папка, в ней нельзя создать файл
      Return
   }
   NewFileName := FolderPath "\" FileName ".txt"
   
   While FileExist(NewFileName)  {
      RegExMatch(NewFileName, "i).*\\" FileName " \((\d+)\)\.txt", number)
      NewFileName := FolderPath "\" FileName " (" . (number1 = "" ? 2 : number1 + 1) . ").txt"
   }

   FileAppend,, % NewFileName
   Run, % NewFileName
   Return

Re: AHK: Создание текcтового документа в текущей директории

null@example.com (hauk70) — Mon, 17 Aug 2015 17:48:11 +0000

Создание текстового документа на рабочем столе было бы очень хорошим дополнением и так то вводить имя файла не всегда удобно, поэтому что-то такое корректно?


   New File (example: foo.txt)   
   FileAppend,, %FolderPath%\foo.txt
   Run, %FolderPath%\foo.txt