Серый форум — AHK: Перебор меток после удержания горячей клавиши

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Thu, 01 Feb 2018 14:16:11 +0000

stealzy, а как решить проблему, при которой зажатие не работает, если рядом задана горячая клавиша с буквой M?

^+m::MsgBox 123

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (stealzy) — Thu, 25 Jan 2018 21:49:06 +0000

becauseim

$^+m::MsgBox 123
MsgBox MsgBox не работает

becauseim пишет:

в конкретном окне?

Попроще: проверяете активность конкретного окна, посложнее: ставите оконный хук и вкл/выкл хоткей на активацию/появление окон.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Thu, 25 Jan 2018 20:46:55 +0000

teadrinker, зажатие не работает, если рядом задан хотей, например, ^+{m}.
И все еще не понял, как задать работу зажатия в конкретном окне? stealzy привел пример, но он отличается от Вашей ф-ии.

$^+m:: MsgBox 123
#Persistent
Hold("sc32", 300, 500, "^+{f2}", "^+{f7}", "^+{f5}", "^+{f6}", "^+{f8}", "^+{f4}", "^+{f3}", "^+{f1}")


Hold(MyHotkey, TimeOut, SleepTime, HeldKeys*)  {
   static oInfo, WH_KEYBOARD_LL := 13
   oInfo := { MyHotkey: MyHotkey, MyHotkeySC: "0x" . SubStr(MyHotkey, 3)
            , TimeOut: TimeOut, SleepTime: SleepTime, HeldKeys: HeldKeys }
   
   DllCall("SetWindowsHookEx", Int, WH_KEYBOARD_LL
      , Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast", 3, pInfo := Object(oInfo))
      , Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr), UInt, 0, Ptr)
   ObjRelease(pInfo)
}

LowLevelKeyboardProc(nCode, wParam, lParam)  {
   static LLKHF_INJECTED := 0x10, WM_KEYDOWN := 0x100, WM_KEYUP := 0x101, timer
   
   Critical
   msg   := wParam
   flags := NumGet(lParam + 8, "UInt")
   ext   := flags & 1
   sc    := NumGet(lParam + 4, "UInt") | ext << 8
   time  := NumGet(lParam + 12, "UInt")
   INJECTED := (flags & LLKHF_INJECTED) >> 4
   oInfo := Object(A_EventInfo)
   
   if (!INJECTED && msg = WM_KEYDOWN && oInfo.KeyDownTime != "")
      Return 1
   
   if (!INJECTED && msg = WM_KEYDOWN && sc = oInfo.MyHotkeySC && oInfo.KeyDownTime = "")  {
      if GetKeyState("Shift", "P") || GetKeyState("Alt", "P") || GetKeyState("Ctrl", "P")
         Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
      
      oInfo.KeyDownTime := time
      timer := Func("SendKeys").Bind(oInfo)
      SetTimer, % timer, % "-" . oInfo.TimeOut
      Return 1
   }
   
   if (!INJECTED && msg = WM_KEYUP && sc = oInfo.MyHotkeySC && oInfo.KeyDownTime != "")  {
      SetTimer, % timer, Delete
      if (A_TickCount - oInfo.KeyDownTime <= oInfo.TimeOut)
         SendInput, % "{" oInfo.MyHotkey "}"
      oInfo.KeyDownTime := ""
      Return 1
   }
   Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
}

SendKeys(oInfo)  {
   max := oInfo.HeldKeys.MaxIndex()
   while oInfo.KeyDownTime  {
      SendInput, % oInfo.HeldKeys[(k := mod(A_Index, max)) ? k : max]
      Sleep, oInfo.SleepTime
   }
}

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Sun, 26 Mar 2017 08:56:06 +0000

becauseim пишет:

teadrinker, горячая клавиша глобальна, несмотря на установку. Что я делаю неправильно?

А в моем скрипте нет установки горячих клавиш, там другой механизм.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (stealzy) — Sun, 26 Mar 2017 05:49:00 +0000

Вы не задали ГК между двумя диезами.
Выражения # обрабатываются отдельно до запуска скрипта и внутрь ф-ии не глядят.
Либо разверните ф-ию между #If, либо засуньте #If внутрь ф-ии.
Правильным подходом будет использование Hotkey, тогда вы сможете передать WinTitle как параметр ф-ии.

Hotkey("ctrl shift C", "ahk_class CabinetWClass", "Explorer_CopySelPath", true, true, false) ; копирование пути выделеного в проводнике объекта

Hotkey(keyName, winTitle:="", func:="", args*)  {
	keyName := GetAHKhotkey(keyName) ; "ctrl shift C" → ^+vk43
	funcObj := Func(func).Bind(args*)
	Hotkey IfWinActive, % winTitle
	Hotkey % keyName, % funcObj
}

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Sun, 26 Mar 2017 05:26:37 +0000

teadrinker, горячая клавиша глобальна, несмотря на установку. Что я делаю неправильно?


#Persistent
#IfWinActive ahk_exe app.exe 
Hold( "sc32", 300, 100, "+{m}", "{y}", "+{s}", "{c}", "{r}", "{i}", "{p}", "{t}", "{sc39}" )
Return
#IfWinActive

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Fri, 24 Mar 2017 16:03:10 +0000

becauseim пишет:

вот изначальный Ваш вариант, который мне подходит.

Он недостаточно надёжный, в нём иногда сама нажатая клавиша отсылается.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Fri, 24 Mar 2017 09:50:48 +0000

teadrinker, вот изначальный Ваш вариант, который мне подходит. Для того, чтобы задать несколько клавиш подобного функционала показалось целесообразным заключить скрипт в функцию, чтобы не увеличивать объем, да и упростить задание таких клавиш.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Fri, 24 Mar 2017 09:10:32 +0000

becauseim, я уже запутался, какой именно первый? Ничего невозможного нет, просто я нашёл такое решение в соответствии с задачей, кто-то, может, нашёл бы более короткое.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Thu, 23 Mar 2017 19:03:30 +0000

teadrinker, да, я заметил, что здесь задействованы системные функции, но не понял, для чего, если предыдущий вариант работал с той же скоростью и столь же стабильно, как мне кажется. Или первый вариант не возможно заключить в функцию без изенения подхода?

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Wed, 22 Mar 2017 08:10:11 +0000

becauseim, если вы заметили, тут совсем другой подход.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Wed, 22 Mar 2017 05:24:47 +0000

teadrinker, да, вроде работает. Спасибо! Скажите, а почему же последний вариант столь сильно увеличился в объеме в сравнении с вариантом без оформления в функцию?

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Tue, 21 Mar 2017 18:18:00 +0000

У меня так вроде работает:

#Persistent
Hold( "sc32"  ; m
     , 300, 100
     , "+{m}", "{y}", "+{s}", "{c}", "{r}", "{i}", "{p}", "{t}", "{sc39}" )
Return

Hold(MyHotkey, TimeOut, SleepTime, HeldKeys*)  {
   static oInfo, WH_KEYBOARD_LL := 13
   oInfo := { MyHotkey: MyHotkey, MyHotkeySC: "0x" . SubStr(MyHotkey, 3)
            , TimeOut: TimeOut, SleepTime: SleepTime, HeldKeys: HeldKeys }
   
   DllCall("SetWindowsHookEx", Int, WH_KEYBOARD_LL
      , Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast", 3, pInfo := Object(oInfo))
      , Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr), UInt, 0, Ptr)
   ObjRelease(pInfo)
}

LowLevelKeyboardProc(nCode, wParam, lParam)  {
   static LLKHF_INJECTED := 0x10, WM_KEYDOWN := 0x100, WM_KEYUP := 0x101, timer
   
   Critical
   msg   := wParam
   flags := NumGet(lParam + 8, "UInt")
   ext   := flags & 1
   sc    := NumGet(lParam + 4, "UInt") | ext << 8
   time  := NumGet(lParam + 12, "UInt")
   INJECTED := (flags & LLKHF_INJECTED) >> 4
   oInfo := Object(A_EventInfo)
   
   if (!INJECTED && msg = WM_KEYDOWN && oInfo.KeyDownTime != "")
      Return 1
   
   if (!INJECTED && msg = WM_KEYDOWN && sc = oInfo.MyHotkeySC && oInfo.KeyDownTime = "")  {
      if GetKeyState("Shift", "P") || GetKeyState("Alt", "P") || GetKeyState("Ctrl", "P")
         Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
      
      oInfo.KeyDownTime := time
      timer := Func("SendKeys").Bind(oInfo)
      SetTimer, % timer, % "-" . oInfo.TimeOut
      Return 1
   }
   
   if (!INJECTED && msg = WM_KEYUP && sc = oInfo.MyHotkeySC && oInfo.KeyDownTime != "")  {
      SetTimer, % timer, Delete
      if (A_TickCount - oInfo.KeyDownTime <= oInfo.TimeOut)
         SendInput, % "{" oInfo.MyHotkey "}"
      oInfo.KeyDownTime := ""
      Return 1
   }
   Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, Ptr, wParam, Ptr, lParam)
}

SendKeys(oInfo)  {
   max := oInfo.HeldKeys.MaxIndex()
   while oInfo.KeyDownTime  {
      SendInput, % oInfo.HeldKeys[(k := mod(A_Index, max)) ? k : max]
      Sleep, oInfo.SleepTime
   }
}

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (becauseim) — Tue, 21 Mar 2017 13:02:10 +0000

teadrinker, спасибо! А как исключить работу гк из других сочетаний? Например, функция срабатывает даже при зажатии Ctrl+Shift+M.

Re: AHK: Перебор меток после удержания горячей клавиши

null@example.com (teadrinker) — Tue, 21 Mar 2017 10:12:26 +0000

Сочетание Shift+b имеет смысл, только если эмулировано нажатие клавиши «b», а когда в данной раскладке такой клавиши нет, отправка осуществляется по-другому, читайте справку по Send.