Серый форум — AHK: Быструю прокрутку на трещотку

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Sun, 01 Jan 2017 17:37:51 +0000

Спасибо, если по другому решить не удастся, наверное приделаю его к старому так, чтобы он только в Chrome активировался.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (becauseim) — Sun, 01 Jan 2017 16:34:28 +0000

Использую такой скрипт.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Sun, 01 Jan 2017 16:22:39 +0000

Может есть у кого-то какие-то идеи? Жуть как надоело вертеть по 20 раз колесо.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Wed, 28 Dec 2016 10:26:59 +0000

Установил, что работе скрипта в 10-ке мешает приложение SetPoint, хотя в 7-ке этого не было. Пока проблему решить не удалось.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (becauseim) — Tue, 27 Dec 2016 22:13:13 +0000

На какой строке примера из 22-го поста можно задать параметры увеличения скорости при каждом нажатии на WheelUp/WheelDown?

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Tue, 27 Dec 2016 13:56:00 +0000

Не более 3%.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (ypppu) — Tue, 27 Dec 2016 10:15:03 +0000

Может в это время сильно загружен процессор? Процессу AutoHotkey можно повысить приоритет.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Sun, 25 Dec 2016 17:39:18 +0000

Перешёл на win10 и почему-то временами скрипт перестаёт работать. Причём обычно в Chrome, а в блокноте всё отлично, как и раньше. Скрипт не видит срабатывание колеса(Mice2 = 0), хотя, шарик и кнопки видит сразу(Mice2 = 1). Иногда после рестарта, какое-то время нормально, а потом опять не работает. Возможно есть связь с открытием новых окон Chrome.
Отчего такое может быть и как исправить?

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Mon, 22 Aug 2016 10:12:27 +0000

Значительно лучше. Только при скорости, например на 2 щелчка, щёлкнуть 4 в обратную сторону, не останавливается, а начинает прокручивать навстречу. Если это решить, то пожалуй остановку по клику мышки можно тоже убирать.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (serzh82saratov) — Mon, 22 Aug 2016 09:51:25 +0000

SetMouseDelay, 0

oSleep := [100,50,20,10,0], I := 0

WheelUp::
WheelDown::
	HD := A_ThisHotkey = "WheelUp" ? "WheelUp" : "WheelDown" 
	D := I = 0 ? HD : D
	I := (D = HD) ? I + (I != oSleep.MaxIndex()) : I - !!I
	Try SetTimer, UpDown, % "-" oSleep[i]
    Return

UpDown: 
	ToolTip,% I "`n"  oSleep[i] "`n" D 
	SendInput {%D% %I%}
	Try SetTimer, UpDown, % "-" oSleep[i] 
	Return 


#If I && !(I := 0)
LButton:: 
	SetTimer, UpDown, Off
	ToolTip
	Return
#If

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Mon, 22 Aug 2016 09:35:47 +0000

Наверное даже не так надо. Надо, чтобы встречное движение уменьшало скорость прокрутки, а если поворот сильнее, чем можно уменьшить текущую скорость, то останавливало бы.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Mon, 22 Aug 2016 08:04:33 +0000

Убрал лямбду. Иначе во время прокрутки случаются ненужные клики по подвернувшимся объектам.
Клавиши для отправки заменил на колесо.
Ввёл меняющийся шаг.


oSleep := [100,50,20,10,0], I := 0

#If IsMice2

WheelUp::
WheelDown::
	HD := A_ThisHotkey = "WheelUp" ? "WheelUp" : "WheelDown"
	If (I && HD != D) {
		D := HD, I := 0
		SetTimer, UpDown, Off
		Return
	} 
	D := HD, I := I = oSleep.MaxIndex() ? I : I + 1
	;ToolTip,% "5 " oSleep[i] " " D
	ToolTip,
	SetTimer, UpDown, % "-" oSleep[i]
    Return 

UpDown: 
	;ToolTip,% "5 " oSleep[i] " " D
	ToolTip, ========================================================================================
	SendInput {%D% %I%}
	SetTimer, UpDown, % "-" oSleep[i] 
	;ToolTip
	Return
#If


#If I && !(I := 0)
LButton::
I := 0
SetTimer, UpDown, Off
ToolTip,
Return
#If

Хорошо получилось. Раз остановка только на ЛКМ, пока не решил как, и надо ли, сделать так, чтобы и любое встречное движение колеса останавливало прокрутку. Иногда трудно поймать именно 1 щелчок и начинается обратная прокрутка, которую опять надо ловить.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (serzh82saratov) — Sun, 21 Aug 2016 23:36:53 +0000

Ну на все клавиши сложнее, думаю клик и альт в большинстве случаев будет достаточно.


SetBatchLines -1
SetKeyDelay, 0
oSleep := [80,30,10,3,0], I := 0

 
WheelUp::
WheelDown::
	HD := A_ThisHotkey = "WheelUp" ? "Up" : "Down"
	If (I && HD != D) {
		D := HD, I := 0
		SetTimer, UpDown, Off
		Return
	} 
	D := HD, I += I != oSleep.MaxIndex()
	Try SetTimer, UpDown, % "-" oSleep[i]
    Return 
 
UpDown: 
	SendInput {%D% 2}
	Try SetTimer, UpDown, % "-" oSleep[i]
	Return
	
	
#If I && !(I := 0)
~Alt:: 
~LButton:: SetTimer, UpDown, Off
#If

Re: AHK: Быструю прокрутку на трещотку

null@example.com (Foma) — Sun, 21 Aug 2016 23:11:47 +0000

Чуть изменил:


SetBatchLines -1
SetKeyDelay, 0
oSleep := [80,30,10,3,0], I := 0
_______

WheelUp::
WheelDown::
	HD := A_ThisHotkey = "WheelUp" ? "Up" : "Down"
	If (I && HD != D) {
		D := HD, I := 0
		SetTimer, UpDown, Off
		Return
	} 
	D := HD, I := I = oSleep.MaxIndex() ? I : I + 1
	SetTimer, UpDown, % "-" oSleep[i]
    Return 

UpDown: 
	SendInput {%D% 2}
	SetTimer, UpDown, % "-" oSleep[i] 
	Return

Ещё одно пожеланин, если позволите. Как можно сделать, чтобы таймер останавливался при нажатии любой клавиши, в том числе мыши? А то при достижении конца страницы не всегда видно, что прокрутка продолжается.

Re: AHK: Быструю прокрутку на трещотку

null@example.com (serzh82saratov) — Sun, 21 Aug 2016 21:09:37 +0000

Так нагляднее. В oSleep задержки в мс, первое нажатие 60 мс между Send, после второго 30 и.т.д. Кол-во задержек любое.

oSleep := [60,30,0], I := 0

WheelUp::
WheelDown::
	HD := A_ThisHotkey = "WheelUp" ? "Up" : "Down"
	If (I && HD != D) {
		D := HD, I := 0
		SetTimer, UpDown, Off
		Return
	} 
	D := HD, I += I != oSleep.MaxIndex()
	SetTimer, UpDown, % "-" oSleep[i]
    Return 

UpDown: 
	SendInput {%D%}
	SetTimer, UpDown, % "-" oSleep[i] 
	Return