Серый форум — AHK: Активация Mozilla Firefox без панели задач

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T20:43:57Z

Как вариант:

f1::
SetWinDelay, -1
if toggle := !toggle
{
    WinHide ahk_class Shell_TrayWnd
    WinHide Start ahk_class Button
    SysGet, Mon, Monitor
    SetWorkArea(MonLeft, MonTop, MonRight, MonBottom)
    WinMove, ahk_class Notepad,, MonLeft, MonTop , MonRight, MonBottom
}
else
{
    WinShow ahk_class Shell_TrayWnd
    WinShow Start ahk_class Button
    SysGet, Mon, MonitorWorkArea
    SetWorkArea(MonLeft, MonTop, MonRight, MonBottom)
    WinMove, ahk_class Notepad,, MonLeft, MonTop , MonRight, MonBottom
}
return

SetWorkArea(left,top,right,bottom)  ; set main monitor work area ; windows are not resized!
{
    VarSetCapacity(area, 16)
    NumPut(left,  area, 0, "UInt") ; left
    NumPut(top,   area, 4, "UInt") ; top
    NumPut(right, area, 8, "UInt") ; right
    NumPut(bottom,area,12, "UInt") ; bottom
    DllCall("SystemParametersInfo", "UInt", 0x2F, "UInt", 0, "UPtr", &area, "UInt", 0) ; SPI_SETWORKAREA
}

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T20:00:00Z

На семёрке отдельное окно.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T19:57:15Z

Если нажать "развернуть", окно растянется не на весь экран, а с вычетом габаритов Панели задач. Но если растягивать окно вручную, им можно заполнить весь экран.
Про кнопку "Старт" не знаю, может это отдельное окно?

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T19:46:28Z

Не знаю, смотря какие задачи. При скрытии на семёрке остаётся кнопка «Старт» и рабочее пространство полноэкранных окон не занимает место таскбара, остаётся бесполезная полоса внизу.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T19:37:56Z

Не, я просто отметил особенности скрипта.

По теме - мне не очень понятно, для чего изменять размеры рабочей области Рабочего стола. Просто скрыть окно Панели задач командой WinHide- не вариант?

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T18:03:58Z

ypppu, всё так и должно быть, кроме высоты. Она не указана явно, видимо, сбивается на дефолтную, на семёрке такого не происходит. Если нужно, могу подправить.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T14:06:09Z

Опробовал на Windows XP. Изменяется высота панели задач (была двойная, стала одинарная), выключается "автоматически скрывать панель задач", включается "отображать панель задач поверх остальных окон".

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T09:51:57Z

teadrinker, спасибо вам за помощь.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T09:46:25Z

F2::
   HideShowTaskbar(toggle := !toggle)
   if toggle
      WinActivate ahk_class MozillaWindowClass
   else
      WinMinimize ahk_class MozillaWindowClass
   Return
   
HideShowTaskbar(action)
{
   static ABM_SETSTATE := 0xA, ABS_AUTOHIDE := 0x1, ABS_ALWAYSONTOP := 0x2
   
   VarSetCapacity(APPBARDATA, size := 2*A_PtrSize + 2*4 + 16 + A_PtrSize, 0)
   NumPut(size, APPBARDATA), NumPut(WinExist("ahk_class Shell_TrayWnd"), APPBARDATA, A_PtrSize)
   NumPut(action ? ABS_AUTOHIDE : ABS_ALWAYSONTOP, APPBARDATA, size - A_PtrSize)
   
   DllCall("Shell32\SHAppBarMessage", UInt, ABM_SETSTATE, Ptr, &APPBARDATA)
}

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T09:41:55Z

Кусок моего кода:

toggle := 0
F2::
toggle := !toggle
if toggle
   WinActivate ahk_class MozillaWindowClass
else
   WinMinimize ahk_class MozillaWindowClass
Return

Кусок вашего кода

F2:: HideShowTaskbar(hide := !hide)
   
HideShowTaskbar(action)
{
   static ABM_SETSTATE := 0xA, ABS_AUTOHIDE := 0x1, ABS_ALWAYSONTOP := 0x2
   
   VarSetCapacity(APPBARDATA, size := 2*A_PtrSize + 2*4 + 16 + A_PtrSize, 0)
   NumPut(size, APPBARDATA), NumPut(WinExist("ahk_class Shell_TrayWnd"), APPBARDATA, A_PtrSize)
   NumPut(action ? ABS_AUTOHIDE : ABS_ALWAYSONTOP, APPBARDATA, size - A_PtrSize)
   
   DllCall("Shell32\SHAppBarMessage", UInt, ABM_SETSTATE, Ptr, &APPBARDATA)
}

Как совместить?

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T09:35:20Z

Так а в чём вопрос? Как скрыть панель задач по горячей клавише?

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T09:15:09Z

Ваша правда, это мне поможет, по правде говоря я собирался использовать этот метод в случае тут ничего не выйдет, у меня имеется софт для скрытия панели задач.

Находясь в активном окне в оконном режиме без рамки(в котором не отображается панель задач), хотелось бы посредством горячей клавиши активировать браузер всё также сохраняя сокрытие панели задач.

Однако в другие моменты мне нужна панель задач и выходит так что мне каждый раз придётся пользоваться горячими клавишами для проявления панели задач или же панель будет показываться в момент наведение курсора мыши.

Техническая сторона данного вопроса для меня сложна, я думаю что нужен подобный механизм.
Если: Нажата горячая клавиша "F2" ; работа в режиме toggle
То: Скрыть панель задач, активировать окно браузера
Если: Нажата горячая клавиша "F2" работа в режиме toggle
То: Показать панель задач, свернуть окно браузера ; В данном случае показываться панель задач должна не в буквальном смысле слова, восстановление возможности показываться, т.е. во время работы в оконном режиме без рамки панель задач должна быть всё так-же не видна.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-03T08:25:08Z

Тогда может просто скрыть панель задач на всё время работы скрипта?

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-02T15:37:10Z

Возможно я не совсем корректно выразился.
http://imgur.com/a/j8wjC
Во время использования окна #1 панели задач нету тк. выставлена настройка "Оконный режим без рамки"
Нужно чтобы во время обращения к окну #2[Браузер] панель задач не появлялась.

Re: AHK: Активация Mozilla Firefox без панели задач

2017-03-02T14:06:54Z

DxNeferzul пишет:

Нужно чтобы при использовании скрипта панель задач не активировалась.

Не пойму, что имеется в виду. При активации окна панель задач не может активироваться, активным может быть только одно окно.