Серый форум — AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Fri, 27 May 2016 11:33:36 +0000

YMP
Спасибо большое, всё работает отлично!

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (YMP) — Thu, 26 May 2016 13:34:16 +0000


Gui, Add, Text, x4 h20, Диск (D:) в работе
Gui, Add, Text, yp x+8 w50 h20 vTimeText, 00:00:00
Gui, Add, Button, x4 w80 h20 vStartStop gStartStop, Стоп
Gui, Show, Restore w450 h300
Gui, Add, Picture, x0 y0 h350 w450, D:\disk.ico

FileName = D:\DRIVE_AWAKE
FileSize := 4096    ; Должен быть кратен 4096.
Timeout = 5000
hFile := pBuf := Running := 0

StartStop:
    If (Running = 1) {
        SetTimer, ReadTimer, Off
        SetTimer, ClockTimer, Off
        Gosub, Cleanup
        Return
    }
    pBuf := DllCall("VirtualAlloc", "ptr", 0
                                  , "ptr", FileSize
                                  , "uint", 0x3000      ; MEM_RESERVE | MEM_COMMIT
                                  , "uint", 4           ; PAGE_READWRITE
                                  , "ptr")
    If (pBuf = 0) {
        Gosub, Cleanup
        MsgBox, Ошибка VirtualAlloc.
        Return
    }
    hFile := DllCall("CreateFile", "str", FileName
                                 , "uint", 0xC0000000   ; GENERIC_READ | GENERIC_WRITE
                                 , "uint", 0
                                 , "ptr", 0
                                 , "uint", 2            ; CREATE_ALWAYS
                                 , "uint", 0x20000000   ; FILE_FLAG_NO_BUFFERING
                                 , "ptr", 0
                                 , "ptr")
    If (hFile = -1) {   ; INVALID_HANDLE_VALUE
        Gosub, Cleanup
        MsgBox, Ошибка CreateFile.
        Return
    }
    If !DllCall("WriteFile", "ptr", hFile
                           , "ptr", pBuf
                           , "uint", FileSize
                           , "uint *", BytesWritten
                           , "ptr", 0)
    {
        Gosub, Cleanup
        MsgBox, Ошибка WriteFile.
        Return
    }
    Running := 1
    SetTimer, ReadTimer, %Timeout%
    GuiControl,, StartStop, Стоп
    TickCount0 := A_TickCount
    SetTimer, ClockTimer, 1000

ReadTimer:
    DllCall("SetFilePointer", "ptr", hFile
                            , "int", 0
                            , "ptr", 0
                            , "uint", 0)        ; FILE_BEGIN
    If !DllCall("ReadFile", "ptr", hFile
                          , "ptr", pBuf
                          , "uint", FileSize
                          , "uint *", BytesRead
                          , "ptr", 0)
    {
        SetTimer, ReadTimer, Off
        Gosub, Cleanup
        MsgBox, Ошибка ReadFile.
    }
    Return

Cleanup:
    If (hFile > 0) {
        DllCall("CloseHandle", "ptr", hFile)
    }
    If (pBuf != 0) {
        DllCall("VirtualFree", "ptr", pBuf, "ptr", 0, "uint", 0x8000)   ; MEM_RELEASE
    }
    hFile := pBuf := Running := 0
    GuiControl,, StartStop, Старт
    GuiControl,, TimeText, 00:00:00
    Return

ClockTimer:
    Time := (A_TickCount - TickCount0) // 1000
    Time := Format("{1:02i}:{2:02i}:{3:02i}"
                    , Time // 3600
                    , Mod(Time, 3600) // 60
                    , Mod(Time, 60) )
    GuiControl,, TimeText, %Time%
    Return

GuiClose:
    ExitApp

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Thu, 26 May 2016 11:35:01 +0000

YMP
Вообще отлично получается, а можно старт/стоп инвертировать, т.е. чтобы после запуска скрипт сразу работал, а кнопка была стоп, сейчас же, после запуска нужно нажимать старт.

А часы, показывать сколько времени прошло после начала работы скрипта, при нажатии кнопки стоп, его обнулять, а при нажатии старт, начинать отсчёт сначала. В виде ЧЧ:ММ:СС (01:27:55).

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (YMP) — Thu, 26 May 2016 10:00:45 +0000

Кнопку можно так. Секундомер или часы? Какое конкретно время измерять?


Gui, Add, Text,, Диск (D:) в работе
Gui, Add, Button, w80 h20 vStartStop gStartStop, Старт
Gui, Show, Restore w450 h300
Gui, Add, Picture, x0 y0 h350 w450, D:\disk.ico

FileName = D:\DRIVE_AWAKE
FileSize := 4096    ; Должен быть кратен 4096.
Timeout = 5000
hFile := pBuf := Running := 0
Return

StartStop:
    If (Running = 1) {
        SetTimer, ReadTimer, Off
        Gosub, Cleanup
        Return
    }
    pBuf := DllCall("VirtualAlloc", "ptr", 0
                                  , "ptr", FileSize
                                  , "uint", 0x3000      ; MEM_RESERVE | MEM_COMMIT
                                  , "uint", 4           ; PAGE_READWRITE
                                  , "ptr")
    If (pBuf = 0) {
        Gosub, Cleanup
        MsgBox, Ошибка VirtualAlloc.
        Return
    }
    hFile := DllCall("CreateFile", "str", FileName
                                 , "uint", 0xC0000000   ; GENERIC_READ | GENERIC_WRITE
                                 , "uint", 0
                                 , "ptr", 0
                                 , "uint", 2            ; CREATE_ALWAYS
                                 , "uint", 0x20000000   ; FILE_FLAG_NO_BUFFERING
                                 , "ptr", 0
                                 , "ptr")
    If (hFile = -1) {   ; INVALID_HANDLE_VALUE
        Gosub, Cleanup
        MsgBox, Ошибка CreateFile.
        Return
    }
    If !DllCall("WriteFile", "ptr", hFile
                           , "ptr", pBuf
                           , "uint", FileSize
                           , "uint *", BytesWritten
                           , "ptr", 0)
    {
        Gosub, Cleanup
        MsgBox, Ошибка WriteFile.
        Return
    }
    Running := 1
    SetTimer, ReadTimer, %Timeout%
    GuiControl,, StartStop, Стоп

ReadTimer:
    DllCall("SetFilePointer", "ptr", hFile
                            , "int", 0
                            , "ptr", 0
                            , "uint", 0)        ; FILE_BEGIN
    If !DllCall("ReadFile", "ptr", hFile
                          , "ptr", pBuf
                          , "uint", FileSize
                          , "uint *", BytesRead
                          , "ptr", 0)
    {
        SetTimer, ReadTimer, Off
        Gosub, Cleanup
        MsgBox, Ошибка ReadFile.
    }
    Return

Cleanup:
    If (hFile > 0) {
        DllCall("CloseHandle", "ptr", hFile)
    }
    If (pBuf != 0) {
        DllCall("VirtualFree", "ptr", pBuf, "ptr", 0, "uint", 0x8000)   ; MEM_RELEASE
    }
    hFile := pBuf := Running := 0
    GuiControl,, StartStop, Старт
    Return
    
GuiClose:
    ExitApp

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Wed, 25 May 2016 20:29:40 +0000

Flasher
Вам видимо повезло с диском и частота парковки выставлена на 5 минут (а не 8 секунд), WD, похоже, у одной и той же модели устанавливает разные значения, были даже Red-ы с 8 секундами.

YMP
Поработал я пару дней с Вашим скриптом, и наконец-то могу вздохнуть с облегчением, раньше, при обработке большого массива файлов, было разумней копировать их на нормальный HDD и обратно, а это 200-300ГБ, или элементарный просмотр фотографий портил нервы постоянными щелчками, а сейчас всё спокойно. Спасибо Вам огромное!

В процессе использования, появилось пару хотелок, это кнопка стоп/старт в GUI, которая нужна, при копировании большого количества файлов, можно ли её встроить в код? И секундомер, показывающий в GUI сколько времени прошло с начала запуска.

Вот текущий код:

Gui, Add, Text,, Диск (D:) в работе
Gui, Show, Restore w450 h300
Gui, Add, Picture, x0 y0 h350 w450, D:\disk.ico

FileName = D:\DRIVE_AWAKE
FileSize := 4096    ; Должен быть кратен 4096.
Timeout = 5000

pBuf := DllCall("VirtualAlloc", "ptr", 0
                              , "ptr", FileSize
                              , "uint", 0x3000  ; MEM_RESERVE | MEM_COMMIT
                              , "uint", 4       ; PAGE_READWRITE
                              , "ptr")
If (pBuf = 0) {
    MsgBox, Ошибка VirtualAlloc.
    ExitApp
}
hFile := DllCall("CreateFile", "str", FileName
                             , "uint", 0xC0000000   ; GENERIC_READ | GENERIC_WRITE
                             , "uint", 0
                             , "ptr", 0
                             , "uint", 2            ; CREATE_ALWAYS
                             , "uint", 0x20000000   ; FILE_FLAG_NO_BUFFERING
                             , "ptr", 0
                             , "ptr")
If (hFile = -1) {   ; INVALID_HANDLE_VALUE
    MsgBox, Ошибка CreateFile.
    ExitApp
}
If !DllCall("WriteFile", "ptr", hFile
                       , "ptr", pBuf
                       , "uint", FileSize
                       , "uint *", BytesWritten
                       , "ptr", 0)
{
    MsgBox, Ошибка WriteFile.
    ExitApp
}

Loop
{
    DllCall("SetFilePointer", "ptr", hFile
                            , "int", 0
                            , "ptr", 0
                            , "uint", 0)        ; FILE_BEGIN
    If !DllCall("ReadFile", "ptr", hFile
                          , "ptr", pBuf
                          , "uint", FileSize
                          , "uint *", BytesRead
                          , "ptr", 0)
    {
        MsgBox, Ошибка ReadFile.
        ExitApp
    }
    Sleep, %Timeout%
}
	
GuiClose:
ExitApp

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Flasher) — Tue, 24 May 2016 07:10:54 +0000

Waveshaper
При просыпании чувствую. При навигации не особо, иногда - слабый стук, но не щелчки. Диспетчер как к этому относится? Это же не системник, там, как полагается, - SSD. А этому диску 1.5 года. Компьютер сам по себе тихий, там кроме пары спящих Green-дисков на звук работают только пару почти неслышных 120-х кулеров, поэтому щелчки вполне будут различимы.

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Mon, 23 May 2016 21:57:30 +0000

Flasher
А Вы сами не чувствуете, при навигации по папкам, щелчкам или диспетчеру задач?

Судя по количеству, у Вас совсем новый диск?

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Flasher) — Mon, 23 May 2016 21:50:02 +0000

Waveshaper
Не пойму, возможно просто статус в DiskInfo погашен из-за отсутствия поддержки опции.
Но у меня всего 186 циклов загрузки/выгрузки при 97 запусках/остановках шпинделя.

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Mon, 23 May 2016 21:20:33 +0000

Flasher
Спасибо, вот и у меня AdvancedPM=no, а -B 255 вот что выдаёт и непонятно в чём дело. А у Вас точно парковка отключилась, а была 8 секунд?

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Flasher) — Mon, 23 May 2016 21:09:51 +0000

Waveshaper
no WriteCache=enabled.
setting Advanced Power Management level to disabled
Win7 x32.

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Mon, 23 May 2016 21:05:52 +0000

Flasher
Вроде можно и её, могли бы проверить команду hdparm.exe -i /dev/sda, что у Вас написано в строке AdvancedPM=? А при -B 255 никаких ошибок не выдаёт? И какая у Вас ОС?

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Flasher) — Mon, 23 May 2016 21:00:28 +0000

Waveshaper
Вот эту сборку? Вроде работает. APM погашен.

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Mon, 23 May 2016 19:56:50 +0000

Flasher
О, значит Вы понимаете, что такое парковка. Вы не пробовали hdparm?

Возможно влияет, что у меня в опциях электропитания, установлено "Отключать жёсткий диск: никогда".

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Flasher) — Mon, 23 May 2016 19:52:58 +0000

Waveshaper
Такой же, только 60, а не 30.
Видимо, спал. Хотя я пробовал тормозить через hddmaster - не вышло.

Re: AHK: Подача сигнала чтения на жёсткий диск каждые 5с, возможно ли это?

null@example.com (Waveshaper) — Mon, 23 May 2016 19:35:22 +0000

Flasher
А у Вас какой диск? У меня WD Green WD30EZRX.

Может быть у Вас он спал, а не запаркован был?