Серый форум — WSH: Нужен скрипт для копирования файлов

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (Sergey_85) — Thu, 11 Nov 2010 07:48:44 +0000

Здравствуйте всем! В программировании не силен.
Помогите со скриптом в этой ветке.
Задача заключается в том, чтобы из папки1(со своей иерархией) прошерстить все файлы и переместить те, которые НЕ ИЗМЕНЯЛИСЬ и НЕ ОТКРЫВАЛИСЬ больше чем заданное время (например год) в папку2 с иерархией папки1.

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (sanchell) — Thu, 20 Sep 2007 16:31:00 +0000

Санёк пишет:

В самом начале указывается, насколько старые должны быть файлы, чтобы скрипт удалил их! (Now-3 возвращает дату на 3 суток раньше текущей)
Скрипт написан путём видоизменения скрипта от The gray Cardinal

InitialFolder = "C:\1" ' каталог, откуда удаляем
ControlDate = Now-3 ' контрольная дата (удаляет файлы с датой создания раньше этой)

'====================================================================
On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")
LogPath = objFSO.GetParentFolderName(WScript.ScriptFullName)
Set LogStream = objFSO.OpenTextFile(LogPath & "\CopyLog.log", 8, True)
LogStream.WriteLine "Начало удаления " & Now()

DelFiles InitialFolder
LogStream.WriteLine "Конец удаления: " & Now()
LogStream.WriteLine
LogStream.Close

' процедура рекурсивно перебирает файлы в каталоге удаляя их
Sub DelFiles(FolderPath)
    On Error Resume Next
    Set objFolderItems = objShellApp.NameSpace(FolderPath).Items()
    For Each objFolderItem In objFolderItems
        If objFolderItem.IsFolder And LCase(Right(objFolderItem.Name, 4)) <> ".zip" Then
            DelFiles objFolderItem.Path
        Else
            Set objFile = objFSO.GetFile(objFolderItem.Path)
            If objFile.DateCreated < ControlDate Then
                LogStream.WriteLine "Был удалён файл: " & objFolderItem.Path
                objFile.Delete true
            End If
        End If
    Next
End Sub

Прива Санчел, что то ControlDate = Now-3 ' контрольная дата (удаляет файлы с датой создания раньше этой) не работит, правильно я понимаю что Now -3 удаляет на три дня до текущей даты
у меня этот скрипт затирает вообще все файлы в папке не смотря на разные даты файлов, включая файлы на текущую дату... в чем загвоздка, помогите! может у меня нет каких нить патчей на VBS и поэтому не понимает синтаксис скрипта???

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (alexii) — Tue, 14 Aug 2007 05:58:10 +0000

Выложите Ваш вариант шаблона, мне тоже интересно.

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (CAIIIOK) — Sat, 11 Aug 2007 15:34:39 +0000

alexii пишет:

Попробуйте такой вариант шаблона...

alexii, с Вашей помошью разобрался я с паттернами :-)

Немного еще покрутил предложенный Вами вариант, и получилось то, что нужно. Работает все замечательно.

Еще раз спасибо.

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (alexii) — Thu, 09 Aug 2007 04:17:48 +0000

Регулярные выражения — очень мощная вещь, при правильном подходе . Мой, как обычно, оказался недостаточно проверенным.

Попробуйте такой вариант шаблона (на основе Вашего примера):

Set objRegExp = CreateObject("VBScript.RegExp")
objRegExp.Global = False
objRegExp.Pattern = "^\d{5}-\d{2}-\d{2}\..{0,4}$"
Str = "12345-01-01.xls"
MsgBox objRegExp.Test(Str), 0 ,Str
Str = "Копия 12345-01-01.xls"
MsgBox objRegExp.Test(Str), 0 ,Str
Str = "12345-01-01.Копия.xls"
MsgBox objRegExp.Test(Str), 0 ,Str
Str = "12345-01-01.Коп.xls"
MsgBox objRegExp.Test(Str), 0 ,Str
Str = "12345-01-01."
MsgBox objRegExp.Test(Str), 0 ,Str

{0,4} — ну, если вдруг *.html, что-ли. Хотя, если у Вас только *.xls, то можно так и написать.

P.S. Да, кстати, "12345-01-01." в примере отрабатывает, но в скрипте-то objFile.Name вернёт только "12345-01-01", т.е. без точки; так что, пожалуй, даже

...
objRegExp.Pattern = "^\d{5}-\d{2}-\d{2}(|\..{1,4})$"
...
Str = "12345-01-01."
MsgBox objRegExp.Test(Str), 0 ,Str 'Должно быть Ложь
Str = "12345-01-01"
MsgBox objRegExp.Test(Str), 0 ,Str 'Должно быть Истина

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (CAIIIOK) — Wed, 08 Aug 2007 18:49:27 +0000

The gray Cardinal пишет:

Регулярными выражениями.

Спасибо.

alexii пишет:

...
objRegExp.Pattern = "\d{5}-\d{2}-\d{2}\..*"
...

До подобного кода я уже дошел, а вот с паттерном есть определенные сложности: и в случае, когда переменная objFile.Name равна "12345-01-01.xls", и когда это же переменная равна "Копия 12345-01-01.xls", результат одинаков - objRegExp.Test(objFile.Name) - истина. Наглядно демонстрируется вот этим:

Set objRegExp = CreateObject("VBScript.RegExp")
objRegExp.Global = False
objRegExp.Pattern = "\d{5}-\d{2}-\d{2}\..*"
Str = "12345-01-01.xls"
MsgBox objRegExp.Test(Str)
Str = "Копия 12345-01-01.xls"
MsgBox objRegExp.Test(Str)

Другой вариант паттерна мне в готову не пришел...

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (alexii) — Tue, 07 Aug 2007 13:07:34 +0000

Я пробовал так:

...
Dim objRegExp 
...
Set objRegExp = New RegExp
objRegExp.IgnoreCase = True
objRegExp.Global = False
' Только десятичные символы в имени; иначе 
' использовать [.{5}-.{2}-.{2}\..*] для любых символов в имени.
objRegExp.Pattern = "\d{5}-\d{2}-\d{2}\..*"
...
For Each objFile In objFSO.GetFolder(strWorkFolder).Files
    If objRegExp.Test(objFile.Name) Then
        If Age(objFile) > 5 Then
            MoveFileToArchive objFile, objArchiveFolder
        End If
    End If
Next
...

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (The gray Cardinal) — Sun, 05 Aug 2007 19:39:35 +0000

CAIIIOK пишет:

...как сделать проверку на соотвествие имени файла формату XXXXX-YY-ZZ (т.е. первые пять символов имени - цифры, шестой - "-", и если не соответствует - не перемещать?

Регулярными выражениями.

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (CAIIIOK) — Sun, 05 Aug 2007 13:26:21 +0000

alexii, спасибо большое!

Вот, немного домучал, прикрутил лог и проверку на ошибки (спасибо The gray Cardinal за скрипт на предыдущей странице):

Option Explicit

Public objFSO
Dim objArchiveFolder
Dim objFile

Dim strWorkFolder
Dim strArchiveFolder
Dim LogStream
Dim LogPath 
Dim objShellApp

set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShellApp = CreateObject("Shell.Application")

strWorkFolder = "D:\Test"
strArchiveFolder = strWorkFolder & "\Архив"
LogPath = strArchiveFolder

set LogStream = objFSO.OpenTextFile(LogPath & "\MoveLog.log", 8, True)

LogStream.WriteLine
LogStream.WriteLine "--- Начало работы " & Now() & " ---"

If Not objFSO.FolderExists(strArchiveFolder) Then
    objFSO.CreateFolder strArchiveFolder
    LogStream.WriteLine "Создана папка " & strArchiveFolder
    
End If

Set objArchiveFolder = objFSO.GetFolder(strArchiveFolder)

For Each objFile In objFSO.GetFolder(strWorkFolder).Files
    If Age(objFile) > 5 Then
        MoveFileToArchive objFile, objArchiveFolder
    End If
Next

LogStream.WriteLine
LogStream.WriteLine "--- Окончание работы " & Now() & " ---"

WScript.Quit(0)

'=======================================================================
Function Age(objFile)
    Age = DateDiff("d", objFile.DateCreated, Now())
End Function
'=======================================================================

'=======================================================================
Sub MoveFileToArchive(objFile, objArchiveFolder)
    
    On Error Resume Next

    Dim strSubFolderToMove

    strSubFolderToMove = objArchiveFolder.Path & "\" & Left(objFile.Name, 5)
    
    If Not objFSO.FolderExists(strSubFolderToMove) Then
        objFSO.CreateFolder strSubFolderToMove
        LogStream.WriteLine
        LogStream.WriteLine "Создана папка " & strSubFolderToMove
    
    
    End If

    objFile.Move strSubFolderToMove & "\" & objFile.Name

    If Err.Number <> 0 Then
        
        LogStream.WriteLine "Ошибка перемещения файла " & strWorkFolder & "\" & objFile.Name & " - " & Err.Description
        Err.Clear

    Else

        LogStream.WriteLine "Файл " & objFile.Name & " перемещен в " & strSubFolderToMove & "\" & objFile.Name


    End If
    
    
End Sub
'=======================================================================

Сильно не ругайте - делаю это в первый раз.

Еще вопрос: как сделать проверку на соотвествие имени файла формату XXXXX-YY-ZZ (т.е. первые пять символов имени - цифры, шестой - "-", и если не соответствует - не перемещать?

Заранее спасибо.

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (alexii) — Sat, 04 Aug 2007 13:31:47 +0000

Примерно так:

Option Explicit

Public objFSO
Dim objArchiveFolder
Dim objFile

Dim strWorkFolder
Dim strArchiveFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

strWorkFolder = "c:\Temp\001"
strArchiveFolder = strWorkFolder & "\Архив"

If Not objFSO.FolderExists(strArchiveFolder) Then
    objFSO.CreateFolder strArchiveFolder
End If

Set objArchiveFolder = objFSO.GetFolder(strArchiveFolder)

For Each objFile In objFSO.GetFolder(strWorkFolder).Files
    If Age(objFile) > 5 Then
        MoveFileToArchive objFile, objArchiveFolder
    End If
Next

WScript.Quit(0)

'=======================================================================
Function Age(objFile)
    Age = DateDiff("d", objFile.DateCreated, Now())
End Function
'=======================================================================

'=======================================================================
Sub MoveFileToArchive(objFile, objArchiveFolder)
    Dim strSubFolderToMove

    strSubFolderToMove = objArchiveFolder.Path & "\" & Left(objFile.Name, 5)
    
    If Not objFSO.FolderExists(strSubFolderToMove) Then
        objFSO.CreateFolder strSubFolderToMove
    End If

    objFile.Move strSubFolderToMove & "\" & objFile.Name
End Sub
'=======================================================================

Проверяйте сначала обязательно на копии

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (CAIIIOK) — Sat, 04 Aug 2007 11:23:49 +0000

Здравствуйте всем!

Есть такая задача: существует папка, в которой сложены файлы вида XXXXX-YY-ZZ, т.е. 12345-01-01, 12345-01-02, 12345-02-01, 12345-02-02 и т.д.
Необходим скрипт, который бы во вложенной папке "Архив" создавал подпапку XXXXX (первые пять символов имени файла) и все файлы старше 5 дней (дата создания), содержащие эти символы в начале своего имени, перемещал в соответствующую папку. Сколько ни пробовал, ничего толком не получается.

У кого какие идеи?

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (The gray Cardinal) — Fri, 27 Jul 2007 09:10:21 +0000

lexx пишет:

Аналогичная задача, только надо не скопировать а переместить файлы старше определенной даты.
Какую функцию поставить?

Вместо CopyFile подставить MoveFile. Синтаксис вызова - см. в файле http://www.script-coding.com/wsh_chm.zip.

lexx пишет:

как сделать чтобы он перемещал файлы старше месяца (отсчет от текущей даты)

Запусти вот это:

WScript.Echo Now
WScript.Echo Now - 30

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (lexx) — Fri, 27 Jul 2007 08:58:21 +0000

Еще забыл, подскажите как сделать чтобы он перемещал файлы старше месяца (отсчет от текущей даты)

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (lexx) — Fri, 27 Jul 2007 08:52:46 +0000

Здравствуйте!

Аналогичная задача, только надо не скопировать а переместить файлы старше определенной даты.
Какую функцию поставить?
А то в скриптах не силен

Спасибо большое

Re: WSH: Нужен скрипт для копирования файлов

null@example.com (The gray Cardinal) — Mon, 25 Jun 2007 16:10:54 +0000

Поскольку постоянно спрашивают, я дополнил пример в коллекции "простым" копированием без условий и подпапок.