<![CDATA[Серый форум — AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?id=12276 Wed, 04 Jan 2017 06:14:26 +0000 PunBB <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110491#p110491 Здорово, спасибо большое.

Подскажите еще, как настройки типографа передавать в xml-запросе? Например, чтобы на выходе готовый текст получался, а не буквенные коды.

http://www.artlebedev.ru/tools/typograf/preferences/

Я пока разобрался только как <p></p> и <br> делать.

UPD: уже разобрался. Спасибо еще раз.

]]> Wed, 04 Jan 2017 06:14:26 +0000 https://forum.script-coding.com/viewtopic.php?pid=110491#p110491 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110489#p110489 Вот так, как на сайте:

text1 := "<>"
text2 =
(
<ProcessTextResult>
— Это "Типограф"?
<ProcessTextResult>
— Нет, это «Типограф»!
)
Typograf := new Typograf
MsgBox, % Typograf.Process(text1)
MsgBox, % Typograf.Process(text2)
MsgBox, % Typograf.Process(text2, true)  ; с переносом строк

class Typograf  {
   __New()  {
      this.xmlhttp := ComObjCreate("Msxml2.XMLHTTP")
      this.WaitForResponse := ObjBindMethod(this, "Ready")
   }
   
   Process(text, useBr := false)  {
      text := this.Replace(text)
      xmlRequest := "<?xml version=""1.0"" encoding=""UTF-8""?>"
                  . "<soap:Envelope xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"""
                  . " xmlns:xsd=""http://www.w3.org/2001/XMLSchema"""
                  . " xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"">"
                  . "<soap:Body>"
                  . "<ProcessText xmlns=""http://typograf.artlebedev.ru/webservices/"">"
                  . "<text>" . text . "</text>"
                  . "<useP>0</useP>"
                  . "<useBr>" . useBr . "</useBr>"
                  . "</ProcessText></soap:Body></soap:Envelope>"
                  
      url := "http://typograf.artlebedev.ru/webservices/typograf.asmx"
      this.xmlhttp.Open("POST", url, true)
      this.xmlhttp.onreadystatechange := this.WaitForResponse
      this.xmlhttp.setRequestHeader("Content-Type", "text/xml")
      this.xmlhttp.Send(xmlRequest)
      while this.result = ""
         Sleep, 200
      res := RegExReplace(this.result, "s).*<ProcessTextResult>(.*)</ProcessTextResult>.*", "$1")
      this.result := ""
      Return this.Replace(res, false)
   }
   
   Ready()  {
      if this.xmlhttp.readyState != 4
         Return
      this.result := this.xmlhttp.ResponseText
   }
   
   Replace(text, direction := true)  {
      for k, v in direction ? [["&", "&amp;"], ["<", "&lt;"], [">", "&gt;"]] : [["&lt;", "<"], ["&gt;", ">"], ["&amp;", "&"]]
         text := StrReplace(text, v[1], v[2])
      Return text
   }
}

Только, если как в примере, тогда то, что в тегах (в угловых скобках), вообще удалится:

text = text.replace (/<[^>]+>/g, '');
]]> Wed, 04 Jan 2017 01:44:05 +0000 https://forum.script-coding.com/viewtopic.php?pid=110489#p110489 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110488#p110488 Ну если посмотреть исходник примера, то там идет так:

function remoteTypograf (text)
{
text = text.replace (/<[^>]+>/g, '');
text = text.replace (/&/g, '&amp;');
text = text.replace (/</g, '&lt;');
text = text.replace (/>/g, '&gt;');
function parseTypografAnswer()
{
var response = xmlSocket.responseText;
var re = /<ProcessTextResult>\s*((.|\n)*?)\s*<\/ProcessTextResult>/m;
response = re.exec (response);
response = RegExp.$1;
response = response.replace (/&gt;/g, '>');
response = response.replace (/&lt;/g, '<');
response = response.replace (/&amp;/g, '&');

http://www.artlebedev.ru/tools/technogr … ample.html

]]> Wed, 04 Jan 2017 01:04:13 +0000 https://forum.script-coding.com/viewtopic.php?pid=110488#p110488 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110487#p110487 Хотя не уверен, надо подумать про последовательность замен.

]]> Wed, 04 Jan 2017 00:59:10 +0000 https://forum.script-coding.com/viewtopic.php?pid=110487#p110487 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110486#p110486 Ну в этом случае на сайте ошибка. Угловые скобки должны быть заменены.

]]> Wed, 04 Jan 2017 00:53:44 +0000 https://forum.script-coding.com/viewtopic.php?pid=110486#p110486 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110485#p110485 Результат по сравнению с сайтом разный:

text2 =
(
<ProcessTextResult>
— Это "Типограф"?
<ProcessTextResult>
— Нет, это «Типограф»!
)
]]> Wed, 04 Jan 2017 00:49:14 +0000 https://forum.script-coding.com/viewtopic.php?pid=110485#p110485 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110484#p110484 2) Точно, но достаточно просто перенести замену ["&", "&amp;"] на последнее место.
1) Согласен, но не в этом дело, нужно просто поменять местами замену спецсимволов и поиск тега.

text1 := "<>"
text2 =
(
<ProcessTextResult>
— Это "Типограф"?
<ProcessTextResult>
— Нет, это «Типограф»!
)
Typograf := new Typograf
MsgBox, % Typograf.Process(text1)
MsgBox, % Typograf.Process(text2)
MsgBox, % Typograf.Process(text2, true)  ; с переносом строк

class Typograf  {
   __New()  {
      this.xmlhttp := ComObjCreate("Msxml2.XMLHTTP")
      this.WaitForResponse := ObjBindMethod(this, "Ready")
   }
   
   Process(text, useBr := false)  {
      text := this.Replace(text)
      xmlRequest := "<?xml version=""1.0"" encoding=""UTF-8""?>"
                  . "<soap:Envelope xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"""
                  . " xmlns:xsd=""http://www.w3.org/2001/XMLSchema"""
                  . " xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"">"
                  . "<soap:Body>"
                  . "<ProcessText xmlns=""http://typograf.artlebedev.ru/webservices/"">"
                  . "<text>" . text . "</text>"
                  . "<useP>0</useP>"
                  . "<useBr>" . useBr . "</useBr>"
                  . "</ProcessText></soap:Body></soap:Envelope>"
                  
      url := "http://typograf.artlebedev.ru/webservices/typograf.asmx"
      this.xmlhttp.Open("POST", url, true)
      this.xmlhttp.onreadystatechange := this.WaitForResponse
      this.xmlhttp.setRequestHeader("Content-Type", "text/xml")
      this.xmlhttp.Send(xmlRequest)
      while this.result = ""
         Sleep, 200
      res := RegExReplace(this.result, "s).*<ProcessTextResult>(.*)</ProcessTextResult>.*", "$1")
      this.result := ""
      Return this.Replace(res, false)
   }
   
   Ready()  {
      if this.xmlhttp.readyState != 4
         Return
      this.result := this.xmlhttp.ResponseText
   }
   
   Replace(text, direction := true)  {
      for k, v in [ ["<", "&lt;"], [">", "&gt;"], ["&", "&amp;"] ]
         text := StrReplace(text, direction ? v[1] : v[2], direction ? v[2] : v[1])
      Return text
   }
}
]]> Wed, 04 Jan 2017 00:43:15 +0000 https://forum.script-coding.com/viewtopic.php?pid=110484#p110484 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110483#p110483 1) Имеет. У тебя часть текста может съесться:

text1 =
(
<ProcessTextResult>
— Это "Типограф"?
<ProcessTextResult>
— Нет, это «Типограф»!
)

2) Разница в результате оттипографивания если делать это через сайт:

text1 =
(
<>
)
]]> Wed, 04 Jan 2017 00:29:03 +0000 https://forum.script-coding.com/viewtopic.php?pid=110483#p110483 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110481#p110481 1) — не имеет смысла, в ответе только один такой тег.
2) — а какая разница?

]]> Wed, 04 Jan 2017 00:22:34 +0000 https://forum.script-coding.com/viewtopic.php?pid=110481#p110481 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110480#p110480 Нашел 2 ошибки:
1) Это:

Return RegExReplace(res, "s).*<ProcessTextResult>(.*)</ProcessTextResult>.*", "$1")

Надо исправить на это:

Return RegExReplace(res, "s).*?<ProcessTextResult>(.*)</ProcessTextResult>.*", "$1")

2) Нарушена последовательность изменений в функции Replace(text, direction := true).
Ответ нужно парсить  в такой последовательности:

response = response.replace (/&gt;/g, '>');
response = response.replace (/&lt;/g, '<');
response = response.replace (/&amp;/g, '&');
]]> Wed, 04 Jan 2017 00:12:19 +0000 https://forum.script-coding.com/viewtopic.php?pid=110480#p110480 <![CDATA[Re: AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110479#p110479 Вроде получилось:

text1 := "Johnson & Johnson"
text2 =
(
— Это "Типограф"?
— Нет, это «Типограф»!
)
Typograf := new Typograf
MsgBox, % Typograf.Process(text1)
MsgBox, % Typograf.Process(text2)
MsgBox, % Typograf.Process(text2, true)  ; с переносом строк

class Typograf  {
   __New()  {
      this.xmlhttp := ComObjCreate("Msxml2.XMLHTTP")
      this.WaitForResponse := ObjBindMethod(this, "Ready")
   }
   
   Process(text, useBr := false)  {
      text := this.Replace(text)
      xmlRequest := "<?xml version=""1.0"" encoding=""UTF-8""?>"
                  . "<soap:Envelope xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"""
                  . " xmlns:xsd=""http://www.w3.org/2001/XMLSchema"""
                  . " xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"">"
                  . "<soap:Body>"
                  . "<ProcessText xmlns=""http://typograf.artlebedev.ru/webservices/"">"
                  . "<text>" . text . "</text>"
                  . "<useP>0</useP>"
                  . "<useBr>" . useBr . "</useBr>"
                  . "</ProcessText></soap:Body></soap:Envelope>"
                  
      url := "http://typograf.artlebedev.ru/webservices/typograf.asmx"
      this.xmlhttp.Open("POST", url, true)
      this.xmlhttp.onreadystatechange := this.WaitForResponse
      this.xmlhttp.setRequestHeader("Content-Type", "text/xml")
      this.xmlhttp.Send(xmlRequest)
      while this.result = ""
         Sleep, 200
      res := this.Replace(this.result, false)
      this.result := ""
      Return RegExReplace(res, "s).*<ProcessTextResult>(.*)</ProcessTextResult>.*", "$1")
   }
   
   Ready()  {
      if this.xmlhttp.readyState != 4
         Return
      this.result := this.xmlhttp.ResponseText
   }
   
   Replace(text, direction := true)  {
      for k, v in [ ["&", "&amp;"], ["<", "&lt;"], [">", "&gt;"] ]
         text := StrReplace(text, direction ? v[1] : v[2], direction ? v[2] : v[1])
      Return text
   }
}
]]> Tue, 03 Jan 2017 23:09:27 +0000 https://forum.script-coding.com/viewtopic.php?pid=110479#p110479 <![CDATA[AHK: API Типографа Лебедева]]> https://forum.script-coding.com/viewtopic.php?pid=110474#p110474 Привет, форумчане.

Я хочу создать скрипт, который будет типографить выделенный текст. Для этого думаю подключаться к типографу Лебедева.
Подскажите, как это сделать вообще? И можно ли вообще?

Типограф: http://www.artlebedev.ru/tools/typograf/

API: http://www.artlebedev.ru/tools/typograf/webservice/

]]> Tue, 03 Jan 2017 18:54:07 +0000 https://forum.script-coding.com/viewtopic.php?pid=110474#p110474