Серый форум — AHK: Несколько результатов в многострочной регулярке

Re: AHK: Несколько результатов в многострочной регулярке

2017-03-03T07:39:19Z

text = 
(

тест 4



тест 3



тест 1

)

MsgBox, % RegExReplace(text, "m`as)^(тест (\d+)$(?=.*(^тест \d+$))?|.*?)(?(3)|(\R|$))", "$2")

Или, если в конце строки "тест 1" не обязательно число, а просто один символ:

RegExReplace(text, "m`as)^(тест (.)$(?=.*(^тест .$))?|.*?)(?(3)|(\R|$))", "$2")

Re: AHK: Несколько результатов в многострочной регулярке

2017-03-03T00:24:05Z

Turambar
Почему тема в Games? Перенесено в основной раздел.

text =
(

тест 4



тест 3



тест 1

)

Pos = 1
While Pos := RegExMatch(text, "\nтест (\d+)\n", Match, Pos+StrLen(Match))
  S := S "`n" Match1
FileOpen("test.txt", "w").Write(SubStr(S, 2))

; Либо:

RegExp := ComObjCreate("VBScript.Regexp")
RegExp.Pattern := "\nтест (\d+)\n"
RegExp.Global := 1, Col := RegExp.Execute(Text)
Loop, % Col.Count
  S := S "`n" Col.Item(A_Index-1).Submatches(0)
FileOpen("test.txt", "w").Write(SubStr(S, 2))

AHK: Несколько результатов в многострочной регулярке

2017-03-02T17:16:27Z

Здравствуйте. Вопрос следующего характера. Как можно заставить многострочную регулярку вывести все совпадения?

В указанном примере выводится только первое значение (разумеется!). Но как сделать запись в файл всех? Поместить регулярку в какой-то цикл? Но как? Ведь построчный цикл чтения (Loop, Read,) тут уже не подойдёт, поскольку регулярка многострочная.

Количество блоков заранее неизвестно. От 0 до тысячи.

text = 
(

тест 4



тест 3



тест 1

)

pattern=.*?тест (.).*?
if RegExMatch(text, pattern, line)
   FileAppend, %line1%`n, %A_ScriptDir%/test.txt
return

Должно быть в файле на выходе:


4
3
1