Серый форум — AHK: Автоподстройка высоты окна GUI под содержимое

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 23:55:52 +0000

Да и тут:

gui, show, w400 autosize

w400 ничего не даёт, ведь действует autosize.

В общих случаях как то так:


col = navy
font = Calibri

sender1 = Джубадзе
sender2 = Меладзе
sender3 = Орджоникидзе

text1 = В чащах юга жил был кактус, но фальшивый экземпляр. Слово экземпляр и этот текст уже не отображаются.`n|
text2 = Только что методом научного тыка (guicontrol, move, m, h200) выяснил, что сам по себе текст на следующую строку переносится, проблема только в том, что не ресайзится окно, не подстраивается под текст.`n|
text3 = В чащах юга жил был кактус`n|

gui, Margin, 88
gui, font, s14 c%col%, %font%
gui, add, text, w380 center hwndhtext
gui, add, button, default vbutton, |    |    | 
gosub Move

Loop {
    Sleep 600 
    DllCall("DestroyWindow", "Ptr", htext)
    i := (i="" || i = 3) ? 0 : ++i
    gui, add, text, w380 xm ym center hwndhtext, % text%i% 
    gosub Move
}

Move:
    GuiControlGet, text_, Pos, %htext%
    GuiControlGet, but_, Pos, button
    guicontrol, move, button, % "y" text_y+text_h+10 "x" text_x+round((text_w/2)-(but_w/2))
    gui, show, autosize, % "Сообщение от " sender%i%
    Return

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 23:49:14 +0000

Хотя в документации сказано, что текстовый блок добавляется borderless, т.е. без оконтовочных пикселей

Читайте Margin.

Если обнулить Margin, то и ваш старый код подойдёт:


gui, +hwndguihwnd
gui, Margin, 0 
gui, font, s14 c%col%, %font%
gui, add, text, w380 center vt
gui, add, button, x1 y+10 default vb, |   |   |
GuiControlGet, posb, Pos, b

DllCall("DestroyWindow", "Ptr", t)
gui, add, text, w380 xm ym center hwndt, |   |   |
GuiControlGet, post, Pos, %t%

guicontrol, move, b, % "y" posty+posth+10 "x" round((postw/2)-(posbw/2))
gui, show, w400 autosize center, Сообщение от %sender%
winwaitclose, ahk_id %guihwnd%
return

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 23:43:29 +0000

А, ну т.е. отсчёт надо было явно ставить от текстового блока. Хотя в документации сказано, что текстовый блок добавляется borderless, т.е. без оконтовочных пикселей. Ну да ладно, видимо у них всё-таки есть какая-то оконтовка (не у текстового блока, так у самого gui).
В общем, вот что получилось, может, кому пригодится:

#SingleInstance force
#NoEnv
SetBatchLines, -1
SetTitleMatchMode, 3

sender = Джубадзе
col = navy
font = Calibri
tex = В чащах юга жил был кактус, но фальшивый экземпляр.

gui, +hwndguihwnd
gui, font, s14 c%col%, %font%
gui, add, text, w400 center vt
gui, add, button, x156 y+10 default vb, Хорошо!
GuiControlGet, posb, Pos, b

DllCall("DestroyWindow", "Ptr", t)
gui, add, text, w400 xm ym center hwndt, %tex%
GuiControlGet, post, Pos, %t%

guicontrol, move, b, % "y" posty+posth+10 "x" postx+round((postw/2)-(posbw/2))
gui, show, w400 autosize center, Сообщение от %sender%
winwaitclose, ahk_id %guihwnd%

buttonХорошо!:
guiclose:
gui, destroy
exitapp
return

Большое спасибо serzh82saratov-у! Вы мне очень помогли!

P.S. Кстати, то что у меня в одном месте стояло 380, а в другом 400, на позицию кнопки не влияло. Я пробовал ставить 400 везде, но кнопка всё равно была смещена влево. Это прошло только когда я задал postx+round((postw/2)-(posbw/2))

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 23:11:21 +0000

gui, font, s14 c%col%, %font% 
gui, add, button, x1 y+10 default vb, I        I        I  
DllCall("DestroyWindow", "Ptr", t)
gui, add, text, w380 xm ym center hwndt, I
GuiControlGet, text, Pos, %t%
GuiControlGet, button, Pos, b
guicontrol, move, b, % "y" texty+texth "x" textx+textw//2-buttonw//2 
gui, show, w400 autosize center, Сообщение от %sender%
return

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 23:01:51 +0000

Да, спасибо. С хэндлами я не очень дружу.
Но центровку всё равно сделать не получается. Кнопка явно чуть смещена влево. Где-то на 15-20 пикселей.

gui, +hwndguihwnd
gui, font, s14 c%col%, %font%
gui, add, text, w380 center vt
gui, add, button, x1 y+10 default vb, Хорошо!
GuiControlGet, posb, Pos, b

DllCall("DestroyWindow", "Ptr", t)
gui, add, text, w380 xm ym center hwndt, %tex%
GuiControlGet, post, Pos, %t%

guicontrol, move, b, % "y" posty+posth+10 "x" round((postw/2)-(posbw/2))
gui, show, w400 autosize center, Сообщение от %sender%
winwaitclose, ahk_id %guihwnd%

buttonХорошо!:
guiclose:
gui, destroy
msgbox, % round((postw/2)-(posbw/2))
exitapp
return

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 22:29:34 +0000

Не с текстовой областью, а с переменной содержащей хэндл.
Есть разница?

gui, add, text, w380 center hwndt

gui, add, text, w380 center vt

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 22:24:58 +0000

Да, действительно. А почему с текстовой областью нужны проценты, а с кнопкой нет?

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 22:21:13 +0000

GuiControlGet, posb, Pos, b

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 22:17:08 +0000

Пытаюсь сделать точную центровку по горизонтали. Не удаётся получить данные только что созданного элемента. Вот:

#SingleInstance force
#NoEnv
SetBatchLines, -1
SetTitleMatchMode, 3

sender = Джубадзе
col = navy
font = Calibri
tex = В чащах юга жил был кактус, но фальшивый экземпляр. Слово экземпляр и этот текст уже не отображаются. Здесь пишу произвольный длинный текст, проверяю отображение при длинном тексте. Ехал грека через реку, видит грека – в реке рак, сунул грека руку в реку, рак за руку грека цап!

gui, +hwndguihwnd
gui, font, s14 c%col%, %font%
gui, add, text, w380 center vt
gui, add, button, x155 y+10 default vb, Хорошо!
GuiControlGet, posb, Pos, %b%

msgbox, %posbx%
exitapp

msgbox отображает пустой текст. guicontrolget не работает с кнопками?

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 21:46:51 +0000

Вот такая морковина получилась.

#SingleInstance force
#NoEnv
SetBatchLines, -1
SetTitleMatchMode, 3

sender = Джубадзе
col = navy
font = Calibri
tex = В чащах юга жил был кактус, но фальшивый экземпляр. Слово экземпляр и этот текст уже не отображаются. Здесь пишу произвольный длинный текст, проверяю отображение при длинном тексте. Ехал грека через реку, видит грека – в реке рак, сунул грека руку в реку, рак за руку грека цап!

gui, +hwndguihwnd
gui, font, s14 c%col%, %font%
gui, add, text, w380 center vt
gui, add, button, x155 y+10 default vb, Хорошо!

DllCall("DestroyWindow", "Ptr", t)
gui, add, text, w380 xm ym center hwndt, %tex%
GuiControlGet, position, Pos, %t%
guicontrol, move, b, % "y" positiony+positionh+10
gui, show, w400 autosize center, Сообщение от %sender%
winwaitclose, ahk_id %guihwnd%

buttonХорошо!:
guiclose:
gui, destroy
exitapp
return

Но я нигде не использовал -wrap. Так и не понял, зачем он. В остальном вроде разобрался.

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 20:42:24 +0000

Да, ваш скрипт ресайзит всё как надо. Только он работает не так как было задумано. Например, в строке 12 в моём случае не нужно делать gui, show, т.к. там ещё нечего показывать. Но когда я закомментировал эту строку, то скрипт вообще перестал что-либо показывать. Многое в коде непонятно (откуда берётся у+10, почему 10?, почему wrap идёт с минусом, если это как раз должно отменять перенос слов, ну и другие моменты). В общем, буду разбираться.

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 20:32:04 +0000

Indrik пишет:

Только что методом научного тыка (guicontrol, move, m, h200) выяснил, что сам по себе текст на следующую строку переносится, проблема только в том, что не ресайзится окно, не подстраивается под текст.

Немного неверно, в первую очередь размер самого контрола text не меняется при изменении в нём текста.

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (serzh82saratov) — Thu, 22 Oct 2015 20:22:14 +0000

sender = Джубадзе
col = navy
font = Calibri

tex1 = В чащах юга жил был кактус, но фальшивый экземпляр. Слово экземпляр и этот текст уже не отображаются. 
tex2 = Только что методом научного тыка (guicontrol, move, m, h200) выяснил, что сам по себе текст на следующую строку переносится, проблема только в том, что не ресайзится окно, не подстраивается под текст.
tex3 = В чащах юга жил был кактус

gui, font, s14 c%col%, %font%
gui, add, text, w380 center hwndm -Wrap
gui, add, button, x155 y+10 default vbutton, Хорошо!
gui, show, w400
return

buttonХорошо!:
    i := (!i || i = 3) ? 1 : ++i
    DllCall("DestroyWindow", "Ptr", m)
    gui, add, text, w380 xm ym center hwndm -Wrap, % tex%i%
    GuiControlGet, p, Pos, %m%
    guicontrol, move, button, % "y" py+ph+10 
    gui, show, w400   autosize, Сообщение от %sender% 
    return

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 20:18:33 +0000

Только что методом научного тыка (guicontrol, move, m, h200) выяснил, что сам по себе текст на следующую строку переносится, проблема только в том, что не ресайзится окно, не подстраивается под текст.

Re: AHK: Автоподстройка высоты окна GUI под содержимое

null@example.com (Indrik) — Thu, 22 Oct 2015 19:59:37 +0000

У вас -wrap,%tex% добавлено в момент создания окна. Но в этот момент переменная tex ещё не содержит текста (да, в этом примере содержит, но этот скрипт просто для иллюстрации), в реальном коде переменная обретает значение уже после строки

gui, add, button, x155 default, Хорошо!

Поэтому ресайзить под текст, видимо надо уже на этапе guicontrol...