Gui, Add, Text, vText gDummy, Main text
Gui, Add, Pic, w32 h-1 vPic1 gDummy Icon28, shell32
Gui, Add, Pic, wp hp xp yp Hidden vPic2 gDummy Icon110, shell32
Gui, Show, w200 h100
OnMessage(0x200, "WM_MOUSEMOVE")
Dummy:
Return

GuiClose:
   ExitApp

WM_MOUSEMOVE(wp, lp, msg, hwnd)  {
   static hover := {}
   if (wp = "timer")  {
      MouseGetPos,,,, hControl, 2
      if (hControl != hwnd)  {
         SetTimer,, Delete
         hover[hwnd] := false
         
         if (msg = "text")  {
            Gui, %lp%:Font, cDefault
            GuiControl, %lp%:Font, % hwnd
         }
         else  {
            GuiControl, %lp%:Hide, Pic2
            GuiControl, %lp%:Show, Pic1
         }
      }
   }
   else  {
      if ( A_GuiControl = "Text" && !hover[hwnd] )  {
         hover[hwnd] := true
         Gui, Font, cRed
         GuiControl, Font, Text
         timer := Func(A_ThisFunc).Bind("timer", A_Gui, "text", hwnd)
         SetTimer, % timer, 100
      }
      else if (A_GuiControl = "Pic1")  {
         GuiControl, Hide, Pic1
         GuiControl, Show, Pic2
      }
      else if ( A_GuiControl = "Pic2" && !hover[hwnd] )  {
         hover[hwnd] := true
         timer := Func(A_ThisFunc).Bind("timer", A_Gui, "pic", hwnd)
         SetTimer, % timer, 100
      }
   }
}

Чтобы его адаптировать для графики нужно вначале понять как скрипт работает.
Для этого нужно почитать команды которые там используются, попытаться понять для чего они там нужны и если есть какие-то по ним вопросы задать их на форуме.

Именно в данном контексте вопрос и был задан:

Код который приведен Разработчиком teadrinker применим к тексту но адаптировать его для графики не вижу возможным, так как большая его часть использует Цвет и Шрифт.

Действительно, Я рассматривал этот вариант, но полноценной (корректной) работы добиться не удалось.
Данный пример хорошо работает с текстом, но к моему сожалению не получается применить его к картинке.

Пример с картинкой плюс доработка против мельканий:

GUI, Add, Picture, vPicture1 Icon4 hwndMyPicture, %A_WinDir%\system32\shell32.dll
GUI, Show
SetTimer, Picture_check , 100
Return



Picture_check:
MouseGetPos, , , , OutputVarControl, 2

IF OutputVarControl = %MyPicture%
	{
	If flag != 5
		{
		GuiControl,, Picture1, *icon5 %A_WinDir%\system32\shell32.dll
		flag = 5
		}
	}

ELSE
	{
	If flag = 5
		{
		GuiControl,, Picture1, *icon4 %A_WinDir%\system32\shell32.dll
		flag = 4
		}
	}
Return




F5:: Reload

В моём сообщении в начале темы есть ссылка на код, в котором отслеживается ЭУ под курсором. Работает стабильно.

Я ознакомился с данным примером, если не затруднит дать небольшое пояснение как задействовать действие при наведении курсора правильно?

Данный пример отлично работает с подсветкой текста, но нестабилен с графикой.

GUI, Add, Text, vMainText hwndMyText, Main text
GUI, Add, Picture, x20 y20 vMAIN1, C:\OFF.BMP
GUI, Add, Picture, x20 y20 vMAIN2, C:\ON.BMP
GUI, Show
SetTimer, Text_check , 100
SetTimer, Pic_check , 100
Return
Text_check:
MouseGetPos, , , , TABLA, 2
IF TABLA = %MyText%
{
Gui, Font, cRed
GuiControl, Font, MainText
}
Else
{
Gui, Font, cDefault
GuiControl, Font, MainText
}
Pic_check:
MouseGetPos, , , , TABLB, 2
If TABLB = %MAIN1%
{
GuiControl, Hide, MAIN1
GuiControl, Show, MAIN2
}
Else
{
GuiControl, Hide, MAIN2
GuiControl, Show, MAIN1
}

Также не ясно почему в данной конструкции есть зависимость между:

MouseGetPos, , , , TABLA, 2
///
MouseGetPos, , , , TABLB, 2

И почему она меняется при смене 2 на 1 в TABLB?
Возможно, я изначально использую не подходящие методы?
Существует более простой способ изменить картинку при наведении на нее курсора?

Осмелюсь предположить, что есть более простое решение без временной переменной…

Чтобы картинка А при наведения на нее курсора мыши, менялось на картинку Б.

А зачем добавлять несколько меток перехода?

Просто эксперементировал. Хотел сделать запуск разных MsgBox из каждого текста.

   Gui, Add, Text, cBlue xp y+5 wp center vChangeColor%A_Index% gDummy1, I'm blue
   Gui, Add, Text, cBlue xp y+5 wp center vChangeColor%A_Index% gDummy2, I'm blue
   Gui, Add, Text, cBlue xp y+5 wp center vChangeColor%A_Index% gDummy3, I'm blue

Dummy1:
	MsgBox  1
Return

Dummy2:
	MsgBox 2
Return

Dummy3:
	MsgBox 3
Return

Почему-то вываливается ошибка

Alectric уже подсказал, что не так делал.

Надо было A_Index убрать.

Разобрался. Спасибо! Все работает.