Серый форум — AHK: Переменный хоткей

Re: AHK: Переменный хоткей

null@example.com (yalanne) — Mon, 27 Jun 2016 13:30:02 +0000

Без процентов ведь надо.

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Mon, 27 Jun 2016 04:29:32 +0000

yalanne
Возникла небольшая сложность, у меня почти все хоткеии читаются и пишутся в файл настроек, поэтому здесь необходимо задавать клавишу пройменной.

VariableH.Hkcombo("!F1"	,	"hotkey1",1)

Пробовал так, не сработало.

VariableH.Hkcombo(%modkey1%	,	"hotkey1",1)

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sun, 26 Jun 2016 15:23:32 +0000

yalanne
Ясно, спасибо.

Re: AHK: Переменный хоткей

null@example.com (yalanne) — Sun, 26 Jun 2016 15:04:59 +0000

Команда Include Просто вставляет Содержимое другого скрипта в свой. При компиляции скрипт будет одним файлом.
Просто в место первой строчки вставь код.

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sun, 26 Jun 2016 14:58:37 +0000

yalanne
А как в одном скрипте сделать?

Re: AHK: Переменный хоткей

null@example.com (yalanne) — Sun, 26 Jun 2016 13:52:50 +0000

#include VariableH.ahk


VariableH.Hkcombo("!F1"	,	"hotkey1",1)  ; Alt+F1(один раз) будет переход на метку hotkey1.
VariableH.Hkcombo("!F1"	,	"hotkey2",2) ; Alt+F1(два раза) будет переход на метку hotkey2.
VariableH.Hkcombo("+F1"	,	"hotkey3",2) ; Shift+F1(два раза) будет переход на метку hotkey3.

Return

hotkey1:
hotkey2:
hotkey3:
ToolTip % A_ThisLabel
return

+ VariableH.ahk

Положить рядом с скриптом

#Persistent
VariableH := new VariableH

Class VariableH
{
	Static List := {}
	
	Hkcombo(hk,LabelorFn="",pressed=1)
	{
		VariableH.List[hk "_" --pressed] := LabelorFn
		Hotkey,% hk, EventPressHk
	}
	
	PressHKCount(hk)
	{
		Loop 
		{
		   N++
		   KeyWait, %hk%, T.3
		   IfEqual,ErrorLevel,1,Break
		   KeyWait, %hk%, D T0.25
		} Until ErrorLevel
		KeyWait, %hk%
		Return N
	}

	_()
	{
	EventPressHk:
	CountP := VariableH.PressHKCount(	RegExReplace(	A_ThisHotkey,"^\W")),	CountP--
	
	if  VariableH.List[A_ThisHotkey "_" CountP ]
		if IsFunc(VariableH.List[A_ThisHotkey "_" CountP ])
			func(VariableH.List[A_ThisHotkey "_" CountP ] ).call()
		Else if IsLabel(VariableH.List[A_ThisHotkey "_" CountP ])
			Gosub % VariableH.List[A_ThisHotkey "_" CountP ]
	Return
	}
}

Можно больше двух нажатий делать.

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sat, 25 Jun 2016 14:46:40 +0000

yalanne
Срабатывает при зажатии.

Re: AHK: Переменный хоткей

null@example.com (ypppu) — Sat, 25 Jun 2016 12:31:27 +0000

Просто не путайте "Ответить" и "Цитировать".

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sat, 25 Jun 2016 12:24:00 +0000

Вон оно что, я в обще пытался редактировать последние сообщение, но форум решил по другому. Или нажал не то, простите.

Re: AHK: Переменный хоткей

null@example.com (ypppu) — Sat, 25 Jun 2016 12:14:57 +0000

Это напоминание. Если захотите сказать "Всё ещё актуально", не цитируйте такое громоздкое сообщение целиком.

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sat, 25 Jun 2016 11:51:56 +0000

Это предупреждение заранее? Если я вдруг решу процитировать предыдущие сообщение и сказать спасибо?

Re: AHK: Переменный хоткей

null@example.com (ypppu) — Sat, 25 Jun 2016 09:56:29 +0000

Sgy-x2, избегайте избыточного цитирования.

Re: AHK: Переменный хоткей

null@example.com (yalanne) — Sat, 25 Jun 2016 09:05:23 +0000

Sgy-x2 пишет:

~hotkey1:

Это уже не клавиша а метка. лишние символы как ~ уже ошибка.

Sgy-x2 пишет:

"~%hotkey1%"

Так же метка не содержит значения как переменная.

Вот вариант:

modkey1 = !
modkey2 = F1
Hotkey,% modkey1 modkey2, hotkey1
Return

hotkey1:
if (A_ThisHotkey = A_PriorHotkey and A_TimeSincePriorHotkey < 300)
{
	MsgBox, Test
}

KeyWait, % A_ThisHotkey
Return

+ с комментами

modkey1 = !	; Первая клавиша alt
modkey2 = F1 ; Вторая клавиша F1
Hotkey,% modkey1 modkey2, hotkey1 ; В первый параметр заносим '!F1'. Второй параметр это название метки, куда скрипт будет ссылаться при нажатии кнопок указанных в первом параметре.
Return ; убираем лишнее срабатывание при старте скрипта. 

hotkey1: ; метка.
if (A_ThisHotkey = A_PriorHotkey and A_TimeSincePriorHotkey < 300) ; если текущая клавиша равна предыдущей и при этом прошло менее 300 мс, то срабатывает условие.
{
	MsgBox, Test
}

KeyWait, % A_ThisHotkey ; ждем отжатия клавиши. Это надо что бы избежать двойного нажатия при зажатии кнопки.
Return

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Sat, 25 Jun 2016 08:40:56 +0000

Всё ещё актуально.

Re: AHK: Переменный хоткей

null@example.com (Sgy-x2) — Tue, 14 Jun 2016 03:04:57 +0000

Скажите пожалуйста, есть такой скрипт, действие от двойного нажатия. Можно ли сделать хоткей переменный?

Оригинал.

~Control::
if (A_PriorHotkey <> "~Control" or A_TimeSincePriorHotkey > 300)
{
	KeyWait, Control
	Return
}
KeyWait, Control
MsgBox, Test
Return

Пытался так, не работает.

modkey1 := Control
Hotkey, % modkey1, hotkey1
~hotkey1:
if (A_PriorHotkey <> "~%hotkey1%" or A_TimeSincePriorHotkey > 300)
{
	KeyWait, % hotkey1
	Return
}
KeyWait, % hotkey1
MsgBox, Test
Return