Серый форум — AHK: Progress Bar

Re: AHK: Progress Bar

2016-12-23T10:56:04Z

becauseim

period := 400
w := 50, h := 7
CreateProgress(w, h)
TimeoutAction := Func("TimeoutAction")
Return

RButton:: ShowProgress(period, TimeoutAction,  w)
Esc:: ExitApp
   
ShowProgress(time, TimeoutAction, w := "")  {
   static start, timer
   (!start && start := A_TickCount)
   if !timer  {
      CoordMode, Mouse
      MouseGetPos, X, Y
      GuiControl,, Progress, 0
      Gui, Show, % "NA x" X - w//2 " y" y + 15
      timer := Func(A_ThisFunc).Bind(time, TimeoutAction)
      SetTimer, % timer, 10
   }
   pos := Round((A_TickCount - start)/time*100)
   (pos > 100 && pos := 100)
   GuiControl,, Progress, % pos
   if (pos = 100)  || !GetKeyState("RButton", "P")  {
      SetTimer,, Delete
      start := timer := ""
      Gui, Show, Hide
      (pos = 100 && TimeoutAction.Call())
   }
}

CreateProgress(w, h)  {
   global Progress
   Gui, +ToolWindow -Caption +AlwaysOnTop
   Gui, Add, Progress, x0 y0 w%w% h%h% vProgress
   Gui, Show, Hide w%w% h%h%
}

TimeoutAction()  {
   MsgBox, Действие`, если время вышло
}

Re: AHK: Progress Bar

2016-12-23T09:22:49Z

Flasher пишет:

Чаще встречаешь тех, кто хочет от него избавиться.

В ТС для меня он действительно ни к чему. Впрочем, как и сам вызов контекстного меню при удержании ПКМ. А в других случаях было бы интересно иметь миниатюрный прогресс-бар, привязанный к удержанию.

Re: AHK: Progress Bar

2016-12-22T23:41:57Z

Еще, чтобы в минус не ушел отсчет, можно так:

Number := 10
Gui, Font, s15
Gui, Add, Text, vText1, 111111111
GuiControl,,Text1, 10
Gui, Add, Progress, vProgress1 w500 h50 -Smooth Range0-500
Gui, Show

SetTimer, Progress2, 1000
ProgressBar("Progress1", Number, 1000)
return

Progress2:
Number -= 1
qw := Number > 0 ? Number : 0
GuiControl,, Text1, %qw%
Return

ProgressBar(sBar, tTime, iRange)
{
	tTime := (tTime * 130)
	iSpeed := iRange / tTime
	iWay := 0 ; WriteDebug(1, "Start")
	While(1)
	{
		Sleep 1
		GuiControl,, %sBar%,% iWay
		iWay += iSpeed
		If(iWay > iRange)
			break
        ; WriteDebug(1, "End")

	}
	
}

Re: AHK: Progress Bar

2016-12-22T21:51:46Z

stealzy
При таких числах нет проблем.

Re: AHK: Progress Bar

2016-12-22T21:47:57Z

Здрасьте, команды то не мгновенно исполняются.
Используйте A_TimeIdle, на старте функции записывайте ее значение, а в цикле вычисляйте разницу.

Re: AHK: Progress Bar

2016-12-22T20:37:25Z

becauseim
Чаще встречаешь тех, кто хочет от него избавиться. Впрочем, это опциональная вещь.

Re: AHK: Progress Bar

2016-12-22T20:31:24Z

Смежный вопрос. Существует ли сценарий, который добавляет к курсору маленький прогресс-бар для отображения необходимой длительности удержания ПКМ, как это реализовано в TotalCommander?
Иными словами, добавить к действию на удержание ПКМ на полторы секунды маленький прогресс-бар рядом с курсором.

AHK: Progress Bar

2016-12-22T12:24:50Z

Number := 10
Gui, Font, s15
Gui, Add, Text, vText1, 111111111
GuiControl,,Text1, 10
Gui, Add, Progress, vProgress1 w500 h100 -Smooth Range0-500
Gui, Show

SetTimer, Progress2, 1000
ProgressBar("Progress1", Number, 500)
return

Progress2:
Number -= 1
GuiControl,, Text1,% Number
Return

ProgressBar(sBar, tTime, iRange)
{
	tTime := (tTime * 100)
	iSpeed := iRange / tTime
	iWay := 0
	;WriteDebug(1, "Start")
	While(1)
	{
		Sleep 1
		GuiControl,, %sBar%,% iWay
		iWay += iSpeed
		If(iWay > iRange)
			break
	}
	;WriteDebug(1, "End")

}

Погрешность в 5 секунд. Помогите исправить.