#NoEnv
#SingleInstance, force
#NoTrayIcon
SetTitleMatchMode RegEx
GroupAdd, Browsers, ahk_class MozillaWindowClass
GroupAdd, Browsers, ahk_class Chrome_WidgetWin
GroupAdd, Browsers, ahk_class OperaWindowClass
GroupAdd, Browsers, ahk_class IEFrame
сообщенийНаСтранице:=20
Return

#IfWinActive ahk_group Browsers
; Shift + Alt + [→]
+!Right::ru_boardMove(сообщенийНаСтранице)
; Shift + Alt + [←]
+!Left::ru_boardMove(-сообщенийНаСтранице)
#If
; Esc::ExitApp

ru_boardMove(n) {
	clipTmp := Clipboard
	Clipboard =
	Send % "^{" Format("vk{:02x}", GetKeyVK("L")) "}" ; Ctrl+L ставит фокус в адр.строку браузера
	Sleep 20
	SendPlay ^{Ins} ; копируем
	ClipWait .3
	url := Clipboard
	If (InStr(url,"forum.ru-board.com") && InStr(url,"&start=")) {
		RegExMatch(url, "(?<=&start=)\d+", pageNumber)
		newPageNumber := pageNumber + n
		newPageNumber .= (n > 0  ?  "#2"  :  "#" (Abs(n)-1)) ; якорь # указывает к какому сообщению на странице перейти
		Clipboard =
		Clipboard := RegExReplace(url, "(?<=&start=).+", newPageNumber)
		ClipWait .3
		Send +{Ins}{Enter} ; переходим по новой ссылке
		Sleep 500
	}
	Clipboard := clipTmp
}