Серый форум — AHK: Получить манифест файла

Re: AHK: Получить манифест файла

null@example.com (Karagiozis) — Sun, 03 Sep 2017 12:48:11 +0000

Спасибо. Все работает.

Re: AHK: Получить манифест файла

null@example.com (YMP) — Sun, 03 Sep 2017 11:46:14 +0000

Да, малость недоработал код. Надо размер ресурса узнавать, иначе StrGet залазит дальше положенного.


File = D:\setup.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
cbData := DllCall("SizeofResource", "ptr", hFile, "ptr", hRsrc)
Manifest := StrGet(pData, cbData, "cp0")
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%

Re: AHK: Получить манифест файла

null@example.com (Karagiozis) — Sat, 02 Sep 2017 20:18:43 +0000

teadrinker пишет:

В вашем файле 0 байт.

Очень странно, но у гугл диска проблема с этим файлом.
Обновил ссылку
https://www.dropbox.com/s/5r5wqtgdje68t … p.exe?dl=0

Re: AHK: Получить манифест файла

null@example.com (teadrinker) — Sat, 02 Sep 2017 16:35:09 +0000

В вашем файле 0 байт.

Re: AHK: Получить манифест файла

null@example.com (Karagiozis) — Sat, 02 Sep 2017 16:11:04 +0000

Помогите! Скрипт крашит, тоесть просто так сам процесс убивается когда пытается прочитать манифест кое-какого файла. Манифест там есть так как Resource Hacker спокойно видит его.
Крашит из-за этой строчки:

Manifest := StrGet(pData, "cp0")

Пробывал словить ошибку, но не помогает:

File = D:\setup.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
try {
	Manifest := StrGet(pData, "cp0") ; Крашит из-за этого
} catch e {
	msgbox, error
}
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%

Вот сам файл:
https://www.dropbox.com/s/5r5wqtgdje68t … p.exe?dl=0

Re: AHK: Получить манифест файла

null@example.com (Karagiozis) — Sat, 26 Aug 2017 11:11:16 +0000

Спасибо большое!

Re: AHK: Получить манифест файла

null@example.com (YMP) — Sat, 26 Aug 2017 08:05:32 +0000

Вот так можно:


File = D:\Temp\Hello.exe
hFile := DllCall("LoadLibraryEx", "str", File, "ptr", 0, "uint", 2, "ptr")
hRsrc := DllCall("FindResource", "ptr", hFile, "ptr", 1, "ptr", 24, "ptr")
hData := DllCall("LoadResource", "ptr", hFile, "ptr", hRsrc, "ptr")
pData := DllCall("LockResource", "ptr", hData, "ptr")
Manifest := StrGet(pData, "cp0")
DllCall("FreeLibrary", "ptr", hFile)
MsgBox, %Manifest%

AHK: Получить манифест файла

null@example.com (Karagiozis) — Fri, 25 Aug 2017 20:01:06 +0000

Доброй ночи. Прошу вашей помощи.
Как можно получить и считать содержимое манифеста в файле если он есть как это делает Resource Hacker?
У скомпилированных ахк скриптов есть манифест. Хотелось бы считать содержимое манифеста любого скомпилированого ахк скрипта.
Я так понял что надо копать в сторону функций FindResource, но поиск привел меня только к извлечению иконок.