Серый форум — CMD/BAT: Переименование файлов по размеру

Re: CMD/BAT: Переименование файлов по размеру

null@example.com (zetix) — Sun, 24 Apr 2016 13:50:15 +0000

Возможна ли в этом коде, еще одна модификация, обрабатывать данным образом только паки, где найдены файлы registrator.txt или partner.txt

Re: CMD/BAT: Переименование файлов по размеру

null@example.com (zetix) — Sun, 24 Apr 2016 11:17:14 +0000

greg zakharovРаботает, спасибо огромное. Очень познавательный код.

Re: CMD/BAT: Переименование файлов по размеру

null@example.com (greg zakharov) — Sun, 24 Apr 2016 10:54:39 +0000

@echo off
  setlocal
    set "p=D:\test"
    call:extchange %p%
    for /f "tokens=*" %%i in (
      'dir /ad /b /s %p%'
    ) do call:extchange "%%~i"
  endlocal
exit /b

:extchange
  pushd "%~1"
    for /f %%i in (
      'dir /a-d *.txt ^| find /n /i /c ".txt"'
    ) do (
      if %%i equ 1 ren *.txt *.log & goto:end
      if %%i equ 2 (
        for /f "tokens=*" %%i in (
          'dir /a-d /os *.txt /b'
        ) do set "lf=%%~i"
      )
    )
    ren "%lf%" "%lf:.txt=.log%"
    :end
  popd
exit /b

Re: CMD/BAT: Переименование файлов по размеру

null@example.com (zetix) — Sun, 24 Apr 2016 10:39:05 +0000

greg zakharov Спасибо, замечательный код! Был бы очень благодарен если добавили бы в него возможность поиска по всему дереву каталога, а не в отдельно взятой папке. Потому как сейчас, в случае нахождения подпапки приходится вручную менять путь. К примеру D:\test\temp\temp2.

Re: CMD/BAT: Переименование файлов по размеру

null@example.com (greg zakharov) — Sun, 24 Apr 2016 09:30:37 +0000

@echo off
  setlocal
    pushd D:\test
      for /f %%i in (
        'dir /a-d *.txt ^| find /n /i /c ".txt"'
      ) do (
        if %%i equ 1 ren *.txt *.log &goto:end
        if %%i equ 2 (
          for /f "tokens=*" %%i in (
            'dir /a-d /os *.txt /b'
          ) do set "lf=%%~i"
        )
      )
      ren "%lf%" "%lf:.txt=.log%"
      :end
    popd
  endlocal
exit /b

CMD/BAT: Переименование файлов по размеру

null@example.com (zetix) — Sat, 23 Apr 2016 19:05:28 +0000

Добрый день. Написал после долгих мучений такой код.

for /r "D:\Test" %%i in (*.txt?) do ren "%%i" *.log

Меняет расширение всех фалов в D:\Test с .txt на .log, проблема в том, что необходимо в случае нахождения в папке более одного файла .txt, сменить расширение только у большего по размеру, остальные пропустить.