Серый форум — AHK: Копировать или вставить по удержанию ЛКМ.

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Wed, 02 Dec 2015 15:28:20 +0000

stealzy если к нему добавить

if (!od and a_timeidle>700 and GetKeyState("Mbutton","P"))
  {
    od=1
    if clipboard
    {
      tooltip,Вставка.
      settimer,removetooltip,-1000
      sendinput,{Mbutton up}
      sendinput,^{vk56}
    }
  }
  else if (od and !GetKeyState("Mbutton","P"))
    od=

то позволяет

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (stealzy) — Wed, 02 Dec 2015 10:56:25 +0000

OmTatSat ваш подход тоже не позволяет заменить выделенный текст (если вы про скрипт в первом сообщении).

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Wed, 02 Dec 2015 08:56:46 +0000

stealzy минус такого подхода, заменить выбранный текст не возможно

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (stealzy) — Tue, 01 Dec 2015 21:05:59 +0000

Использую копирование-вставку по MButton(если есть выделение - копирует, иначе вставляет):

MButton::copyPaste()

copyPaste() {
	ClipSaved:=Clipboard
	Clipboard:=""
	Send ^{Ins}
	Sleep 20
	if (Clipboard="") {
		Clipboard:=ClipSaved
		Send ^{vk56} ; V
	}
}

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Tue, 01 Dec 2015 08:53:01 +0000

В принципе использование mbutton хорошее решение, оказалось оно нормально уживается с моим предыдущим использованием mbutton - разные задержки.
Ещё бы одну проблему победить, когда перетаскиваешь окно с текстом, и курсор положения в тексте в это время мигает, то происходит вставка.

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Tue, 01 Dec 2015 07:57:08 +0000

Alectric пишет:

если выделен текст, скрипт это узнает и скопирует его, вместо того чтобы вставить старый скопированный текст

У меня если по выделеному тексту зажать lbutton происходит вставка. То-есть копирование только если lbutton была зажата, перемещена, и удержана. И выделение текста пропадает прямо перед вставкой, не сразу после нажатия lbutton, скажем примерно после секунды, двух удержания.

Mbutton к сожалению уже используется.

Теперь понял, что вы имели ввиду

закомментировав

;sendinput,{lbutton up}
sendinput,^{vk43}

Ещё раз спасибо за скрипт.

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (Alectric) — Tue, 01 Dec 2015 04:34:45 +0000

OmTatSat пишет:

где при вставке делается клик

Клик ты делаешь сам.

OmTatSat пишет:

такова специфика скрипта

Верно, т.к. если выделен текст, скрипт это узнает и скопирует его, вместо того чтобы вставить старый скопированный текст.

Можно сделать вставку текста на среднюю кнопку мыши, добавив в цикл этот код:

  if (!od and a_timeidle>700 and GetKeyState("Mbutton","P"))
  {
    od=1
    if clipboard
    {
      tooltip,Вставка.
      settimer,removetooltip,-1000
      sendinput,{Mbutton up}
      sendinput,^{vk56}
    }
  }
  else if (od and !GetKeyState("Mbutton","P"))
    od=

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Mon, 30 Nov 2015 21:56:20 +0000

Alectric никак понять не могу, где при вставке делается клик из-за которого теряется выделение, соответственно теряется возможность замещения выделенного текста?
Пробовал поменять местами

sendinput,{lbutton up}
sendinput,^{vk56}

и даже вообще убрать sendinput,{lbutton up}, всё равно выделение теряется перед вставкой. Это поправимо, или такова специфика скрипта?

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (ypppu) — Mon, 30 Nov 2015 20:07:17 +0000

Alectric, ясно, способ интересный. Хотя лично мне тяжело держать кнопку пару секунд.
P. S.: Можно и на ты.

Тему следовало назвать "AHK: Копировать и вставить по удержанию ЛКМ".

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Mon, 30 Nov 2015 18:55:39 +0000

Alectric Огромное спасибо за помощь, очень удобно получилось!

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (Alectric) — Mon, 30 Nov 2015 18:46:00 +0000

?...
Странно, вроде все понятно... ну ладно: он хочет копировать текст или файлы просто зажав левую кнопку мыши, и затем вставлять, также, просто зажав левую кнопку мыши.
Как работает: выделяешь текст и, не отпуская ЛКМ кнопку, ждешь сообщения о том, что все скопировано, затем зажимаешь ЛКМ на пустом месте и ждешь сообщения, что вставлено; с файлами аналогично.

PS Можно и на ты, мы уж тут все друг друга знаем по никам и стилям кодинга... наверно.

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (ypppu) — Mon, 30 Nov 2015 18:41:28 +0000

Alectric, если Вы поняли, чего хочет OmTatSat, расскажте нам.

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (Alectric) — Mon, 30 Nov 2015 18:30:08 +0000

Не знаю как можно записать в clipboard из переменной так, чтобы система думала что скопирован файл... может кто-нибудь еще подскажет. Были темы про clipboard, нужно покапаться...

...

Вроде работает...

#SingleInstance,Force
SetKeyDelay,0
SetWinDelay,20

loop
{
  sleep,10
  if (!do and a_timeidle>700 and GetKeyState("Lbutton","P"))
  {
    do=1
    if Text:=Copy(1)
    {
      settimer,removetooltip,-2000
      if !(Text~="^\w:\\")
      {
        tooltip,Текст скопирован.`n`n%Text%
        clipboard:=Text
      }
      else
        tooltip,Файл скопирован.`n%Text%

    }
    else
    {
      tooltip,Вставка.
      settimer,removetooltip,-1000
      sendinput,{lbutton up}
      sendinput,^{vk56}
    }
  }
  else if (do and !GetKeyState("Lbutton","P"))
    do=
;tooltip,% Text "`n" a_timeidle
}
return

removetooltip:
tooltip
return

Copy(c="")
{
  tmp:=clipboardall
  if c
  {
    Clipboard=
    loop,30
    {
      sleep,10
    } until !Clipboard
    sendinput,{lbutton up}
    sendinput,^{vk43}
  }
  loop,30
  {
    sleep,10
  } until Clipboard
  txt:=Clipboard
  if !(Txt~="^\w:\\")
    Clipboard:=tmp
  return % txt
}

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (OmTatSat) — Mon, 30 Nov 2015 18:02:12 +0000

Alectric выделяю текст, зажимаю пишет всегда вставка. Случайно понял свою ошибку - после выделения не нужно отпускать кнопку, супер реализация!! Выделяю ярлыки на раб столе, пишет скопировано. Зажимаю на пустом месте раб стола, пишет вставка, но ничего не появляется. Можно сделать, чтобы скрипт мог всё копировать?

Re: AHK: Копировать или вставить по удержанию ЛКМ.

null@example.com (Alectric) — Mon, 30 Nov 2015 17:50:19 +0000

Вот такой вариант:

http://forum.script-coding.com/viewtopi … 419#p99419

Выдели текст и не отпускай кнопку до появления сообщения.