Серый форум — AHK: ProgressBar при копировании иногда пишет Not Responding

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Fri, 25 Sep 2015 20:36:56 +0000

Почитайте здесь. Возможно, какая-то из описанных проблем.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (unKn0wn) — Fri, 25 Sep 2015 19:25:11 +0000

Скачал инсталлер по приведённой мною ссылке, запустил его-modify-32 unicod. Проблема осталась.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Fri, 25 Sep 2015 18:24:15 +0000

скрипт пишет, что autohotkey не является приложением win32

Переустановите ещё раз с помощью инсталлера, смотрите внимательно, что устанавливаете.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Fri, 25 Sep 2015 18:05:43 +0000

Любой код на форуме пишется в расчёте на самую последнюю версию AHK.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (unKn0wn) — Fri, 25 Sep 2015 17:55:54 +0000

Точно, спасибо. Для тех, кто столкнётся, с проблемой при запуске: Autohotkey_L

Всё-же рано радовался, теперь мне скрипт пишет, что autohotkey не является приложением win32 -хотя, я устанавливал версию 32 unicod.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Fri, 25 Sep 2015 17:47:24 +0000

Обновите AHK.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (unKn0wn) — Fri, 25 Sep 2015 17:39:50 +0000

Пытался выполнить код, что сообщением выше, но не получилось. Не подскажите в чем дело?

(7) : ==> The following variable name contains an illegal character:
"CopyFile.end"

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Tue, 22 Sep 2015 11:05:03 +0000

Или так всё-таки, не знаю, как лучше.

CopyFile.Start( "source.txt"   ; путь к файлу 
               , "dest.txt"    ; путь копирования
               , 250           ; ширина прогрессбара
               , 400           ; x-координата окна
               , 300 )         ; y-координата окна

while !CopyFile.end
   Sleep, 500
ExitApp

class CopyFile
{
   Start(source, dest, w = 300, x = "", y = "")  {
      this.end := 0
      if FileExist(dest)  {
         MsgBox, 0x34,, Файл "%dest%" уже существует.`nПерезаписать?
         IfMsgBox, No
            Return,, this.end := 1
      }
      Gui, New, +hwndhGui
      this.hGui := hGui
      Gui, Margin,, 10
      Gui, Add, Progress, w%w% h20 -Smooth, 0
      Gui, Add, Button, gCancelCopy x+-80 y+10 w80, Cancel
      Gui, Show, % (x != "" && y != "") ? "x" x " y" y : "", Идёт копирование...
      
      OnMessage(DllCall("RegisterWindowMessage", Str, "WM_INFO"), "WM_INFO")
      this.CopyPID := ExecScript(this.GetScript(source, dest))
      OnExit("CancelCopy")
   }
   
   GetScript(source, dest)  {
      CopyScript =
      (
         #NoTrayIcon
         ERROR_REQUEST_ABORTED := 1235, COPY_FILE_NO_BUFFERING := 0x1000
         source := "%source%", dest := "%dest%"
         WM_INFO := DllCall("RegisterWindowMessage", Str, "WM_INFO")
         DetectHiddenWindows, On
         WinWait, ahk_id %A_ScriptHwnd%
         VarSetCapacity(cancel, 4, 0)
         PostMessage, WM_INFO, 1, &cancel
         
         addr := RegisterCallback("ProgressControl", "F", 4, WM_INFO)
         FileGetSize, size, `% source, M
         if !DllCall("CopyFileEx", Str, source, Str, dest, Ptr, addr, Ptr, 0, Ptr, &cancel, UInt, size > 1024 ? COPY_FILE_NO_BUFFERING : 0)
            PostMessage, WM_INFO, 0, A_LastError = ERROR_REQUEST_ABORTED ? 0 : A_LastError
         else
            PostMessage, WM_INFO, 3
         ExitApp
         
         ProgressControl(TotalFileSize, TotalBytesTransferred, StreamSize, StreamBytesTransferred)  {
            PostMessage, A_EventInfo, 2, Round((A_PtrSize = 8 ? TotalBytesTransferred : StreamSize)/TotalFileSize * 100)
         }
      )
      Return CopyScript
   }
}

CancelCopy()
{
   static PROCESS_VM_OPERATION := 0x8, PROCESS_VM_WRITE := 0x20
   Process, Exist, % CopyFile.CopyPID
   if !ErrorLevel
      Return
   
   hProc := DllCall("OpenProcess", UInt, PROCESS_VM_OPERATION|PROCESS_VM_WRITE, Int, 0, UInt, CopyFile.CopyPID, Ptr)
   DllCall("WriteProcessMemory", Ptr, hProc, Ptr, CopyFile.CancelPtr, UIntP, 1, Ptr, 4, PtrP, Written)
   DllCall("CloseHandle", Ptr, hProc)
   OnExit("CancelCopy", 0)
}

WM_INFO(wp, lp)
{
   Critical
   Gui, % CopyFile.hGui ":Default"
   if (wp = 1)
      CopyFile.CancelPtr := lp
   
   if (wp = 2)  {
      GuiControl,, msctls_progress321, % lp
      Gui, Show, NA, % "Идёт копирование... " . lp . "%"
   }
   if (wp = 0 && lp = 0)  {
      GuiControl,, msctls_progress321, 0
      Gui, Show, NA, Отменено
      Sleep, 1000
      Gui, Destroy
   }
   if (wp = 0 && lp != 0)  {
      GuiControl,, msctls_progress321, 0
      Gui, Show, NA, Ошибка
      MsgBox, 16, Error, Ошибка копирования %lp%
      Gui, Destroy
   }
   if (wp = 3)  {
      GuiControl,, msctls_progress321, 100
      Gui, Show, NA, Успешно завершено
      Sleep, 1000
      Gui, Destroy
   }
   if wp in 0,3
      OnExit("CancelCopy", 0), CopyFile.end := 1
}

ExecScript(Script)
{
   shell := ComObjCreate("WScript.Shell")
   exec := shell.Exec(A_AhkPath " *")
   exec.StdIn.Write(script)
   exec.StdIn.Close()
   return exec.ProcessID
}

Так можно параллельно с копированием делать что-то ещё.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Tue, 22 Sep 2015 10:51:26 +0000

Подправил немного.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (Flasher) — Tue, 22 Sep 2015 09:55:50 +0000

Ну, какая разница? Так поведенчески логичней.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Tue, 22 Sep 2015 09:51:16 +0000

Почему, это ведь не самостоятельный скрипт, это просто функция для копирования, которую можно вставить куда угодно.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (Flasher) — Tue, 22 Sep 2015 09:48:07 +0000

teadrinker
Гуд, только по окончанию надо бы убирать прогресс вместе со скриптом из трея, клавиша не назначена всё равно.

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (teadrinker) — Tue, 22 Sep 2015 09:01:25 +0000

До кучи асинхронное копирование:

CopyFile.Start( "source.txt"   ; путь к файлу 
               , "dest.txt"    ; путь копирования
               , 250           ; ширина прогрессбара
               , 400           ; x-координата окна
               , 300 )         ; y-координата окна
               
ExitApp

class CopyFile
{
   Start(source, dest, w = 300, x = "", y = "")  {
      this.end := 0
      if FileExist(dest)  {
         MsgBox, 0x34,, Файл "%dest%" уже существует.`nПерезаписать?
         IfMsgBox, No
            Return
      }
      Gui, New, +hwndhGui
      this.hGui := hGui
      Gui, Margin,, 10
      Gui, Add, Progress, w%w% h20 -Smooth, 0
      Gui, Add, Button, gCancelCopy x+-80 y+10 w80, Cancel
      Gui, Show, % (x != "" && y != "") ? "x" x " y" y : "", Идёт копирование...
      
      OnMessage(DllCall("RegisterWindowMessage", Str, "WM_INFO"), "WM_INFO")
      this.CopyPID := ExecScript(this.GetScript(source, dest))
      OnExit("CancelCopy") 
      while !this.end
         Sleep, 500
   }
   
   GetScript(source, dest)  {
      CopyScript =
      (
         #NoTrayIcon
         ERROR_REQUEST_ABORTED := 1235, COPY_FILE_NO_BUFFERING := 0x1000
         source := "%source%", dest := "%dest%"
         WM_INFO := DllCall("RegisterWindowMessage", Str, "WM_INFO")
         DetectHiddenWindows, On
         WinWait, ahk_id %A_ScriptHwnd%
         VarSetCapacity(cancel, 4, 0)
         PostMessage, WM_INFO, 1, &cancel
         
         addr := RegisterCallback("ProgressControl", "F", 4, WM_INFO)
         FileGetSize, size, `% source, M
         if !DllCall("CopyFileEx", Str, source, Str, dest, Ptr, addr, Ptr, 0, Ptr, &cancel, UInt, size > 1024 ? COPY_FILE_NO_BUFFERING : 0)
            PostMessage, WM_INFO, 0, A_LastError = ERROR_REQUEST_ABORTED ? 0 : A_LastError
         else
            PostMessage, WM_INFO, 3
         ExitApp
         
         ProgressControl(TotalFileSize, TotalBytesTransferred, StreamSize, StreamBytesTransferred)  {
            PostMessage, A_EventInfo, 2, Round((A_PtrSize = 8 ? TotalBytesTransferred : StreamSize)/TotalFileSize * 100)
         }
      )
      Return CopyScript
   }
}

CancelCopy()
{
   static PROCESS_VM_OPERATION := 0x8, PROCESS_VM_WRITE := 0x20
   Process, Exist, % CopyFile.CopyPID
   if !ErrorLevel
      Return
   
   hProc := DllCall("OpenProcess", UInt, PROCESS_VM_OPERATION|PROCESS_VM_WRITE, Int, 0, UInt, CopyFile.CopyPID, Ptr)
   DllCall("WriteProcessMemory", Ptr, hProc, Ptr, CopyFile.CancelPtr, UIntP, 1, Ptr, 4, PtrP, Written)
   DllCall("CloseHandle", Ptr, hProc)
   OnExit("CancelCopy", 0)
}

WM_INFO(wp, lp)
{
   Critical
   Gui, % CopyFile.hGui ":Default"
   if (wp = 1)
      CopyFile.CancelPtr := lp
   
   if (wp = 2)  {
      GuiControl,, msctls_progress321, % lp
      Gui, Show, NA, % "Идёт копирование... " . lp . "%"
   }
   if (wp = 0 && lp = 0)  {
      GuiControl,, msctls_progress321, 0
      Gui, Show, NA, Отменено
      Sleep, 1000
      Gui, Destroy
   }
   if (wp = 0 && lp != 0)  {
      GuiControl,, msctls_progress321, 0
      Gui, Show, NA, Ошибка
      MsgBox, 16, Error, Ошибка копирования %lp%
      Gui, Destroy
   }
   if (wp = 3)  {
      GuiControl,, msctls_progress321, 100
      Gui, Show, NA, Успешно завершено
      Sleep, 1000
      Gui, Destroy
   }
   if wp in 0,3
      OnExit("CancelCopy", 0), CopyFile.end := 1
}

ExecScript(Script)
{
   shell := ComObjCreate("WScript.Shell")
   exec := shell.Exec(A_AhkPath " *")
   exec.StdIn.Write(script)
   exec.StdIn.Close()
   return exec.ProcessID
}

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (Malcev) — Tue, 22 Sep 2015 05:47:00 +0000

Вот еще один вариант:
Можно копировать через Robocopy и захватывать информацию с CMD с помощью:
http://www.autohotkey.com/board/topic/9 … douttovar/

Re: AHK: ProgressBar при копировании иногда пишет Not Responding

null@example.com (serzh82saratov) — Mon, 21 Sep 2015 09:42:29 +0000

Думаю нет.