Серый форум — AHK: Определение границ массива

Re: AHK: Определение границ массива

null@example.com (KusochekDobra) — Tue, 19 Jul 2016 00:24:02 +0000


fileSize := 0
position := 0
file := FileOpen("Test.txt", "r", "UTF-8")
strArray := []
arrCount := 0
while (true) {
	if (file.Length > fileSize) {
		fileSize := file.Length
		file.Seek(position)
		line := file.ReadLine()
		while (line != "") {
			strArray.Push(line)
			line := file.ReadLine()
		}
		position := file.Tell()
		arrCount := strArray.Length()
	}
	sleep 100
}

Такая конструкция прочитает "Test.txt", положит прочитанные строки в массив "strArray", сообщит переменной "arrCount" верхнее значение массива и раз в 100 миллисекунд будет проверять размер "Test.txt". Если размер увеличится, новые строки будут добавлены в массив "strArray", а переменная "arrCount" получит новое предельное значение.

Re: AHK: Определение границ массива

null@example.com (ypppu) — Mon, 18 Jul 2016 20:00:44 +0000

Ещё такой вариант.

Loop, Read, Test.txt
{
line%A_Index% := A_LoopReadLine
last_line := A_Index
}
Random, varrandom, 1, last_line
MsgBox,  % line%varrandom%

Re: AHK: Определение границ массива

null@example.com (Alectric) — Mon, 18 Jul 2016 16:37:43 +0000

ypppu
В файле неизвестное кол-во строк, необходимо рандомно вывести одну из строк.

Re: AHK: Определение границ массива

null@example.com (ypppu) — Mon, 18 Jul 2016 16:16:15 +0000

Кто-нибудь переведите, в чём задача вообще заключалась?

Re: AHK: Определение границ массива

null@example.com (Veranda) — Mon, 18 Jul 2016 15:23:30 +0000

Благодарю за помощь! Все варианты поробовал, но остановился на решении от Malcev из предыдущего сообщения.

Re: AHK: Определение границ массива

null@example.com (Malcev) — Mon, 18 Jul 2016 15:11:56 +0000

Можно так ещё:

FileRead, All, test.txt
Sort, All, Random
msgbox % RegExReplace(All, "\R.*")

Re: AHK: Определение границ массива

null@example.com (yalanne) — Mon, 18 Jul 2016 15:07:13 +0000

А зачем два раза файл читать?

random, varrandom, 1, % (objList := StrSplit(FileOpen("Test.txt","r").Read(),"`r`n")).Length()
MsgBox % objList[varrandom]

Re: AHK: Определение границ массива

null@example.com (Flasher) — Mon, 18 Jul 2016 14:33:50 +0000

Первую строку заменить на:

FileRead, All, Test.txt
random, varrandom, 1, StrLen(RegExReplace(All, "[^\r\n]"))/2 + 1

Re: AHK: Определение границ массива

null@example.com (Malcev) — Mon, 18 Jul 2016 14:07:16 +0000

Можно посчитать количество строк в файле до вызова random.

Re: AHK: Определение границ массива

null@example.com (Veranda) — Mon, 18 Jul 2016 13:59:23 +0000

Файл Test прилагаю. Представляет из себя 14 строк с разными значениями для вывода в MsgBox.

Re: AHK: Определение границ массива

null@example.com (ypppu) — Mon, 18 Jul 2016 13:36:11 +0000

Нужно конкретный пример файла Test.txt в начальный момент, а потом после добавления.

AHK: Определение границ массива

null@example.com (Veranda) — Mon, 18 Jul 2016 13:27:34 +0000

Доброго дня, уважаемые форумчане!
Столкнулся с проблемой: для работы скрипта подключаю внешний файл, в котором есть 16 строк. Строки вызываю через random, с ограничением диапазона чтения строк с 1 по 14
Каким образом можно отказаться от необходимости указывать в параметрах переменно varrandom количество строк, из списка которых необходимо вывести строку со значением? Т.е чтобы пр добавлении новых строк в файл - они наравне с уже имеющимися участвовали в поиске и ненужно было изменять значение верхней границы массива строк в файле?

Была мысль сверять количество символов в строке при генерации varrandom и если их количество=0 - то происходит повторная генерация, пока в переменной не окажется строка с количеством символов >0. Однако данное решение мне кажется не очень удачным.


random, varrandom, 1, 14
FileReadLine, OutputVar, Test.txt, %varrandom% ;путь к файлу
MsgBox, Текущее значение:`n%OutputVar%