Серый форум — AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (OmTatSat) — Tue, 02 Feb 2016 09:17:47 +0000

Понял, благодарю за помощь!

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (Nikva) — Tue, 02 Feb 2016 07:40:47 +0000

OmTatSat Зависит от задачи: если нужно узнать какая была нажата кнопка последней то ваш вариант с A_priorkey конечно лучше. Мой вариант в отличии от вашего следит только за конкретными хоткеями, и считает их нажатия.

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (OmTatSat) — Mon, 01 Feb 2016 15:01:28 +0000

Nikva спасибо, работает. Такой вариант предпочтительней чем с использованием A_priorkey, требует меньше ресурсов, времени?

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (Nikva) — Mon, 01 Feb 2016 10:19:08 +0000

#NoTrayIcon
#ifwinactive, ahk_class MozillaWindowClass
~MButton::
  MState := 1
  starttime1 := A_TickCount
  MouseGetPos, OutputVarY, OutputVarX
  KeyWait, MButton
  MouseGetPos, OutputVarY2, OutputVarX2
  elapsedtime := A_TickCount - starttime1
  IF ((wheel = "") & (OutputVarX > 108) & (elapsedtime > 220) & (elapsedtime < 520) & (OutputVarX = OutputVarX2) & (OutputVarY = OutputVarY2) & (A_Cursor = "Arrow"))
  {
  ToolTip, %A_priorkey%
  Send, +{mButton}
  }
  wheel := ""
Return

#If MState
~MButton up::MState := 0

~WheelUp::
~WheelDown::
  wheel ++
return
#If

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (OmTatSat) — Mon, 01 Feb 2016 10:06:04 +0000

Nikva наоборот, если было прокручено колесо то не выполнять

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (Nikva) — Mon, 01 Feb 2016 09:56:44 +0000

OmTatSat пишет:

в тултипе цифры появляются, так должно быть?

Для наглядности, он считает количество поворотов колеса пока оно зажато.

Правильно ли я понял задачу?
Проверить, пока было зажато колесо мыши, крутилось ли оно, и если соблюдены условия выполнить действие?

#NoTrayIcon
#ifwinactive, ahk_class MozillaWindowClass
~MButton::
MState := 1
starttime1 := A_TickCount
MouseGetPos, OutputVarY, OutputVarX
Return

#If MState
~MButton up::
  MState := 0
  ToolTip
Return

~WheelUp::
~WheelDown::
  MouseGetPos, OutputVarY2, OutputVarX2
  elapsedtime := A_TickCount - starttime1
IF ((OutputVarX > 108) & (elapsedtime > 220) & (elapsedtime < 520) & (OutputVarX = OutputVarX2) & (OutputVarY = OutputVarY2) & (A_Cursor = "Arrow"))
  {
  ToolTip, %A_priorkey%
  Send, +{mButton}
  }
Return

#If

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (OmTatSat) — Mon, 01 Feb 2016 09:32:18 +0000

Nikva в тултипе цифры появляются, так должно быть?

В любом случае это реакция на wheel, спасибо за вариант!

нашел вариант с IF (A_priorkey = "mbutton")
использую его, так как прост в контексте моего скрипта, если было прокручено колесо то A_priorkey выдаёт wheel...

приведу весь скрипт, может кто-то знает более правильный подход

#NoTrayIcon
#ifwinactive, ahk_class MozillaWindowClass
~mButton::
starttime1 := A_TickCount
MouseGetPos, OutputVarY, OutputVarX
KeyWait, MButton
MouseGetPos, OutputVarY2, OutputVarX2
elapsedtime := A_TickCount - starttime1


IF ((A_priorkey = "mbutton") & (OutputVarX > 108) & (elapsedtime > 220) & (elapsedtime < 520) & (OutputVarX = OutputVarX2) & (OutputVary = OutputVary2) & (A_Cursor = "Arrow"))
{
	ToolTip, %A_priorkey%
Send, +{mButton}
}

Re: AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (Nikva) — Mon, 01 Feb 2016 09:15:43 +0000

~MButton::MState := 1

#If MState
~MButton up::
  MState := 0
  OutputVar := ""
  ToolTip
Return

~WheelUp::
~WheelDown::
  OutputVar ++
  ToolTip, %OutputVar%
Return

#If

AHK: Узнать была ли нажата клавиша, пока был зажат hotkey.

null@example.com (OmTatSat) — Mon, 01 Feb 2016 08:01:19 +0000

Здравствуйте, нужно по нажатию mbutton проверить крутился ли wheel пока она была нажата

~mButton::

keywait, MButton

Getkeystate, OutputVar, WheelUp, p

ToolTip, %OutputVar%
OutputVar = 
return

проблема в том, что OutputVar отдает U до первого прокрута колеса, потом всегда выдает D, как сделать, чтобы была реальная проверка, заместо старых данных?