Серый форум — AHK: Преобразование типов данных.

Re: AHK: Преобразование типов данных.

null@example.com (Raven) — Mon, 14 Aug 2017 13:26:40 +0000

Всем откликнувшемся большое спасибо! Код отлично подходит под мои нужды.

Re: AHK: Преобразование типов данных.

null@example.com (teadrinker) — Sat, 12 Aug 2017 10:21:59 +0000

serzh82saratov пишет:

Но в зависимости от целого должно быть как то известно какова возможная точность дроби

Не совсем понял, но скорее всего нет:

MsgBox, % FloatHexConverter(123.456) . "`n" . FloatHexConverter(123.456001)

FloatHexConverter(source)  {
   if source is Float
      isSourceFloat := true
   DllCall( "RtlMoveMemory", isSourceFloat ? "UIntP" : "FloatP", result
                           , isSourceFloat ? "FloatP" : "UIntP", source
                           , Ptr, 4 )
   Return isSourceFloat ? Format("0x{:X}", result) : result
}

Можно, конечно, добавить параметр, определяющий до какого знака округлять, но имхо это будет не очень красиво, т. к. в случае конвертации float в hex он будет лишним.

serzh82saratov пишет:

примере уже не то число, вместо .456000 выходит .456001

Это нормально, действия с float-числами всегда осуществляются с определённой погрешностью, это нужно учитывать.

Re: AHK: Преобразование типов данных.

null@example.com (serzh82saratov) — Sat, 12 Aug 2017 00:52:26 +0000

Но в зависимости от целого должно быть как то известно какова возможная точность дроби, собственно и в примере уже не то число, вместо .456000 выходит .456001.


 Hex := FloatHexConverter(99999.99)  ;	max 2
MsgBox, % FloatHexConverter(Hex, 6)

 Hex := FloatHexConverter(9999.999)  ;	max 3
MsgBox, % FloatHexConverter(Hex, 6)

 Hex := FloatHexConverter(999.9999)  ;	max 4
MsgBox, % FloatHexConverter(Hex, 6)

FloatHexConverter(source, Round = 0)  {
   if source is Float
      isSourceFloat := true
   DllCall( "RtlMoveMemory", isSourceFloat ? "UIntP" : "FloatP", result
                           , isSourceFloat ? "FloatP" : "UIntP", source
                           , Ptr, 4 )
   Return isSourceFloat ? Format("0x{:X}", result) : result   ;	Round(result, Round)
}

Re: AHK: Преобразование типов данных.

null@example.com (teadrinker) — Sat, 12 Aug 2017 00:13:39 +0000

Не, заранее же неизвестно, до какого знака округлять.

Re: AHK: Преобразование типов данных.

null@example.com (serzh82saratov) — Sat, 12 Aug 2017 00:09:22 +0000

Может ещё Round добавить.

Return isSourceFloat ? Format("0x{:X}", result) : Round(result, 3)

Re: AHK: Преобразование типов данных.

null@example.com (teadrinker) — Fri, 11 Aug 2017 23:14:00 +0000

Тогда так:

MsgBox, % FloatHexConverter(123.456)
MsgBox, % FloatHexConverter(0x42F6E979)

FloatHexConverter(source)  {
   if source is Float
      isSourceFloat := true
   DllCall( "RtlMoveMemory", isSourceFloat ? "UIntP" : "FloatP", result
                           , isSourceFloat ? "FloatP" : "UIntP", source
                           , Ptr, 4 )
   Return isSourceFloat ? Format("0x{:X}", result) : result
}

Re: AHK: Преобразование типов данных.

null@example.com (serzh82saratov) — Fri, 11 Aug 2017 22:41:07 +0000


MsgBox, % HexToFloat(0x42F6E979)

HexToFloat(x) {
   DllCall("RtlMoveMemory", "FloatP", f, "UIntP", x, "Uint", 4)
   Return f
}

Re: AHK: Преобразование типов данных.

null@example.com (teadrinker) — Fri, 11 Aug 2017 22:19:27 +0000

MsgBox, % FloatToHex(123.456)

FloatToHex(value)
{
   Return Format( "0x{:X}", DllCall("MulDiv", Float, value, Int, 1, Int, 1, UInt) )
}

Re: AHK: Преобразование типов данных.

null@example.com (Malcev) — Fri, 11 Aug 2017 19:59:37 +0000

HexToFloat(value)
{
    Return, (1 - 2 * (value >> 31)) * (2 ** ((value >> 23 & 255) - 150)) * (0x800000 | value & 0x7FFFFF)
}

FloatToHex(value)
{
   format := A_FormatInteger
   SetFormat, Integer, H
   result := DllCall("MulDiv", Float, value, Int, 1, Int, 1, UInt)
   SetFormat, Integer, %format%
   Return, result
}

Re: AHK: Преобразование типов данных.

null@example.com (Raven) — Fri, 11 Aug 2017 19:44:21 +0000

Уважаемые форумчане, всем спасибо за развернутые ответы. Был в дороге, поэтому не было меня на форме. Весь предоставляемый код который вы дали, смогу проверить только в понедельник, так как нахожусь в отъезде. Будут дельные советы или какой либо код прошу не стесняться и оставлять все это здесь, на благо общественности.

Re: AHK: Преобразование типов данных.

null@example.com (Alectric) — Fri, 11 Aug 2017 18:03:38 +0000

Проблема в том что голова уже не варит... пойду отдыхать.

Re: AHK: Преобразование типов данных.

null@example.com (YMP) — Fri, 11 Aug 2017 18:02:18 +0000

Alectric пишет:

Raven, будет возможность, напиши HEX данные для заранее известного real числа, а лучше для двух разных чисел.

Это не вы разве писали? Я вам показал, как вы можете сами получить эти данные.

Re: AHK: Преобразование типов данных.

null@example.com (teadrinker) — Fri, 11 Aug 2017 18:00:30 +0000

Так а в чём проблема превратить hex в число по тому же алгоритму, только в обратную сторону?

Re: AHK: Преобразование типов данных.

null@example.com (Alectric) — Fri, 11 Aug 2017 17:55:22 +0000

teadrinker пишет:

Из f31ce7d не получится

Alectric пишет:

(цифры от балды, только суть)

Re: AHK: Преобразование типов данных.

null@example.com (Alectric) — Fri, 11 Aug 2017 17:53:20 +0000

Наоборот. В предыдущей теме мы обсуждали как получать данные из ПЛК (программируемый логический контроллер) с помощью dll. Результат работы dll - HEX строка, являющаяся копией памяти ПЛК в которой содержится значение Real представленное на картинке во втором посте. Из этой HEX строки необходимо получить Float число десятичного вида (123.456).