Серый форум — AHK: Несколько подвкладок в главной вкладке (GUI tab)

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2018-07-14T16:53:05Z

По кнопке надо создать вторую вкладку, или переключится на неё?

И то, и другое.

Gui, Add, Tab3, w222 vTab, Вкладка 1|Вкладка 2
Gui, Tab, 1 
Gui, Add, Button, w100 gButton, Кнопка
Gui, Tab, 2
Gui, Show
return

Button:
	GuiControl, Choose, Tab, Вкладка 2
	GuiControl, , Tab, Вкладка 3
	return

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2018-07-14T06:14:40Z

Как создать функцию для кнопки, которая в tab1, при нажатии которой появлялась tab2?

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T17:02:37Z

serzh82saratov пишет:

Название переменных не всегда уместно обсуждать, но может "hChild", или нет?

hParent в том смысле, что оно будет родительским для добавленных позже контролов.

serzh82saratov пишет:

То есть добавленные контролы как бы не имеют родственной связи с табом, а только с #32770?

Ну да, они для него дочерние, а он является дочерним для Gui, и sibling'ом для таба:

Gui, +hwndhGui
Gui, Add, Tab3, hwndhTab, 1
hGW_HWNDNEXT := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)
WinGetClass, winClass, ahk_id %hGW_HWNDNEXT%
MsgBox, % winClass
hParent := DllCall("GetParent", Ptr, hGW_HWNDNEXT)  ; получаем родительское для #32770
MsgBox, % "Хэндл родительского для #32770 = " . Format("{:#x}", hParent) . "`nhTab = " hTab "`nhGui = " hGui

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T16:52:42Z

teadrinker пишет:

т. к. добавленные к Tab3 контролы не являются дочерними для таба (и для отдельных вкладок).

То есть добавленные контролы как бы не имеют родственной связи с табом, а только с #32770?

teadrinker пишет:

hParent := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)

Название переменных не всегда уместно обсуждать, но может "hChild", или нет?

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T16:40:46Z

Тут путаница вышла. При добавлении Tab3 добавляется также контрол #32770. Я думал, что он добавляется только когда к Tab3 добавлен ещё какой-то контрол. Но эта идея была изначально неверной, т. к. добавленные к Tab3 контролы не являются дочерними для таба (и для отдельных вкладок). Так что контрол #32770 добавляется в любом случае.


Gui, Add, Tab3, hwndhTab, 1
hGW_HWNDNEXT := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)   ; можно и GW_HWNDLAST = 1
MsgBox % hGW_HWNDNEXT
WinGetClass, winClass, ahk_id %hGW_HWNDNEXT%
MsgBox, % winClass

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T16:36:09Z

teadrinker пишет:

Тоже так показалось.

Я там выше добавил, это про tab2. В tab3 он есть безусловно.

teadrinker пишет:

Не понял, что именно почему.

Из описания GetWindow я не понял, почему она возвращает в данном случае - "то что требуется".

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T16:31:39Z

serzh82saratov пишет:

Возможно, что можно обойтись без создания контрола в Tab3

Да, у меня получилось, попробовал:

Gui, Main: Default
Gui, Margin, 0, 0
Gui, Add, Tab3, hwndhTab vMainTab w400 h300 gMainTab AltSubmit, Вкладка 1|Вкладка 2|Вкладка 3
hParent := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)
WinGetPos,,, W, H, ahk_id %hParent%

Colors := ["Red", "Lime", "Blue"]
Loop 3  {
   Gui, Tab%A_Index%: Default
   Gui, +Parent%hParent% -Caption +ToolWindow
   Gui, Add, Tab3, % "x" 5 " y" 5 " w" W - 20 " h" H - 20, Вкладка %A_Index%-1|Вкладка %A_Index%-2|Вкладка %A_Index%-3
   Gui, Tab, 1
   Gui, Add, Edit, w200 h100, Edit %A_Index%-1
   Gui, Tab, 2
   Gui, Add, Button, gOnClick w100, Кнопка %A_Index%-2
   Gui, Tab, 3
   Gui, Add, Progress, % "w200 h20 c" Colors[A_Index], % 100 * A_Index/3
   Gui, Show, % "Hide x5 y5 w" W - 10 " h" H - 10
}
Gui, Tab1:Show, NA

Gui,Main: Show, w400 h300
Return

OnClick:
   MsgBox, % A_GuiControl
   Return
   
MainTab:
   Gui, Tab%MainTab%:Show, Hide
   GuiControlGet, MainTab, Main:
   Gui, Tab%MainTab%:Show, NA
   Return
   
MainGuiClose:
   ExitApp

serzh82saratov пишет:

#32770, причём он создаётся только если в таб добавлен хотя бы один контрол.

Тоже так показалось.

serzh82saratov пишет:

Ещё вопрос, если с GetWindow работает, то почему?

Не понял, что именно почему.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-15T16:19:08Z

Возможно, что можно обойтись без создания контрола в Tab3:


Gui, Add, Tab3, hwndhTab, 1
Gui, Tab, 1
Gui, Add, Text, hwndhStatic hidden
hParentStatic := DllCall("GetParent", Ptr, hStatic, Ptr)
hGW_HWNDNEXT := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)   ; можно и GW_HWNDLAST = 1
MsgBox % hParentStatic "`n" hGW_HWNDNEXT "`n" (hParentStatic = hGW_HWNDNEXT)

Ещё вопрос, если с GetWindow работает, то почему?


Gui, Add, Tab3, hwndhTab, 1
hGW_HWNDNEXT := DllCall("GetWindow", "Ptr", hTab, "Uint", 2)   ; можно и GW_HWNDLAST = 1
MsgBox % hGW_HWNDNEXT

Из описания не понял.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-09T09:32:07Z

Не только Static, с остальными тоже самое, также если и tab является родительским как в 7 посте.

teadrinker пишет:

В моём варианте дочерние окна добавляются именно к тому элементу, к которому их добавляет AHK

Да, принцип понятен, не заметил сразу что там есть ещё контрол #32770, причём он создаётся только если в таб добавлен хотя бы один контрол.

АПД:

#32770, причём он создаётся только если в таб добавлен хотя бы один контрол.

Как оказалось, это про tab2.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-09T08:45:26Z

Не-а, насколько я понял, у вкладок нет отдельных окон, это просто синтаксис AHK такой, что появление/скрытие контролов, добавленных после Gui, tab, [номер вкладки] программируется автоматически.

У тебя в последнем примере родительские окна — элементы «Static», они по идее не предназначены для этой роли (хотя я о каких-то ограничениях нигде на читал), я бы опасался каких-нибудь проблем — у тебя же с tab3 почему-то нестабильно работало. В моём варианте дочерние окна добавляются именно к тому элементу, к которому их добавляет AHK.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-09T07:43:35Z

teadrinker
С GetParent интересный ход, но можно ли tab сделать дочерним именно вкладке, наподобии как у меня в 11 посте, чтобы не скрывать \ показывать окна при переключении вкладок.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-08T19:15:55Z

Тоже ради интереса сделал, всё работает с Tab3:

Gui, Main: Default
Gui, Margin, 0, 0
Gui, Add, Tab3, vMainTab w400 h300 gMainTab AltSubmit, Вкладка 1|Вкладка 2|Вкладка 3
Gui, Tab, 1
Gui, Add, Text, hwndhStatic hidden
hParent := DllCall("GetParent", Ptr, hStatic, Ptr)
WinGetPos,,, W, H, ahk_id %hParent%

Colors := ["Red", "Lime", "Blue"]
Loop 3  {
   Gui, Tab%A_Index%: Default
   Gui, +Parent%hParent% -Caption +ToolWindow
   Gui, Add, Tab3, % "x" 5 " y" 5 " w" W - 20 " h" H - 20, Вкладка %A_Index%-1|Вкладка %A_Index%-2|Вкладка %A_Index%-3
   Gui, Tab, 1
   Gui, Add, Edit, w200 h100, Edit %A_Index%-1
   Gui, Tab, 2
   Gui, Add, Button, gOnClick w100, Кнопка %A_Index%-2
   Gui, Tab, 3
   Gui, Add, Progress, % "w200 h20 c" Colors[A_Index], % Round(100 * A_Index/3)
   Gui, Show, % "Hide x5 y5 w" W - 10 " h" H - 10
}
Gui, Tab1:Show, NA

Gui,Main: Show, w400 h300
Return

OnClick:
   MsgBox, % A_GuiControl
   Return
   
MainTab:
   Gui, Tab%MainTab%:Show, Hide
   GuiControlGet, MainTab, Main:
   Gui, Tab%MainTab%:Show, NA
   Return
   
MainGuiClose:
   ExitApp

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-08T07:41:50Z

Можно сделать наоборот, чтобы скрывать ЭУ не по одному, а "оптом".

Gui, Add, Button, w100 x10  y10 gTAB1, Вкладка1
Gui, Add, Button, w100 x120 y10 gTAB2, Вкладка2

Gui, Add, Tab, x10 y50 w600 h600 vTAB1, Подвкладка 1-1|Подвкладка 1-2
Gui, Tab, 1, 1
Gui, Add, Text, , 1111111
Gui, Tab, 2, 1
Gui, Add, Text, , 2222222

Gui, Add, Tab, x10 y50 w600 h600 vTAB2, Подвкладка 2-1|Подвкладка 2-2
Gui, Tab, 1,2
Gui, Add, Edit, , 3333333
Gui, Tab, 2,2
Gui, Add, Edit, , 4444444

GUIcontrol, Hide, TAB2

GUI, Show
Return



TAB1:
GUIcontrol, Hide, TAB2
GUIcontrol, Show, TAB1
Return

TAB2:
GUIcontrol, Hide, TAB1
GUIcontrol, Show, TAB2
Return

Кроме того, можно прикрутить ЭУ типа "флажок" или "радио-точка", чтобы было видно, в которой вкладке происходит работа.

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-07T19:38:38Z

Я уже сделал все по примеру yupppu. Пришлось немножко попотеть чтобы присвоить всем текстовым контролам переменные и все их в hide занести, но оно того стоило - все просто идеально. Ещё раз спасибо!

Re: AHK: Несколько подвкладок в главной вкладке (GUI tab)

2017-05-07T18:47:02Z

А если в Tab3 добавлять Tab2, то работает.

Color = 0xC2E2A7
w := 300, h := 200
Gui, -DPIScale
Gui, Color, %Color%
Gui, Add, Tab3, w%w% h%h%, основное|макросы|другое 
Gui, Tab, 1
Gui, Add, Text, HWNDhTab1 x10 y10 w%w% h%h%, % ""
Gui, Tab, 2
Gui, Add, Text, HWNDhTab2 x10 y10 w%w% h%h%, % ""
Gui, Tab, 3
Gui, Add, Text, , другое

Gui, Tab1:Default
Gui, Color, %Color%
Gui, +Parent%hTab1% -Caption -DPIScale
Gui, Add, Tab2, x0 y0 w%w% h%h%, основное 1|основное 2
Gui, Tab, 1
Gui, Add, Edit, , основное 1
Gui, Tab, 2
Gui, Add, Text, , основное 2
Gui, Show, Na x1 y25

Gui, Tab2:Default
Gui, Color, %Color%
Gui, +Parent%hTab2% -Caption -DPIScale
Gui, Add, Tab2, x0 y0 w%w% h%h%, макросы 1|макросы 2|макросы 3
Gui, Tab, 1
Gui, Add, Text, , макросы 1 
Gui, Tab, 2
Gui, Add, Edit, , макросы 2 
Gui, Tab, 3
Gui, Add, Button, , макросы 3
Gui, Show, Na x1 y25

Gui, 1:Default
Gui, Show 
Return