Серый форум — AHK: Неминимизируемое окно Gui

Re: AHK: Неминимизируемое окно Gui

2017-03-08T10:43:05Z

Malcev
Этот вариант работает очень стабильно (и Win7 и Win10). Спасибо!

Re: AHK: Неминимизируемое окно Gui

2017-03-08T08:09:24Z

SetWinDelay -1
SetBatchLines -1
Gui +LastFound -Caption +toolwindow +hwndhGui -
bgcolor = 000000
Gui, Color, %bgcolor%
Gui, Font, s16 cFFFFFF bold
linespace = y+8
Gui, Add, Text,%linespace%, Имя АРМ: %A_ComputerName%
Gui, Add, Text,%linespace%, Пользователь: %A_UserName%

WinSet, TransColor, %bgcolor% 255
xpos := A_ScreenWidth - 550
Gui, Show, NoActivate AutoSize x%xpos% y20

loop
{
   WinGet, list, list
   if !hDesktop := WinExist("ahk_class WorkerW")
   {
      list--
      if (list%list% != hGui)
         WinSet, Bottom,, ahk_id %hGui%
   }
   else
   {
      loop % list
      {
         if (List%A_Index% = hGui)
            break
         WinGetClass, class, % "ahk_id " List%A_Index%
         if (class = "WorkerW") or (class = "")
         {
            loop 2
               WinSet, AlwaysOnTop,, ahk_id %hGui%
            break
         }
      }
   }
   sleep 50
}

Re: AHK: Неминимизируемое окно Gui

2017-03-08T07:00:42Z

Malcev, очень интересный вариант.
Сначала (Win10) - не работало (окно сворачивалось). Перенес на Win7 - заработало со 2 запуска. Потом вновь запускал и на Win10 и на Win7 - работает (не сворачивается). Но почему то иногда (~1 раз из 10) не срабатывает. Пытался поймать закономерность (запускал напрямую из кода, предварительно откомпилировав, во всех случаях кроме Тотала и SciTE дополнительные открытые окна закрывал) - никакой зависимости так и не обнаружил. Вот сейчас - работает. Уже раз 20 перезапустил...

Re: AHK: Неминимизируемое окно Gui

2017-03-07T19:11:44Z

Так сворачивается по «Свернуть все окна».

Re: AHK: Неминимизируемое окно Gui

2017-03-07T18:57:42Z

А так?

SetWinDelay -1
DetectHiddenWindows on
WinGet, list, list, ahk_class WorkerW
hDesktop := list%list%
Gui +LastFound -Caption +toolwindow +hwndhGui

bgcolor = 000000
Gui, Color, %bgcolor%
Gui, Font, s16 cFFFFFF bold
linespace = y+8
Gui, Add, Text,%linespace%, Имя АРМ: %A_ComputerName%
Gui, Add, Text,%linespace%, Пользователь: %A_UserName%

WinSet, TransColor, %bgcolor% 255

xpos := A_ScreenWidth - 550
Gui, Show, NoActivate AutoSize x%xpos% y20
loop
{
   WinWaitActive, ahk_class WorkerW
   DllCall("SetWindowPos", "ptr", hDesktop, "ptr", hGui, "int", 0, "int", 0, "int", 0, "int", 0, "uint", 3) ;3 = SWP_NOSIZE|SWP_NOMOVE
   WinWaitNotActive, ahk_class WorkerW
}
return

#if WinActive("ahk_class WorkerW")
~#vk44::   ; d
~#vk4D::   ; m
sleep 50
DllCall("SetWindowPos", "ptr", hDesktop, "ptr", hGui, "int", 0, "int", 0, "int", 0, "int", 0, "uint", 3) ;3 = SWP_NOSIZE|SWP_NOMOVE
return
#if

Re: AHK: Неминимизируемое окно Gui

2017-03-07T17:43:13Z

Malcev, виноват, тормознул с ответом, но, к сожалению, Ваш последний вариант (в отличии от предпоследнего) у меня не работает ни на Win7 ни на Win10. Окошко скрывается по "Свернуть все окна".
Повторю, предпоследний вариант у меня стабильно работает и с фаерфоксом и с win+d и на win7 и на win10.

Re: AHK: Неминимизируемое окно Gui

2017-03-07T16:41:22Z

Проблема в том, что прозрачность можно установить только 3 способами:
1) SetLayeredWindowAttributes
https://msdn.microsoft.com/en-us/library/ms633540.aspx
Эту функцию использует автохотки в WinSet, TransColor.
Но она работает с дочерними окнами при включенном desktop composition только в Win8.
Возможно в десятке тоже, про нее ничего не сказано.
2) UpdateLayeredWindow
https://msdn.microsoft.com/en-us/library/ms633556.aspx
Тоже самое.
3) Через Direct3D
https://msdn.microsoft.com/en-us/library/ms893092.aspx
Вот там вроде как можно установить прозрачность дочерним окнам.

Re: AHK: Неминимизируемое окно Gui

2017-03-07T16:00:52Z

Тоже был такой вопрос, никак не решил. В смысле такие же костыли. Может из z - order как то удалять окно, не уверен...

Re: AHK: Неминимизируемое окно Gui

2017-03-07T15:53:34Z

mozers пишет:

И предыдущий вариант - хорош

У меня он глючил в 2 случаях:
1) Если при максимизированном окне (тестировал на фаерфоксе) быстро нажимать win+d, то в какой-то момент надпись появлялась поверх фаерфокса, поэтому я заменилил AlwaysOnTop на SetWindowPos, чтобы надпись была только поверх десктопа.
2) Если при активном десктопе и каком нибудь развернутом приложении нажать win+d, то надпись пропадала, поэтому я вставил условие для горячих кнопок при активном десктопе.

Re: AHK: Неминимизируемое окно Gui

2017-03-07T13:27:16Z

mozers, на Ваше письмо отвечаю:
1) По правилам русского языка в конце предложения должны быть знаки препинания. Заглавные буквы и точки - это минимальное требование по грамотности на форуме, но соблюдать его обязательно для всех. Отсутствие точки не компенсируется наличием смайлика.
2) Каждый пользователь при написании сообщения может поставить галочку "Не показывать графические смайлики". Либо в профиле "Показывать смайлы как изображения " (если Вы это имели в виду).
Пользоваться смайлами никто не запрещал. Речь идёт об отсутствии точек.

Re: AHK: Неминимизируемое окно Gui

2017-03-06T18:10:41Z

Malcev
И предыдущий вариант - хорош. Даже на 10ке заработал.
За новый - спасибо - буду тестировать/изучать. Как въеду в смысл написанного - так буду использовать.

Re: AHK: Неминимизируемое окно Gui

2017-03-06T15:24:26Z

mozers, напомню, смайлик точку не заменяет.

У нас не чат, мы пишем аккуратно. Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.

Re: AHK: Неминимизируемое окно Gui

2017-03-06T10:47:29Z

Потестировал - не совсем он надёжный оказался.
Так понадёжней:

SetWinDelay -1
hDesktop := WinExist("ahk_class WorkerW")
Gui +LastFound -Caption +toolwindow +hwndhGui

bgcolor = 000000
Gui, Color, %bgcolor%
Gui, Font, s16 cFFFFFF bold
linespace = y+8
Gui, Add, Text,%linespace%, Имя АРМ: %A_ComputerName%
Gui, Add, Text,%linespace%, Пользователь: %A_UserName%

WinSet, TransColor, %bgcolor% 255

xpos := A_ScreenWidth - 550
Gui, Show, NoActivate AutoSize x%xpos% y20
loop
{
   WinWaitActive, ahk_class WorkerW
   DllCall("SetWindowPos", "ptr", hDesktop, "ptr", hGui, "int", 0, "int", 0, "int", 0, "int", 0, "uint", 3) ;3 = SWP_NOSIZE|SWP_NOMOVE
   WinWaitNotActive, ahk_class WorkerW
}
return

#if WinActive("ahk_class WorkerW")
~#vk44::   ; d
~#vk4D::   ; m
sleep 50
DllCall("SetWindowPos", "ptr", hDesktop, "ptr", hGui, "int", 0, "int", 0, "int", 0, "int", 0, "uint", 3) ;3 = SWP_NOSIZE|SWP_NOMOVE
return
#if

Re: AHK: Неминимизируемое окно Gui

2017-03-06T08:46:52Z

Malcev, спасибо, простой и надежный вариант!
Добавил только #NoTrayIcon и строчку для получения полных ФИО (чтоб сразу было видно к кому ты по удаленке подключился)

Gui Add, Text,, % ComObjGet("LDAP://" . ComObjCreate("ADSystemInfo").UserName).cn

Все! Выбрасываю Русиновичевский BGInfo

Re: AHK: Неминимизируемое окно Gui

2017-03-05T19:00:40Z

Дочерние окна не могут быть прозрачными.
Хотя, при отключенном desktop composition - работает.
При +ToolWindow и нажатии Show Desktop, как я понимаю окно не минимизируется, а просто перекрывается десктопом.
Поэтому можно сделать так:

SetWinDelay -1
Gui +LastFound -Caption +toolwindow +hwndhGui

bgcolor = 000000
Gui, Color, %bgcolor%
Gui, Font, s16 cFFFFFF bold
linespace = y+8
Gui, Add, Text,%linespace%, Имя АРМ: %A_ComputerName%
Gui, Add, Text,%linespace%, Пользователь: %A_UserName%

WinSet, TransColor, %bgcolor% 255

xpos := A_ScreenWidth - 550
Gui, Show, NoActivate AutoSize x%xpos% y20
loop
{
   WinWaitActive, ahk_class WorkerW
   loop 2
      WinSet, AlwaysOnTop, Toggle, ahk_id %hGui%
   WinWaitNotActive, ahk_class WorkerW
}