Серый форум — АХК: добавление в автозагрузку

Re: АХК: добавление в автозагрузку

null@example.com (Vicoriyan) — Sat, 21 Apr 2018 16:06:18 +0000

teadrinker Спасибо. Работает.

Re: АХК: добавление в автозагрузку

null@example.com (teadrinker) — Fri, 20 Apr 2018 14:42:29 +0000

Если внешние файлы находятся в папке скрипта, попробуйте так:

#Include %A_ScriptDir%
#Include MyScript.ahk

Re: АХК: добавление в автозагрузку

null@example.com (Vicoriyan) — Thu, 19 Apr 2018 19:36:04 +0000

Такая проблема. При ручном запуске все библиотеки и внешние файлы подгружаются нормально. Когда происходит автозапуск, ошибка загрузки библиотек и внешних файлов.
Прописывал:

SetWorkingDir % A_ScriptDir

Не помогает. Прописывать в #Include полный путь - не вариант.
Есть какие-то другие варианты?

Re: АХК: добавление в автозагрузку

null@example.com (stealzy) — Sat, 13 Jan 2018 13:54:28 +0000

Без меню в трее:

#NoTrayIcon
IniRead FirstRun, % A_ScriptName ".ini", Pref, FirstRun, 1
If FirstRun
	IniWrite % AutoRun("On"), % A_ScriptName ".ini", Pref, FirstRun
Run explorer %A_StartupCommon%
Return

End::AutoRun("Off")
Home::AutoRun("On")
Tab::AutoRun("Toggle")
Esc::ExitApp

AutoRun(p) {
	ShortcutPath := A_StartupCommon "\" A_ScriptName ".lnk"

	If (p = "On")
		FileCreateShortcut % A_ScriptFullPath, % ShortcutPath, "%A_ScriptDir%"
	Else If (p = "Off")
		FileDelete % ShortcutPath
	Else If (p = "Toggle")
		FileExist(ShortcutPath) ? AutoRun("Off") : AutoRun("On")
}

Re: АХК: добавление в автозагрузку

null@example.com (bsmolz) — Sat, 13 Jan 2018 13:17:52 +0000

Где иконка скрывается нашел, спасибо огромное. Можешь описать что за что отвечает, чтобы я понимал что и куда вставляю. stealzy

Re: АХК: добавление в автозагрузку

null@example.com (bsmolz) — Sat, 13 Jan 2018 13:16:06 +0000

А можешь пожалуйста описать что за что отвечает, и как скрыть иконку запускаемого приложения в трее. stealzy

Re: АХК: добавление в автозагрузку

null@example.com (stealzy) — Sat, 13 Jan 2018 12:14:56 +0000

; Menu Tray, NoIcon
Menu Tray, NoStandard
Menu Tray, Add, % AutoRun("MenuIni"), AutoRun
Menu Tray, Add, Выход, _Exit

IniRead FirstRun, % A_ScriptName ".ini", Pref, FirstRun, 1
If FirstRun
	IniWrite % AutoRun("On"), % A_ScriptName ".ini", Pref, FirstRun
Return

End::AutoRun("Off")
Esc::
_Exit:
	ExitApp

AutoRun(p:="Toggle") {
	static tAdd := "Добавить в автозагрузку", tRem := "Убрать из автозагрузки"
	ShortcutPath := A_StartupCommon "\" A_ScriptName ".lnk"

	If e:=FileExist(ShortcutPath) {
		FileGetShortcut % ShortcutPath, linkTarget,, linkParam
		If (linkTarget != A_ScriptFullPath)
			FileCreateShortcut % A_ScriptFullPath, % ShortcutPath, "%A_ScriptDir%"
			; If AHK not install - FileCreateShortcut "%A_AHKPath%", % ShortcutPath, "%A_ScriptDir%", "%A_ScriptFullPath%"
	}

	If (p = "MenuIni")
		Return e ? tRem : tAdd

	If e {
		If (p != "On")
			FileDelete % ShortcutPath
		Else
			ErrorLevel := true
	}
	Else {
		If (p != "Off")
			FileCreateShortcut % A_ScriptFullPath, % ShortcutPath, "%A_ScriptDir%"
		Else
			ErrorLevel := true
	}

	If Not ErrorLevel
		Menu Tray, Rename, % e ? tRem : tAdd, % e ? tAdd : tRem
}

АХК: добавление в автозагрузку

null@example.com (bsmolz) — Sat, 13 Jan 2018 09:36:52 +0000

Всем привет. Вопрос такой уважаемые знатоки:
Как в ахк сделать авто добавление этого ахк в автозагрузку при первом запуске
и удаление по нажатию "End". Если кто нибудь может сделать с меня плюха.

Если можно вопрос в вопросе задам.

АХК добавился в авто загрузку. После запуска Windows (любого с любым пользователем) программа открывается и как сделать так чтобы он себя из трея скрывала ?!

P.S Тема уже была но там как-то не понятно.